configure.ac

   1 dnl#
   2 dnl# Process this file with autoconf to produce a configure script.
   3 dnl#
   4
   5 AC_INIT
   6 AC_PREREQ(2.50)
   7 AC_CONFIG_SRCDIR([src/feature.h])
   8 AC_CONFIG_HEADER(config.h:config.h.in)
   9
  10 AC_CANONICAL_HOST
  11
  12 dnl RXVT version
  13 changequote(, )dnl
  14 VERSION=`sed -n -e 's/^.*[ \t]VERSION.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  15 DATE=`sed -n -e 's/^.*[ \t]DATE.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  16 changequote([, ])dnl
  17 AC_SUBST(VERSION)dnl
  18 AC_SUBST(DATE)dnl
  19
  20 echo ""
  21 echo "configuring for rxvt $VERSION"
  22 echo ""
  23
  24 orig_CXXFLAGS="$CXXFLAGS"
  25
  26 dnl# Checks for programs.
  27 AC_PROG_CC
  28 AC_PROG_CXX
  29 AC_PROG_CPP
  30 AC_PROG_INSTALL
  31
  32 AC_AIX
  33 AC_GNU_SOURCE
  34 AC_ISC_POSIX
  35 AC_LANG(C++)
  36
  37 dnl check wether we can link with gcc -lsupc++
  38 if test x$GCC = xyes && test x$GXX = xyes; then
  39    dnl FreeBSD (at least up to 5.3) has a broken GCC, workaround it
  40    AC_MSG_CHECKING([for working libsupc++])
  41    save_CXX="$CXX"
  42    save_LIBS="$LIBS"
  43    CXX="$CC"
  44    LIBS="$LIBS -lsupc++"
  45    LINKER="$CC"
  46    AC_LINK_IFELSE(
  47       [AC_LANG_PROGRAM([struct test { }; void f() try { throw new test; } catch (...) { throw; }],[])],
  48       [AC_MSG_RESULT(ok)],
  49       [
  50          AC_MSG_RESULT([no, making everything bigger and slower])
  51          LIBS="$save_LIBS"
  52          LINKER="$save_CXX"
  53       ]
  54    )
  55    CXX="$save_CXX"
  56 fi
  57 AC_SUBST(LINKER,[$LINKER])
  58
  59 dnl# --------------------------------------------------------------------------
  60 dnl# Supply default CXXFLAGS, if not specified by `CXXFLAGS=flags ./configure'
  61 dnl#
  62 if test -z "$orig_CXXFLAGS"; then
  63   if test x$GCC = xyes && test "x$GXX" = xyes; then
  64     CXXFLAGS="-g -O3 -fno-rtti -fvisibility-inlines-hidden -fno-threadsafe-statics -fno-enforce-eh-specs"
  65     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [], [CXXFLAGS="-g -O3"])
  66   else
  67     CXXFLAGS="-O"
  68   fi
  69   CFLAGS="$CXXFLAGS"
  70 fi
  71
  72 case $host in
  73    *-*-solaris* )
  74       AC_DEFINE(_XOPEN_SOURCE, 500, Needed to get declarations for msg_control and msg_controllen on Solaris)
  75       ;;
  76 esac
  77
  78 dnl# FreeBSD needs to link libxpg4
  79 AC_CHECK_FUNC(setlocale,     [], [AC_CHECK_LIB(xpg4,   setlocale,     [LIBS="$LIBS -lxpg4"])])
  80
  81 dnl# solaris needs to link libnsl and socket
  82 AC_CHECK_FUNC(gethostbyname, [], [AC_CHECK_LIB(nsl,    gethostbyname, [LIBS="$LIBS -lnsl"])])
  83 AC_CHECK_FUNC(socket,        [], [AC_CHECK_LIB(socket, socket,        [LIBS="$LIBS -lsocket"])])
  84
  85 support_frills=yes
  86 support_inheritpixmap=yes
  87 support_fading=yes
  88 support_keepscrolling=yes
  89 support_selectionscrolling=yes
  90 support_mousewheel=yes
  91 support_mouseslipwheel=yes
  92 support_text_blink=yes
  93 support_pointer_blank=yes
  94 support_scroll_rxvt=yes
  95 support_scroll_next=yes
  96 support_scroll_xterm=yes
  97 support_xim=yes
  98 support_afterimage=yes
  99 support_afterstep=yes
 100 support_xft=yes
 101 support_unicode3=no
 102 support_combining=yes
 103 support_8bitctrls=no
 104 support_iso14755=yes
 105 support_styles=yes
 106 support_perl=yes
 107 codesets=all
 108
 109 dnl# --------------------------------------------------------------------------
 110 dnl# CHECKING COMMAND LINE OPTIONS
 111 dnl# --------------------------------------------------------------------------
 112
 113 AC_ARG_ENABLE(everything,
 114   [  --enable-everything     enable standard non-multichoice features
 115                           NOTE: this option is order dependent],
 116   [
 117     if test x$enableval = xno; then
 118        support_frills=no
 119        support_inheritpixmap=no
 120        support_fading=no
 121        support_keepscrolling=no
 122        support_selectionscrolling=no
 123        support_lastlog=no
 124        support_mousewheel=no
 125        support_mouseslipwheel=no
 126        support_text_blink=no
 127        support_pointer_blank=no
 128        support_scroll_rxvt=no
 129        support_scroll_next=no
 130        support_scroll_xterm=no
 131        support_utmp=no
 132        support_wtmp=no
 133        support_xim=no
 134        support_afterimage=no
 135        support_afterstep=no
 136        support_xft=no
 137        support_unicode3=no
 138        support_combining=no
 139        support_8bitctrls=no
 140        support_iso14755=no
 141        support_styles=no
 142        support_perl=no
 143        codesets=
 144     fi
 145     if test x$enableval = xyes; then
 146        support_frills=yes
 147        support_inheritpixmap=yes
 148        support_fading=yes
 149        support_keepscrolling=yes
 150        support_selectionscrolling=yes
 151        support_lastlog=yes
 152        support_mousewheel=yes
 153        support_mouseslipwheel=yes
 154        support_text_blink=yes
 155        support_pointer_blank=yes
 156        support_scroll_rxvt=yes
 157        support_scroll_next=yes
 158        support_scroll_xterm=yes
 159        support_utmp=yes
 160        support_wtmp=yes
 161        support_xim=yes
 162        support_afterimage=yes
 163        support_afterstep=yes
 164        support_xft=yes
 165        support_unicode3=yes
 166        support_combining=yes
 167        #support_8bitctrls=yes
 168        support_iso14755=yes
 169        support_styles=yes
 170        support_perl=yes
 171        codesets=all
 172     fi
 173   ])
 174
 175 WARNINGS=no
 176 AC_ARG_ENABLE(warnings,
 177   [  --enable-warnings       turn on g++ warnings],
 178   [if test x$enableval = xyes; then
 179     WARNINGS=yes
 180   fi])
 181 if test x$GXX = xyes; then
 182   if test $WARNINGS = yes; then
 183     save_CXXFLAGS="$CXXFLAGS"
 184     CXXFLAGS="$CXXFLAGS -Wall -Wno-sign-compare -Wno-reorder -Wno-non-virtual-dtor"
 185     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [], [CXXFLAGS="$save_CXXFLAGS"])
 186   else
 187     CXXFLAGS="$CXXFLAGS -w"
 188   fi
 189 fi
 190
 191 AC_ARG_ENABLE(unicode3,
 192   [  --enable-unicode3       use 21 instead of 16 bits to represent unicode characters],
 193   [if test x$enableval = xyes -o x$enableval = xno; then
 194     support_unicode3=$enableval
 195   fi])
 196
 197 AC_ARG_ENABLE(combining,
 198   [  --enable-combining      enable composition of base and combining characters],
 199   [if test x$enableval = xyes -o x$enableval = xno; then
 200     support_combining=$enableval
 201   fi])
 202
 203 AC_ARG_ENABLE(xft,
 204   [  --enable-xft            enable xft support on systems that have it],
 205   [if test x$enableval = xyes -o x$enableval = xno; then
 206     support_xft=$enableval
 207   fi])
 208
 209 AC_ARG_ENABLE(font-styles,
 210   [  --enable-font-styles    enable bold and italic support],
 211   [if test x$enableval = xyes -o x$enableval = xno; then
 212     support_styles=$enableval
 213   fi])
 214
 215 AC_ARG_ENABLE(afterimage,
 216   [  --enable-afterimage     enable integration with libAfterImage for background images],
 217   [if test x$enableval = xyes -o x$enableval = xno; then
 218     support_afterimage=$enableval
 219   fi])
 220
 221 AC_ARG_WITH(afterimage_config,
 222   [  --with-afterimage-config=DIR  use libAfterImage config script in DIR],
 223   [if test "x$withval" != x; then
 224     afterimage_config=$withval/afterimage-config
 225   fi])
 226
 227 dnl AC_ARG_ENABLE(afterstep,
 228 dnl   [  --enable-afterstep enable integration with AfterStep window manager],
 229 dnl   [if test x$enableval = xyes -o x$enableval = xno; then
 230 dnl     support_afterstep=$enableval
 231 dnl   fi])
 232
 233 AC_ARG_ENABLE(transparency,
 234   [  --enable-transparency   enable transparent backgrounds],
 235   [if test x$enableval = xyes -o x$enableval = xno; then
 236     support_inheritpixmap=$enableval
 237   fi])
 238
 239 AC_ARG_ENABLE(fading,
 240   [  --enable-fading         enable colors fading when off focus],
 241   [if test x$enableval = xyes -o x$enableval = xno; then
 242     support_fading=$enableval
 243   fi])
 244
 245 AC_ARG_ENABLE(rxvt-scroll,
 246   [  --enable-rxvt-scroll    enable rxvt style scrollbar],
 247   [if test x$enableval = xyes -o x$enableval = xno; then
 248     support_scroll_rxvt=$enableval
 249   fi])
 250
 251 AC_ARG_ENABLE(next-scroll,
 252   [  --enable-next-scroll    enable NeXT style scrollbar],
 253   [if test x$enableval = xyes -o x$enableval = xno; then
 254     support_scroll_next=$enableval
 255   fi])
 256
 257 AC_ARG_ENABLE(xterm-scroll,
 258   [  --enable-xterm-scroll   enable Xterm style scrollbar],
 259   [if test x$enableval = xyes -o x$enableval = xno; then
 260     support_scroll_xterm=$enableval
 261   fi])
 262
 263 AC_ARG_ENABLE(perl,
 264   [  --enable-perl           enable embedded perl interpreter],
 265   [if test x$enableval = xyes -o x$enableval = xno; then
 266     support_perl=$enableval
 267   fi])
 268
 269 AC_ARG_WITH(codesets,
 270   [  --with-codesets=CS,...  compile in additional codesets (jp,jp_ext,kr,zh,zh_ext,all)],
 271   [codesets="$withval"])
 272
 273 AC_ARG_ENABLE(xim,
 274   [  --enable-xim            XIM (X Input Method) protocol support],
 275   [if test x$enableval = xyes -o x$enableval = xno; then
 276     support_xim=$enableval
 277   fi])
 278
 279 AC_ARG_ENABLE(backspace-key,
 280   [  --disable-backspace-key disable handling of the backspace key],
 281   [if test x$enableval = xno; then
 282     AC_DEFINE(NO_BACKSPACE_KEY, 1, Define if you don't want support for the backspace key)
 283   fi])
 284
 285 AC_ARG_ENABLE(delete-key,
 286   [  --disable-delete-key    disable handling of the delete key],
 287   [if test x$enableval = xno; then
 288     AC_DEFINE(NO_DELETE_KEY, 1, Define if you don't want support for the (non-keypad) delete key)
 289   fi])
 290
 291 AC_ARG_ENABLE(resources,
 292   [  --disable-resources     disable all resource checking],
 293   [if test x$enableval = xno; then
 294     AC_DEFINE(NO_RESOURCES, 1, Define if you don't want any resources read)
 295   fi])
 296
 297 AC_ARG_ENABLE(8bitctrls,
 298   [  --enable-8bitctrls      enable 8 bit control sequences (not recommended)],
 299   [if test x$enableval = xyes -o x$enableval = xno; then
 300     support_8bitctrls=$enableval
 301   fi])
 302
 303 RESFALLBACK=Rxvt
 304 AC_ARG_ENABLE(fallback,
 305   [  --enable-fallback@<:@=CLASS@:>@ fall back on CLASS resources in addition to URxvt ones (default: Rxvt)],
 306   [
 307    test x$enableval = xyes && enableval=Rxvt
 308    test x$enableval = xno  && enableval=
 309    RESFALLBACK="$enableval"
 310   ])
 311
 312 if test x$RESFALLBACK != x; then
 313    AC_DEFINE_UNQUOTED(RESFALLBACK, "$RESFALLBACK", [Fallback resource class])
 314 fi
 315
 316 RESNAME=urxvt
 317 AC_ARG_WITH(res-name,
 318   [  --with-res-name=NAME    use this as default resource name (default: urxvt)],
 319   [RESNAME="$withval"])
 320 AC_DEFINE_UNQUOTED(RESNAME,"$RESNAME", [Default resource name])
 321
 322 RESCLASS=URxvt
 323 AC_ARG_WITH(res-class,
 324   [  --with-res-class=CLASS  use this as the resource class (default: URxvt)],
 325   [RESCLASS="$withval"])
 326 AC_DEFINE_UNQUOTED(RESCLASS,"$RESCLASS", [Resource class])
 327
 328 RXVTNAME=urxvt
 329 AC_ARG_WITH(name,
 330   [  --with-name=NAME        set the basename for the installed binaries (default: urxvt)],
 331   [RXVTNAME="$withval"])
 332 AC_DEFINE_UNQUOTED(RXVTNAME,"$RXVTNAME", [Binary base name])
 333
 334 RXVTNAME=`echo "$RXVTNAME"|sed "$program_transform_name"`
 335 AC_SUBST(RXVTNAME)
 336
 337 AC_ARG_ENABLE(swapscreen,
 338   [  --disable-swapscreen    disable swap screen support],
 339   [if test x$enableval = xno; then
 340     AC_DEFINE(NO_SECONDARY_SCREEN, 1, Disable the secondary screen. Many programs use the secondary screen as their workplace)
 341   fi])
 342
 343 AC_ARG_ENABLE(iso14755,
 344   [  --enable-iso14755       enable support for extended ISO 14755 modes],
 345   [if test x$enableval = xyes -o x$enableval = xno; then
 346     support_iso14755=$enableval
 347   fi])
 348
 349 AC_ARG_ENABLE(frills,
 350   [  --enable-frills         enable support for rarely used features],
 351   [if test x$enableval = xyes -o x$enableval = xno; then
 352     support_frills=$enableval
 353   fi])
 354
 355 AC_ARG_ENABLE(keepscrolling,
 356   [  --enable-keepscrolling  enable continual scrolling on scrollbar arrow press],
 357   [if test x$enableval = xyes -o x$enableval = xno; then
 358     support_keepscrolling=$enableval
 359   fi])
 360
 361 AC_ARG_ENABLE(selectionscrolling,
 362   [  --enable-selectionscrolling  enable scrolling during selections],
 363   [if test x$enableval = xyes -o x$enableval = xno; then
 364     support_selectionscrolling=$enableval
 365   fi])
 366
 367 AC_ARG_ENABLE(mousewheel,
 368   [  --enable-mousewheel     enable scrolling via mouse wheel or buttons 4 & 5],
 369   [if test x$enableval = xyes -o x$enableval = xno; then
 370     support_mousewheel=$enableval
 371   fi])
 372
 373 AC_ARG_ENABLE(slipwheeling,
 374   [  --enable-slipwheeling   enable slip wheel scrolling (requires --enable-mousewheel)],
 375   [if test x$enableval = xyes -o x$enableval = xno; then
 376     support_mouseslipwheel=$enableval
 377   fi])
 378
 379 AC_ARG_ENABLE(smart-resize,
 380   [  --enable-smart-resize   enable smart growth/shrink behaviour],
 381   [if test x$enableval = xyes; then
 382     AC_DEFINE(SMART_RESIZE, 1, Define to use "smart" resize behavior)
 383   fi])
 384
 385 AC_ARG_ENABLE(text-blink,
 386   [  --enable-text-blink     enable blinking text],
 387   [if test x$enableval = xyes -o x$enableval = xno; then
 388     support_text_blink=$enableval
 389   fi])
 390
 391 AC_ARG_ENABLE(pointer-blank,
 392   [  --enable-pointer-blank  enable pointer blank when typing or inactive pointer],
 393   [if test x$enableval = xyes -o x$enableval = xno; then
 394     support_pointer_blank=$enableval
 395   fi])
 396
 397 AC_ARG_WITH(term,
 398   [  --with-term=NAME        set the terminal to NAME (default: rxvt)],
 399   [if test x$withval != x; then
 400     AC_DEFINE_UNQUOTED(TERMENV, "$withval",Set TERM to the value given by configure) term="$withval"
 401   fi])
 402
 403 AC_ARG_WITH(terminfo,
 404   [  --with-terminfo=PATH    set the path to the terminfo tree to PATH],
 405   [if test x$withval != x; then
 406     AC_DEFINE_UNQUOTED(RXVT_TERMINFO, "$withval", Set TERMINFO value to the value given by configure) terminfo="$withval"
 407   fi])
 408
 409 dnl# --------------------------------------------------------------------------
 410
 411 LIBEV_M4_AVOID_LIBRT=1
 412 m4_include([libev/libev.m4])
 413
 414 dnl# --------------------------------------------------------------------------
 415
 416 AC_PATH_PROG(TIC, tic, :)
 417
 418 AC_PATH_XTRA
 419
 420 AFTERIMAGE_CFLAGS=
 421 AFTERIMAGE_LIBS=
 422 AFTERIMAGE_VERSION=
 423
 424 if test x$support_afterimage = xyes; then
 425   support_afterimage=no
 426
 427   if test "x$afterimage_config" = "x" ; then
 428     AC_PATH_PROG(afterimage_config, afterimage-config, no)
 429   fi
 430   if test "x$afterimage_config" != "xno" ; then
 431     AC_MSG_CHECKING(for libAfterImage version >= 1.15)
 432     xAFTERIMAGE_VERSION=`$afterimage_config --version`
 433     if test -n "$xAFTERIMAGE_VERSION" ; then
 434       xAFTERIMAGE_CFLAGS=`$afterimage_config --cflags`
 435       xAFTERIMAGE_LIBS=`$afterimage_config --libs`
 436       if test "x$xAFTERIMAGE_LIBS" != "x"; then
 437         libai_ver_major=`echo $xAFTERIMAGE_VERSION | cut -f 1 -d .`
 438         libai_ver_minor=`echo $xAFTERIMAGE_VERSION | cut -f 2 -d .`
 439         if test $libai_ver_major -gt 1 -o \( $libai_ver_major -eq 1 -a $libai_ver_minor -ge 15 \); then
 440           support_afterimage=yes
 441           AFTERIMAGE_CFLAGS="$xAFTERIMAGE_CFLAGS"
 442           AFTERIMAGE_LIBS="$xAFTERIMAGE_LIBS"
 443           AFTERIMAGE_VERSION="$xAFTERIMAGE_VERSION"
 444         fi
 445       fi
 446     fi
 447     if test "x$support_afterimage" = "xyes"; then
 448       AC_MSG_RESULT($AFTERIMAGE_LIBS)
 449     else
 450       AC_MSG_RESULT(no)
 451     fi
 452   fi
 453 fi
 454
 455 dnl# --------------------------------------------------------------------------
 456 dnl# CHECKING FOR HEADER FILES
 457 dnl# --------------------------------------------------------------------------
 458 AC_CHECK_HEADERS( \
 459         sys/byteorder.h \
 460         sys/ioctl.h \
 461         sys/sockio.h \
 462         sys/strredir.h \
 463         stdint.h \
 464         wchar.h \
 465         cwchar \
 466 )
 467
 468 AC_CACHE_CHECK([for XPointer], rxvt_cv_xpointer,
 469 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XPointer dummy;]])],[rxvt_cv_xpointer=yes],[rxvt_cv_xpointer=no])])
 470 if test x$rxvt_cv_xpointer = xyes; then
 471   AC_DEFINE(HAVE_XPOINTER, 1, Define if you have XPointer typedef)
 472 fi
 473
 474 AC_CACHE_CHECK([for XLIB_ILLEGAL_ACCESS], rxvt_xlib_illegal_access,
 475 [AC_COMPILE_IFELSE(
 476    [AC_LANG_PROGRAM([
 477 #define XLIB_ILLEGAL_ACCESS
 478 #include <X11/Xlib.h>
 479    ],[
 480       Display *dpy;
 481       dpy->xdefaults = (char *)0;
 482    ])],
 483    [rxvt_xlib_illegal_access=yes],[rxvt_xlib_illegal_access=no]
 484 )])
 485 if test x$rxvt_xlib_illegal_access = xyes; then
 486    AC_DEFINE(XLIB_ILLEGAL_ACCESS, 1, Define ONLY iff Xlib.h supports it)
 487 fi
 488
 489 dnl# --------------------------------------------------------------------------
 490 dnl# CHECKING FOR MISSING TYPEDEFS
 491 dnl# --------------------------------------------------------------------------
 492 dnl# Missing typedefs and replacements
 493 AC_TYPE_MODE_T
 494 AC_TYPE_PID_T
 495 AC_TYPE_UID_T
 496 AC_TYPE_INT16_T
 497 AC_TYPE_UINT16_T
 498 AC_TYPE_INT32_T
 499 AC_TYPE_UINT32_T
 500
 501 dnl# --------------------------------------------------------------------------
 502 dnl# CHECKING FOR LIBRARY FUNCTIONS
 503 dnl# --------------------------------------------------------------------------
 504 AC_CHECK_FUNCS(unsetenv)
 505
 506 UTMP_CHECK
 507
 508 dnl# --------------------------------------------------------------------------
 509
 510 dnl# --------------------------------------------------------------------------
 511 dnl# --------------------------------------------------------------------------
 512
 513 dnl# this is a really hack test for some basic Xlocale stuff
 514 save_LIBS=$LIBS
 515 save_CFLAGS=$CFLAGS
 516 CFLAGS="$CFLAGS $X_CFLAGS"
 517 LIBS="$LIBS $X_LIBS $X_EXTRA_LIBS -lX11"
 518 if test x$support_xim = xyes; then
 519   AC_CACHE_CHECK(for working Xlocale, rxvt_cv_func_xlocale,
 520   [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <X11/Xlib.h>
 521   #include <stdlib.h>
 522   main() {
 523   char *p;
 524   if ((p = XSetLocaleModifiers("@im=none")) != NULL && *p)
 525   exit (XSupportsLocale() ? 0 : 1);
 526   else
 527   exit (1);}]])],[dnl
 528     rxvt_cv_func_xlocale=yes],[rxvt_cv_func_xlocale=no],[dnl
 529     :])])
 530   if test x$rxvt_cv_func_xlocale = xyes; then
 531     AC_DEFINE(USE_XIM, 1, Define if you want to have XIM (X Input Method) protocol support - required for multibyte characters input)
 532     AC_CACHE_CHECK(for broken XIM callback, rxvt_broken_ximcb,
 533     [AC_COMPILE_IFELSE([
 534     #include <X11/Xlib.h>
 535
 536     void im_destroy_cb (XIC unused1, XPointer client_data, XPointer unused3);
 537
 538     void f() {
 539       XIMCallback cb;
 540       cb.callback = im_destroy_cb;
 541     }
 542     ],rxvt_broken_ximcb=yes,rxvt_broken_ximcb=no)])
 543
 544     if test x$rxvt_broken_ximcb = xyes; then
 545        AC_DEFINE(XIMCB_PROTO_BROKEN, 1, Define if your XIMCallback specifies XIC as first type.)
 546     fi
 547   fi
 548 fi
 549
 550 AC_CACHE_CHECK(for working X setlocale, rxvt_cv_func_xsetlocale,
 551 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define X_LOCALE 1
 552 #include <X11/Xlocale.h>]], [[setlocale(LC_CTYPE, "");]])],[rxvt_cv_func_xsetlocale=yes],[rxvt_cv_func_xsetlocale=no])])
 553 if test x$rxvt_cv_func_xsetlocale = xyes; then
 554   AC_DEFINE(HAVE_XSETLOCALE, 1, Define if setlocale (defined to Xsetlocale) works)
 555 fi
 556 LIBS=$save_LIBS
 557 CFLAGS=$save_CFLAGS
 558
 559 AC_CACHE_CHECK(for working plain setlocale, rxvt_cv_func_setlocale,
 560 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <clocale>]], [[setlocale(LC_CTYPE, "");]])],[rxvt_cv_func_setlocale=yes],[rxvt_cv_func_setlocale=no])])
 561 if test x$rxvt_cv_func_setlocale = xyes; then
 562   AC_DEFINE(HAVE_SETLOCALE, 1, Define if plain old setlocale works)
 563 fi
 564
 565 AC_CACHE_CHECK(for working nl_langinfo, rxvt_cv_func_nl_langinfo,
 566 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(CODESET);]])],[rxvt_cv_func_nl_langinfo=yes],[rxvt_cv_func_nl_langinfo=no])])
 567 if test x$rxvt_cv_func_nl_langinfo = xyes; then
 568   AC_DEFINE(HAVE_NL_LANGINFO, 1, Define if nl_langinfo(CODESET) works)
 569 fi
 570
 571 SCM_RIGHTS_CHECK
 572
 573 PTY_CHECK
 574
 575 TTY_GROUP_CHECK
 576
 577 dnl# --------------------------------------------------------------------------
 578 dnl# now add and remove other stuff
 579 dnl# --------------------------------------------------------------------------
 580 if test x$support_xft = xyes; then
 581   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 582   if test $PKG_CONFIG != no && $PKG_CONFIG --exists xft; then
 583     X_LIBS="`$PKG_CONFIG xft --libs` $X_LIBS"
 584     CPPFLAGS="$CPPFLAGS `$PKG_CONFIG xft --cflags`"
 585   else
 586     AC_PATH_PROG(XFT_CONFIG, xft-config, no)
 587     if test $XFT_CONFIG != no; then
 588       X_LIBS="`$XFT_CONFIG --libs` $X_LIBS"
 589       CPPFLAGS="$CPPFLAGS `$XFT_CONFIG --cflags`"
 590     fi
 591   fi
 592
 593   save_LIBS="$LIBS"
 594   LIBS="$LIBS $X_LIBS"
 595   AC_CHECK_HEADERS(X11/Xft/Xft.h,,[support_xft=no])
 596   AC_CHECK_LIB(Xft,XftDrawString32,:,[support_xft=no])
 597   LIBS="$save_LIBS"
 598
 599   if test x$support_xft = xyes; then
 600     AC_DEFINE(XFT, 1, Define to enable xft support)
 601   fi
 602 fi
 603 if test x$support_styles = xyes; then
 604   AC_DEFINE(ENABLE_STYLES, 1, Define if you want bold and italic support)
 605 fi
 606 if test x$support_iso14755 = xyes; then
 607   AC_DEFINE(ISO_14755, 1, Define if you want ISO 14755 extended support)
 608 fi
 609 if test x$support_8bitctrls = xyes; then
 610   AC_DEFINE(EIGHT_BIT_CONTROLS, 1, Define if you want 8 bit control sequences)
 611 fi
 612 if test x$support_fading = xyes; then
 613   AC_DEFINE(OFF_FOCUS_FADING, 1, Define if you want faded colors when focus is lost)
 614 fi
 615 if test x$support_inheritpixmap = xyes; then
 616   AC_DEFINE(ENABLE_TRANSPARENCY, 1, Define if you want your background to use the parent window background)
 617 fi
 618 if test x$support_keepscrolling = xno; then
 619   AC_DEFINE(NO_SCROLLBAR_BUTTON_CONTINUAL_SCROLLING, 1, Define for continual scrolling when you keep the scrollbar button pressed)
 620 fi
 621 if test x$support_selectionscrolling = xyes; then
 622   AC_DEFINE(SELECTION_SCROLLING, 1, Define to allow scrolling when the selection moves to the top or bottom of the screen)
 623 fi
 624 if test x$support_frills = xyes; then
 625   AC_DEFINE(ENABLE_FRILLS, 1, Define if you want handling for rarely used but handy features)
 626 fi
 627 if test x$support_mousewheel = xyes; then
 628   AC_DEFINE(MOUSE_WHEEL, 1, Define to use wheel events (button4 and button5) to scroll)
 629 fi
 630 if test x$support_mouseslipwheel = xyes; then
 631   AC_DEFINE(MOUSE_SLIP_WHEELING, 1, Define to have CTRL cause wheel events to accelerate scrolling. Release CTRL to halt scrolling)
 632 fi
 633 if test x$support_afterimage = xyes; then
 634   AC_DEFINE(HAVE_AFTERIMAGE, 1, Define if you want to use libAfterImage for image processing)
 635   AC_DEFINE(BG_IMAGE_FROM_FILE, 1, Define if you want to have sexy-looking background pixmaps. Needs libAfterImage)
 636 fi
 637
 638 dnl if test x$support_afterstep = xyes; then
 639 dnl   AC_DEFINE(AFTERSTEP_INTEGRATION, 1, Define if you want to integrate with AfterStep window manager)
 640 dnl fi
 641
 642 scrolltypes=plain
 643 AC_DEFINE(PLAIN_SCROLLBAR, 1, Support plain style scrollbars)
 644
 645 if test x$support_scroll_rxvt = xyes; then
 646   AC_DEFINE(RXVT_SCROLLBAR, 1, Support Rxvt original style scrollbars)
 647   scrolltypes="$scrolltypes rxvt"
 648 fi
 649 if test x$support_scroll_next = xyes; then
 650   AC_DEFINE(NEXT_SCROLLBAR, 1, Support NeXT style scrollbars)
 651   scrolltypes="$scrolltypes next"
 652 fi
 653 if test x$support_scroll_xterm = xyes; then
 654   AC_DEFINE(XTERM_SCROLLBAR, 1, Support Xterm style scrollbars)
 655   scrolltypes="$scrolltypes xterm"
 656 fi
 657 if test x$support_pointer_blank = xyes; then
 658   AC_DEFINE(POINTER_BLANK, 1, Define if you want hide the pointer while typing)
 659 fi
 660 if test x$support_text_blink = xyes; then
 661   AC_DEFINE(TEXT_BLINK, 1, Define if you want blinking text support)
 662 fi
 663 if test x$support_unicode3 = xyes; then
 664   AC_DEFINE(UNICODE_3, 1, Define if you want to represent unicode characters outside plane 0)
 665 fi
 666 if test x$support_combining = xyes; then
 667   AC_DEFINE(ENABLE_COMBINING, 1, Define if you want to automatically compose combining characters)
 668 fi
 669 if test x$codesets = xall; then
 670   codesets=jp,jp-ext,kr,zh,zh-ext
 671 fi
 672 AC_DEFINE(ENCODING_EU, 1, Define if you want european extended codesets)
 673 AC_DEFINE(ENCODING_VN, 1, Define if you want vietnamese codesets)
 674 for codeset in `echo $codesets | tr "[a-z,\\-]" "[A-Z _]"`; do
 675   case "$codeset" in
 676     JP     ) AC_DEFINE(ENCODING_JP,     1, Define if you want japanese codesets) ;;
 677     JP_EXT ) AC_DEFINE(ENCODING_JP_EXT, 1, Define if you want extended japanese codesets) ;;
 678     KR     ) AC_DEFINE(ENCODING_KR,     1, Define if you want korean codesets) ;;
 679     ZH     ) AC_DEFINE(ENCODING_ZH,     1, Define if you want chinese codesets) ;;
 680     ZH_EXT ) AC_DEFINE(ENCODING_ZH_EXT, 1, Define if you want extended chinese codesets) ;;
 681   esac
 682 done
 683
 684 IF_PERL=\#
 685 if test x$support_perl = xyes; then
 686   AC_PATH_PROG(PERL, perl5)
 687   AC_PATH_PROG(PERL, perl)
 688
 689   AC_MSG_CHECKING(for $PERL suitability)
 690   if $PERL -MExtUtils::Embed -e "use v5.8" >/dev/null 2>/dev/null; then
 691
 692      save_CXXFLAGS="$CXXFLAGS"
 693      save_LIBS="$LIBS"
 694      CXXFLAGS="$CXXFLAGS `$PERL -MExtUtils::Embed -e ccopts`"
 695      LIBS="$LIBS `$PERL -MExtUtils::Embed -e ldopts`"
 696      AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 697 #include <EXTERN.h>
 698 #include <perl.h>
 699 #include <XSUB.h>
 700 ]], [[
 701      PerlInterpreter *perl = perl_alloc ();
 702 ]])],[rxvt_perl_link=yes],[rxvt_perl_link=no])
 703      CXXFLAGS="$save_CXXFLAGS"
 704      LIBS="$save_LIBS"
 705
 706      if test x$rxvt_perl_link = xyes; then
 707         AC_MSG_RESULT(ok)
 708         AC_DEFINE(ENABLE_PERL, 1, Define if you can embed a perl interpreter)
 709         IF_PERL=
 710         PERL_O=rxvtperl.o
 711         PERLFLAGS="`$PERL -MExtUtils::Embed -e ccopts`"
 712         PERLLIB="`$PERL -MExtUtils::Embed -e ldopts`"
 713         PERLPRIVLIBEXP="`$PERL -MConfig -e 'print $Config{privlibexp}'`"
 714      else
 715         AC_MSG_ERROR([no, unable to link])
 716      fi
 717   else
 718      AC_MSG_ERROR([no working perl found, or perl not version >= 5.8])
 719   fi
 720 fi
 721 AC_SUBST(PERLLIB)
 722 AC_SUBST(PERLFLAGS)
 723 AC_SUBST(PERLPRIVLIBEXP)
 724 AC_SUBST(PERL)
 725 AC_SUBST(IF_PERL)
 726 AC_SUBST(PERL_O)
 727
 728 AC_SUBST(CFLAGS)
 729 AC_SUBST(CPPFLAGS)
 730 AC_SUBST(LDFLAGS)
 731 AC_SUBST(X_CFLAGS)
 732
 733 dnl# Attack the libs
 734 AC_SUBST(LIBS)
 735 AC_SUBST(X_LIBS)
 736 AC_SUBST(X_EXTRA_LIBS)
 737
 738 AC_SUBST(AFTERIMAGE_CFLAGS)
 739 AC_SUBST(AFTERIMAGE_LIBS)
 740
 741 AC_ARG_PROGRAM
 742
 743 AC_CONFIG_FILES([Makefile \
 744 doc/Makefile \
 745 src/Makefile \
 746 ])
 747 AC_OUTPUT
 748
 749 echo "Configuration:
 750
 751   Rxvt version:               $VERSION : $DATE
 752   Source code location:       $srcdir
 753   Install path:               ${prefix}/bin
 754   Compiler:                   $CXX
 755   Compiler flags:             $CXXFLAGS
 756   Linker:                     $LINKER"
 757
 758 if test x$term != x; then
 759   echo "  set TERM to:                $term"
 760 fi
 761 if test x$terminfo != x; then
 762   echo "  set TERMINFO to:            $terminfo"
 763 fi
 764 echo "  default resource name:      $RESNAME"
 765 echo "  resource class:             $RESCLASS"
 766 if test x$RESFALLBACK != x; then
 767    echo "  resource class fallback:    $RESFALLBACK"
 768 fi
 769 echo
 770 echo "  embedded perl:              $support_perl"
 771 echo "  libafterimage:              $support_afterimage"
 772 dnl echo "  AfterStep integration:      $support_afterstep"
 773 echo
 774 if test x$support_xim = xyes -a x$rxvt_cv_func_xlocale = xno; then
 775   echo ".----------------------------------------------------------------."
 776   echo ". WARNING: --enable-xim was specified however the locale support ."
 777   echo ".          functions could not be found.                         ."
 778   echo ".          XIM is now being DISABLED!                            ."
 779   echo ".----------------------------------------------------------------."
 780 fi
 781
 782 echo "*** Optionally check src/feature.h for further, rarely used options ***"
 783 echo
 784