configure.ac

   1 dnl#
   2 dnl# Process this file with autoconf to produce a configure script.
   3 dnl#
   4
   5 AC_INIT
   6 AC_PREREQ(2.50)
   7 AC_CONFIG_SRCDIR([src/feature.h])
   8 AC_CONFIG_HEADER(config.h:config.h.in)
   9
  10 AC_CANONICAL_HOST
  11
  12 dnl RXVT version
  13 changequote(, )dnl
  14 VERSION=`sed -n -e 's/^.*[ \t]VERSION.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  15 DATE=`sed -n -e 's/^.*[ \t]DATE.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  16 dnl LIBVERSION=`sed -n -e 's/^.*[ \t]LIBVERSION.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  17 changequote([, ])dnl
  18 AC_SUBST(VERSION)dnl
  19 AC_SUBST(DATE)dnl
  20 AC_SUBST(LSMDATE)dnl
  21 AC_SUBST(LIBVERSION)dnl
  22 echo ""
  23 echo "configuring for rxvt $VERSION"
  24 echo ""
  25
  26 orig_CXXFLAGS="$CXXFLAGS"
  27
  28 dnl# Checks for programs.
  29 dnl AC_MAKE_SET
  30
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_PROG_CPP
  34 AC_PROG_INSTALL
  35
  36 AC_AIX
  37 AC_ISC_POSIX
  38 AC_LANG(C++)
  39
  40 dnl check wether we can link with gcc -lsupc++
  41 if test x$GCC = xyes && test x$GXX = xyes; then
  42    dnl FreeBSD (at least up to 5.3) has a broken GCC, workaround it
  43    AC_MSG_CHECKING([for working libsupc++])
  44    save_CXX="$CXX"
  45    save_LIBS="$LIBS"
  46    CXX="$CC"
  47    LIBS="$LIBS -lsupc++"
  48    LINKER="$CC"
  49    AC_LINK_IFELSE(
  50       [AC_LANG_PROGRAM([struct test { }; void f() try { throw new test; } catch (...) { throw; }],[])],
  51       [AC_MSG_RESULT(ok)],
  52       [
  53          AC_MSG_RESULT([no, making everything bigger and slower])
  54          LIBS="$save_LIBS"
  55          LINKER="$save_CXX"
  56       ]
  57    )
  58    CXX="$save_CXX"
  59 fi
  60 AC_SUBST(LINKER,[$LINKER])
  61
  62 dnl# --------------------------------------------------------------------------
  63 dnl# Supply default CXXFLAGS, if not specified by `CXXFLAGS=flags ./configure'
  64 dnl#
  65 if test -z "$orig_CXXFLAGS"; then
  66   if test x$GCC = xyes && test "x$GXX" = xyes; then
  67      CXXFLAGS="-g -O3 -fno-threadsafe-statics -fno-enforce-eh-specs"
  68     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [], [CXXFLAGS="-g -O3"])
  69   else
  70     CXXFLAGS="-O"
  71   fi
  72   CFLAGS="$CXXFLAGS"
  73 fi
  74
  75 AC_DEFINE(_GNU_SOURCE, 1, Use all glibc features.)
  76
  77 case $host in
  78    *-*-solaris* )
  79       AC_DEFINE(_XOPEN_SOURCE, 500, Needed to get declarations for msg_control and msg_controllen on Solaris)
  80       ;;
  81 esac
  82
  83 dnl if test x$GXX = xyes; then
  84 dnl    CXXFLAGS="$CXXFLAGS" dnl I once had -fno-exceptions, but I am using them now...
  85 dnl fi
  86
  87 dnl# FreeBSD needs to link libxpg4
  88 AC_CHECK_FUNC(setlocale,     [], [AC_CHECK_LIB(xpg4,   setlocale,     [LIBS="$LIBS -lxpg4"])])
  89
  90 dnl# solaris needs to link libnsl and socket
  91 AC_CHECK_FUNC(gethostbyname, [], [AC_CHECK_LIB(nsl,    gethostbyname, [LIBS="$LIBS -lnsl"])])
  92 AC_CHECK_FUNC(socket,        [], [AC_CHECK_LIB(socket, socket,        [LIBS="$LIBS -lsocket"])])
  93
  94 dnl AC_ENABLE_SHARED(no)dnl#    libtool
  95 dnl AC_ENABLE_STATIC(yes)dnl#   libtool
  96 dnl AC_PROG_LIBTOOL()dnl#               libtool
  97
  98 support_frills=yes
  99 support_inheritpixmap=yes
 100 support_fading=yes
 101 support_keepscrolling=yes
 102 support_selectionscrolling=yes
 103 support_mousewheel=yes
 104 support_mouseslipwheel=yes
 105 support_text_blink=yes
 106 support_pointer_blank=yes
 107 support_scroll_rxvt=yes
 108 support_scroll_next=yes
 109 support_scroll_xterm=yes
 110 support_scroll_plain=yes
 111 support_xim=yes
 112 support_afterimage=yes
 113 support_afterstep=yes
 114 support_xft=yes
 115 support_unicode3=no
 116 support_combining=yes
 117 support_8bitctrls=no
 118 support_iso14755=yes
 119 support_styles=yes
 120 support_perl=yes
 121 codesets=all
 122
 123 dnl# --------------------------------------------------------------------------
 124 dnl# CHECKING COMMAND LINE OPTIONS
 125 dnl# --------------------------------------------------------------------------
 126
 127 if test "x$enable_shared" = xyes; then
 128     AC_DEFINE(LIBRXVT, 1, Build shared library version - specify via configure only)
 129     INSTALL_LIBRXVT=yes
 130 fi
 131 AC_SUBST(INSTALL_LIBRXVT)
 132
 133 AC_ARG_ENABLE(everything,
 134   [  --enable-everything     enable standard non-multichoice features
 135                      NOTE: this option is order dependent
 136                      NOTE: automatically enabled with --enable-shared],
 137   [
 138     if test x$enableval = xno; then
 139        support_frills=no
 140        support_inheritpixmap=no
 141        support_fading=no
 142        support_keepscrolling=no
 143        support_selectionscrolling=no
 144        support_lastlog=no
 145        support_mousewheel=no
 146        support_mouseslipwheel=no
 147        support_text_blink=no
 148        support_pointer_blank=no
 149        support_scroll_rxvt=no
 150        support_scroll_next=no
 151        support_scroll_xterm=no
 152        support_scroll_plain=no
 153        support_utmp=no
 154        support_wtmp=no
 155        support_xim=no
 156        support_afterimage=no
 157        support_afterstep=no
 158        support_xft=no
 159        support_unicode3=no
 160        support_combining=no
 161        support_8bitctrls=no
 162        support_iso14755=no
 163        support_styles=no
 164        support_perl=no
 165        codesets=
 166     fi
 167     if test x$enableval = xyes; then
 168        support_frills=yes
 169        support_inheritpixmap=yes
 170        support_fading=yes
 171        support_keepscrolling=yes
 172        support_selectionscrolling=yes
 173        support_lastlog=yes
 174        support_mousewheel=yes
 175        support_mouseslipwheel=yes
 176        support_text_blink=yes
 177        support_pointer_blank=yes
 178        support_scroll_rxvt=yes
 179        support_scroll_next=yes
 180        support_scroll_xterm=yes
 181        support_scroll_plain=yes
 182        support_utmp=yes
 183        support_wtmp=yes
 184        support_xim=yes
 185        support_afterimage=yes
 186        support_afterstep=yes
 187        support_xft=yes
 188        support_unicode3=yes
 189        support_combining=yes
 190        #support_8bitctrls=yes
 191        support_iso14755=yes
 192        support_styles=yes
 193        support_perl=yes
 194        codesets=all
 195     fi
 196   ])
 197
 198 AC_ARG_ENABLE(unicode3,
 199   [  --enable-unicode3       use 21 instead of 16 bits to represent unicode characters],
 200   [if test x$enableval = xyes -o x$enableval = xno; then
 201     support_unicode3=$enableval
 202   fi])
 203
 204 AC_ARG_ENABLE(combining,
 205   [  --enable-combining      enable composition of base and combining characters],
 206   [if test x$enableval = xyes -o x$enableval = xno; then
 207     support_combining=$enableval
 208   fi])
 209
 210 AC_ARG_ENABLE(xft,
 211   [  --enable-xft            enable xft support on systems that have it],
 212   [if test x$enableval = xyes -o x$enableval = xno; then
 213     support_xft=$enableval
 214   fi])
 215
 216 AC_ARG_ENABLE(font-styles,
 217   [  --enable-font-styles    enable bold and italic support],
 218   [if test x$enableval = xyes -o x$enableval = xno; then
 219     support_styles=$enableval
 220   fi])
 221
 222 AC_ARG_ENABLE(afterimage,
 223   [  --enable-afterimage enable integration with libAfterImage for background images],
 224   [if test x$enableval = xyes -o x$enableval = xno; then
 225     support_afterimage=$enableval
 226   fi])
 227
 228 AC_ARG_WITH(afterimage_config,
 229   [  --with-afterimage-config=DIR  use libAfterImage config script in DIR],
 230   [if test "x$withval" != x; then
 231     afterimage_config=$withval/afterimage-config
 232   fi])
 233
 234 dnl AC_ARG_ENABLE(afterstep,
 235 dnl   [  --enable-afterstep enable integration with AfterStep window manager],
 236 dnl   [if test x$enableval = xyes -o x$enableval = xno; then
 237 dnl     support_afterstep=$enableval
 238 dnl   fi])
 239
 240 AC_ARG_ENABLE(transparency,
 241   [  --enable-transparency   enable transparent backgrounds],
 242   [if test x$enableval = xyes -o x$enableval = xno; then
 243     support_inheritpixmap=$enableval
 244   fi])
 245
 246 AC_ARG_ENABLE(fading,
 247   [  --enable-fading         enable colors fading when off focus],
 248   [if test x$enableval = xyes -o x$enableval = xno; then
 249     support_fading=$enableval
 250   fi])
 251
 252 AC_ARG_ENABLE(rxvt-scroll,
 253   [  --enable-rxvt-scroll    enable rxvt style scrollbar],
 254   [if test x$enableval = xyes -o x$enableval = xno; then
 255     support_scroll_rxvt=$enableval
 256   fi])
 257
 258 AC_ARG_ENABLE(next-scroll,
 259   [  --enable-next-scroll    enable NeXT style scrollbar],
 260   [if test x$enableval = xyes -o x$enableval = xno; then
 261     support_scroll_next=$enableval
 262   fi])
 263
 264 AC_ARG_ENABLE(xterm-scroll,
 265   [  --enable-xterm-scroll   enable Xterm style scrollbar],
 266   [if test x$enableval = xyes -o x$enableval = xno; then
 267     support_scroll_xterm=$enableval
 268   fi])
 269
 270 AC_ARG_ENABLE(perl,
 271   [  --enable-perl           enable embedded perl interpreter],
 272   [if test x$enableval = xyes -o x$enableval = xno; then
 273     support_perl=$enableval
 274   fi])
 275
 276 AC_ARG_ENABLE(plain-scroll,
 277   [  --enable-plain-scroll   enable plain style scrollbar],
 278   [if test x$enableval = xyes -o x$enableval = xno; then
 279     support_scroll_plain=$enableval
 280   fi])
 281
 282 AC_ARG_WITH(codesets,
 283   [  --with-codesets=NAME,.. compile in additional codesets (jp,jp_ext,kr,zh,zh_ext,all)],
 284   [codesets="$withval"])
 285
 286 AC_ARG_ENABLE(xim,
 287   [  --enable-xim            XIM (X Input Method) protocol support],
 288   [if test x$enableval = xyes -o x$enableval = xno; then
 289     support_xim=$enableval
 290   fi])
 291
 292 AC_ARG_ENABLE(backspace-key,
 293   [  --disable-backspace-key disable handling of the backspace key],
 294   [if test x$enableval = xno; then
 295     AC_DEFINE(NO_BACKSPACE_KEY, 1, Define if you don't want support for the backspace key)
 296   fi])
 297
 298 AC_ARG_ENABLE(delete-key,
 299   [  --disable-delete-key    disable handling of the delete key],
 300   [if test x$enableval = xno; then
 301     AC_DEFINE(NO_DELETE_KEY, 1, Define if you don't want support for the (non-keypad) delete key)
 302   fi])
 303
 304 AC_ARG_ENABLE(resources,
 305   [  --disable-resources     disable all resource checking],
 306   [if test x$enableval = xno; then
 307     AC_DEFINE(NO_RESOURCES, 1, Define if you don't want any resources read)
 308   fi])
 309
 310 AC_ARG_ENABLE(8bitctrls,
 311   [  --enable-8bitctrls      enable 8 bit control sequences (not recommended)],
 312   [if test x$enableval = xyes -o x$enableval = xno; then
 313     support_8bitctrls=$enableval
 314   fi])
 315
 316 RESFALLBACK=Rxvt
 317 AC_ARG_ENABLE(fallback,
 318   [  --enable-fallback(=CLASS) fall back on CLASS resources in addition to URxvt ones (default: Rxvt)],
 319   [
 320    test x$enableval = xyes && enableval=Rxvt
 321    test x$enableval = xno  && enableval=
 322    RESFALLBACK="$enableval"
 323   ])
 324
 325 if test x$RESFALLBACK != x; then
 326    AC_DEFINE_UNQUOTED(RESFALLBACK, "$RESFALLBACK", [Fallback resource class])
 327 fi
 328
 329 RESNAME=urxvt
 330 AC_ARG_WITH(res-name,
 331   [  --with-res-name=NAME    use this as default resource name (default: urxvt)],
 332   [RESNAME="$withval"])
 333 AC_DEFINE_UNQUOTED(RESNAME,"$RESNAME", [Default resource name])
 334
 335 RESCLASS=URxvt
 336 AC_ARG_WITH(res-class,
 337   [  --with-res-class=CLASS  use this as the resource class (default: URxvt)],
 338   [RESCLASS="$withval"])
 339 AC_DEFINE_UNQUOTED(RESCLASS,"$RESCLASS", [Resource class])
 340
 341 RXVTNAME=urxvt
 342 AC_ARG_WITH(name,
 343   [  --with-name=NAME        set the basename for the installed binaries (default: urxvt)],
 344   [RXVTNAME="$withval"])
 345 AC_DEFINE_UNQUOTED(RXVTNAME,"$RXVTNAME", [Binary base name])
 346
 347 RXVTNAME=`echo "$RXVTNAME"|sed "$program_transform_name"`
 348 AC_SUBST(RXVTNAME)
 349
 350 AC_ARG_ENABLE(swapscreen,
 351   [  --disable-swapscreen    disable swap screen support],
 352   [if test x$enableval = xno; then
 353     AC_DEFINE(NO_SECONDARY_SCREEN, 1, Disable the secondary screen. Many programs use the secondary screen as their workplace)
 354   fi])
 355
 356 AC_ARG_ENABLE(iso14755,
 357   [  --enable-iso14755       enable support for extended ISO 14755 modes],
 358   [if test x$enableval = xyes -o x$enableval = xno; then
 359     support_iso14755=$enableval
 360   fi])
 361
 362 AC_ARG_ENABLE(frills,
 363   [  --enable-frills         enable support for rarely used features],
 364   [if test x$enableval = xyes -o x$enableval = xno; then
 365     support_frills=$enableval
 366   fi])
 367
 368 AC_ARG_ENABLE(keepscrolling,
 369   [  --enable-keepscrolling  enable continual scrolling on scrollbar arrow press],
 370   [if test x$enableval = xyes -o x$enableval = xno; then
 371     support_keepscrolling=$enableval
 372   fi])
 373
 374 AC_ARG_ENABLE(selectionscrolling,
 375   [  --enable-selectionscrolling  enable scrolling during selections],
 376   [if test x$enableval = xyes -o x$enableval = xno; then
 377     support_selectionscrolling=$enableval
 378   fi])
 379
 380 AC_ARG_ENABLE(mousewheel,
 381   [  --enable-mousewheel     enable scrolling via mouse wheel or buttons 4 & 5],
 382   [if test x$enableval = xyes -o x$enableval = xno; then
 383     support_mousewheel=$enableval
 384   fi])
 385
 386 AC_ARG_ENABLE(slipwheeling,
 387   [  --enable-slipwheeling   enable slip wheel scrolling     (requires previous)],
 388   [if test x$enableval = xyes -o x$enableval = xno; then
 389     support_mouseslipwheel=$enableval
 390   fi])
 391
 392 AC_ARG_ENABLE(smart-resize,
 393   [  --enable-smart-resize   enable smart growth/shrink behaviour],
 394   [if test x$enableval = xyes; then
 395     AC_DEFINE(SMART_RESIZE, 1, Define to use "smart" resize behavior)
 396   fi])
 397
 398 AC_ARG_ENABLE(text-blink,
 399   [  --enable-text-blink     enable blinking text],
 400   [if test x$enableval = xyes -o x$enableval = xno; then
 401     support_text_blink=$enableval
 402   fi])
 403
 404 AC_ARG_ENABLE(pointer-blank,
 405   [  --enable-pointer-blank  enable pointer blank when typing or inactive pointer],
 406   [if test x$enableval = xyes -o x$enableval = xno; then
 407     support_pointer_blank=$enableval
 408   fi])
 409
 410 AC_ARG_WITH(term,
 411   [  --with-term=NAME        set the terminal to NAME (default: rxvt)],
 412   [if test x$withval != x; then
 413     AC_DEFINE_UNQUOTED(TERMENV, "$withval",Set TERM to the value given by configure) term="$withval"
 414   fi])
 415
 416 AC_ARG_WITH(terminfo,
 417   [  --with-terminfo=PATH    set the path to the terminfo tree to PATH],
 418   [if test x$withval != x; then
 419     AC_DEFINE_UNQUOTED(RXVT_TERMINFO, "$withval", Set TERMINFO value to the value given by configure) terminfo="$withval"
 420   fi])
 421
 422 dnl# --------------------------------------------------------------------------
 423
 424 AC_PATH_PROG(TIC, tic, :)
 425
 426 dnl# need a neat way to detect SVR4 or its features
 427 dnl# in src/command.c we use these functions:
 428 dnl# grantpt(), unlockpt(), ptsname(), which are defined in <sys/ptms.h>
 429 dnl# - but are these also defined for other systems?
 430
 431 dnl# hack to find if this is SVR4 -- who knows?
 432 dnl## AC_MSG_CHECKING(for SVR4)
 433 dnl## AC_EGREP_CPP(yes,
 434 dnl## [#if defined (SVR4) || defined (_SVR4) || defined (__svr4__)
 435 dnl##   yes;
 436 dnl## #endif
 437 dnl## ], [AC_MSG_RESULT(yes); AC_DEFINE(PERHAPS_SVR4)], AC_MSG_RESULT(perhaps not?))
 438
 439 AC_PATH_XTRA
 440
 441 AFTERIMAGE_CFLAGS=
 442 AFTERIMAGE_LIBS=
 443 AFTERIMAGE_VERSION=
 444
 445 if test x$support_afterimage = xyes; then
 446   support_afterimage=no
 447
 448   if test "x$afterimage_config" = "x" ; then
 449     AC_PATH_PROG(afterimage_config, afterimage-config, no)
 450   fi
 451   if test "x$afterimage_config" != "xno" ; then
 452     AC_MSG_CHECKING(for libAfterImage version >= 1.15)
 453     xAFTERIMAGE_VERSION=`$afterimage_config --version`
 454     if test -n "$xAFTERIMAGE_VERSION" ; then
 455       xAFTERIMAGE_CFLAGS=`$afterimage_config --cflags`
 456       xAFTERIMAGE_LIBS=`$afterimage_config --libs`
 457       if test "x$xAFTERIMAGE_LIBS" != "x"; then
 458         libai_ver_major=`echo $xAFTERIMAGE_VERSION | cut -f 1 -d .`
 459         libai_ver_minor=`echo $xAFTERIMAGE_VERSION | cut -f 2 -d .`
 460         if test $libai_ver_major -gt 1 -o \( $libai_ver_major -eq 1 -a $libai_ver_minor -ge 15 \); then
 461           support_afterimage=yes
 462           AFTERIMAGE_CFLAGS="$xAFTERIMAGE_CFLAGS"
 463           AFTERIMAGE_LIBS="$xAFTERIMAGE_LIBS"
 464           AFTERIMAGE_VERSION="$xAFTERIMAGE_VERSION"
 465         fi
 466       fi
 467     fi
 468     if test "x$support_afterimage" = "xyes"; then
 469       AC_MSG_RESULT($AFTERIMAGE_LIBS)
 470     else
 471       AC_MSG_RESULT(no)
 472     fi
 473   fi
 474 fi
 475
 476 dnl# --------------------------------------------------------------------------
 477 dnl# CHECKING FOR HEADER FILES
 478 dnl# --------------------------------------------------------------------------
 479 AC_HEADER_SYS_WAIT
 480 AC_CHECK_HEADERS( \
 481         assert.h \
 482         fcntl.h \
 483         stdarg.h \
 484         stdlib.h \
 485         string.h \
 486         termios.h \
 487         unistd.h \
 488         sys/byteorder.h \
 489         sys/ioctl.h \
 490         sys/select.h \
 491         sys/sockio.h \
 492         sys/strredir.h \
 493         sys/time.h \
 494         stdint.h \
 495         wchar.h \
 496         cwchar \
 497         clocale \
 498 )
 499
 500 AC_HEADER_TIME
 501
 502 dnl# check to allow both <termios.h> and <sys/ioctl.h>
 503 AC_CACHE_CHECK(whether termios.h and sys/ioctl.h may both be included, rxvt_cv_header_sysioctl,
 504 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 505 #include <sys/ioctl.h>
 506 #ifdef HAVE_TERMIOS_H
 507 #include <termios.h>
 508 #endif]], [[int a = ECHO;]])],[rxvt_cv_header_sysioctl=yes],[rxvt_cv_header_sysioctl=no])])
 509
 510 AC_CACHE_CHECK([for XPointer], rxvt_cv_xpointer,
 511 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XPointer dummy;]])],[rxvt_cv_xpointer=yes],[rxvt_cv_xpointer=no])])
 512 if test x$rxvt_cv_xpointer = xyes; then
 513   AC_DEFINE(HAVE_XPOINTER, 1, Define if you have XPointer typedef)
 514 fi
 515
 516 AC_CACHE_CHECK([for XLIB_ILLEGAL_ACCESS], rxvt_xlib_illegal_access,
 517 [AC_COMPILE_IFELSE(
 518    [AC_LANG_PROGRAM([
 519 #define XLIB_ILLEGAL_ACCESS
 520 #include <X11/Xlib.h>
 521    ],[
 522       Display *dpy;
 523       dpy->xdefaults = (char *)0;
 524    ])],
 525    [rxvt_xlib_illegal_access=yes],[rxvt_xlib_illegal_access=no]
 526 )])
 527 if test x$rxvt_xlib_illegal_access = xyes; then
 528    AC_DEFINE(XLIB_ILLEGAL_ACCESS, 1, Define ONLY iff Xlib.h supports it)
 529 fi
 530
 531 AC_C_CONST
 532 AC_C_INLINE
 533
 534 dnl> AC_HEADER_STDC      dnl# skip this test, Sun always fails anyhow.
 535
 536 dnl# --------------------------------------------------------------------------
 537 dnl# CHECKING FOR MISSING TYPEDEFS
 538 dnl# --------------------------------------------------------------------------
 539 dnl# Missing typedefs and replacements
 540 AC_TYPE_MODE_T
 541 dnl> AC_CHECK_TYPE(umode_t, int)
 542 dnl> AC_CHECK_TYPE(off_t, long)
 543 AC_TYPE_PID_T
 544 AC_TYPE_UID_T
 545
 546 AC_CHECK_SIZEOF(short, 2)
 547 AC_CHECK_SIZEOF(int, 4)
 548 dnl AC_CHECK_SIZEOF(long, 4)
 549 AC_CHECK_SIZEOF(long long, 8)
 550 AC_CHECK_SIZEOF(int *, 4)
 551
 552 dnl# see usage below
 553 AC_DEFUN([RXVT_CHECK_SIZE],
 554   [AC_CACHE_CHECK([for $2], $1,
 555     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdint.h>]], [[$2 dummy;]])],[$1=yes],[dnl
 556 if test "$ac_cv_sizeof_char" -ge $3; then
 557   $1="$4 char"
 558 else
 559   if test "$ac_cv_sizeof_short" -ge $3; then
 560     $1="$4 short"
 561   else
 562     if test "$ac_cv_sizeof_int" -ge $3; then
 563       $1="$4 int"
 564     else
 565       if test "$ac_cv_sizeof_long" -ge $3; then
 566         $1="$4 long"
 567       else
 568         if test "$ac_cv_sizeof_long_long" -ge $3; then
 569           $1="$4 long long"
 570         else
 571           $1="$4 $5" # we _must_ have a (possibly wrong) default
 572         fi
 573       fi
 574     fi
 575   fi
 576 fi])])]
 577 if test x"$$1" != xyes; then
 578   $6="typedef $$1 $2;"
 579 else
 580   if test x"$4" = x; then
 581     $6="/* typedef $5 $2; */"
 582   else
 583     $6="/* typedef $4 $5 $2; */"
 584   fi
 585 fi dnl
 586 )
 587 dnl#
 588 dnl# Look for types the system may know about anyway.
 589 dnl#
 590 RXVT_CHECK_SIZE(rxvt_cv_int16_t, int16_t, 2, , short, rxvt_int16_typedef)
 591 AC_SUBST(rxvt_int16_typedef)
 592 RXVT_CHECK_SIZE(rxvt_cv_uint16_t, uint16_t, 2, unsigned, short, rxvt_uint16_typedef)
 593 AC_SUBST(rxvt_uint16_typedef)
 594 RXVT_CHECK_SIZE(rxvt_cv_int32_t, int32_t, 4, , int, rxvt_int32_typedef)
 595 AC_SUBST(rxvt_int32_typedef)
 596 RXVT_CHECK_SIZE(rxvt_cv_uint32_t, uint32_t, 4, unsigned, int, rxvt_uint32_typedef)
 597 AC_SUBST(rxvt_uint32_typedef)
 598 dnl RXVT_CHECK_SIZE(rxvt_cv_int64_t, int64_t, 8, , long long, rxvt_int64_typedef)
 599 dnl AC_SUBST(rxvt_int64_typedef)
 600 dnl RXVT_CHECK_SIZE(rxvt_cv_uint64_t, uint64_t, 8, unsigned, long long, rxvt_uint64_typedef)
 601 dnl AC_SUBST(rxvt_uint64_typedef)
 602 dnl#
 603 dnl# Now look for another we use
 604 dnl#
 605 if test "$ac_cv_sizeof_int_p" -eq 8; then
 606   rxvt_intp_define="#define intp_t int64_t"
 607   rxvt_u_intp_define="#define u_intp_t u_int64_t"
 608 else
 609   if test "$ac_cv_sizeof_int_p" -eq 4; then
 610     rxvt_intp_define="#define intp_t int32_t"
 611     rxvt_u_intp_define="#define u_intp_t u_int32_t"
 612   else
 613     if test "$ac_cv_sizeof_int_p" -eq 2; then
 614       rxvt_intp_define="#define intp_t int16_t"
 615       rxvt_u_intp_define="#define u_intp_t u_int16_t"
 616     else
 617       rxvt_intp_define="#error set intp_t"
 618       rxvt_u_intp_define="#error set u_intp_t"
 619     fi
 620   fi
 621 fi
 622 AC_SUBST(rxvt_intp_define)
 623 AC_SUBST(rxvt_u_intp_define)
 624
 625 dnl# --------------------------------------------------------------------------
 626 dnl# CHECKING FOR LIBRARY FUNCTIONS
 627 dnl# --------------------------------------------------------------------------
 628 AC_TYPE_SIGNAL
 629 dnl> AC_FUNC_VPRINTF
 630
 631 AC_CHECK_FUNCS( \
 632         unsetenv \
 633         setutent \
 634         on_exit \
 635 )
 636
 637 UTMP_CHECK
 638
 639 dnl# --------------------------------------------------------------------------
 640
 641 dnl# find ttys/ttytab
 642 AC_CACHE_CHECK(where ttys/ttytab is located, rxvt_cv_path_ttytab,
 643 [for ttys_file in   dnl
 644   /etc/ttys /etc/ttytab;
 645 do
 646   if test -f "$ttys_file" ; then
 647     rxvt_cv_path_ttytab=$ttys_file
 648     break
 649   fi
 650 done
 651 ])
 652 if test x$rxvt_cv_path_ttytab != x; then
 653   AC_DEFINE_UNQUOTED(TTYTAB_FILENAME, "$rxvt_cv_path_ttytab", Define location of ttys/ttytab)
 654 fi
 655
 656 dnl# --------------------------------------------------------------------------
 657 dnl# --------------------------------------------------------------------------
 658
 659 dnl# this is a really hack test for some basic Xlocale stuff
 660 ac_save_LIBS=$LIBS
 661 ac_save_CFLAGS=$CFLAGS
 662 CFLAGS="$CFLAGS $X_CFLAGS"
 663 LIBS="$LIBS $X_LIBS $X_EXTRA_LIBS -lX11"
 664 if test x$support_xim = xyes; then
 665   AC_CACHE_CHECK(for working Xlocale, rxvt_cv_func_xlocale,
 666   [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <X11/Xlib.h>
 667   #include <stdlib.h>
 668   main() {
 669   char *p;
 670   if ((p = XSetLocaleModifiers("@im=none")) != NULL && *p)
 671   exit (XSupportsLocale() ? 0 : 1);
 672   else
 673   exit (1);}]])],[dnl
 674     rxvt_cv_func_xlocale=yes],[rxvt_cv_func_xlocale=no],[dnl
 675     :])])
 676   if test x$rxvt_cv_func_xlocale = xyes; then
 677     AC_DEFINE(USE_XIM, 1, Define if you want to have XIM (X Input Method) protocol support - required for multibyte characters input)
 678     AC_CACHE_CHECK(for broken XIM callback, rxvt_broken_ximcb,
 679     [AC_COMPILE_IFELSE([
 680     #include <X11/Xlib.h>
 681
 682     void im_destroy_cb (XIC unused1, XPointer client_data, XPointer unused3);
 683
 684     void f() {
 685       XIMCallback cb;
 686       cb.callback = im_destroy_cb;
 687     }
 688     ],rxvt_broken_ximcb=yes,rxvt_broken_ximcb=no)])
 689
 690     if test x$rxvt_broken_ximcb = xyes; then
 691        AC_DEFINE(XIMCB_PROTO_BROKEN, 1, Define if your XIMCallback specifies XIC as first type.)
 692     fi
 693   fi
 694 fi
 695
 696 AC_CACHE_CHECK(for working X setlocale, rxvt_cv_func_xsetlocale,
 697 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define X_LOCALE 1
 698 #include <X11/Xlocale.h>]], [[setlocale(LC_CTYPE, "");]])],[rxvt_cv_func_xsetlocale=yes],[rxvt_cv_func_xsetlocale=no])])
 699 if test x$rxvt_cv_func_xsetlocale = xyes; then
 700   AC_DEFINE(HAVE_XSETLOCALE, 1, Define if setlocale (defined to Xsetlocale) works)
 701 fi
 702 LIBS=$ac_save_LIBS
 703 CFLAGS=$ac_save_CFLAGS
 704
 705 AC_CACHE_CHECK(for working plain setlocale, rxvt_cv_func_setlocale,
 706 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <clocale>]], [[setlocale(LC_CTYPE, "");]])],[rxvt_cv_func_setlocale=yes],[rxvt_cv_func_setlocale=no])])
 707 if test x$rxvt_cv_func_setlocale = xyes; then
 708   AC_DEFINE(HAVE_SETLOCALE, 1, Define if plain old setlocale works)
 709 fi
 710
 711 AC_CACHE_CHECK(for working nl_langinfo, rxvt_cv_func_nl_langinfo,
 712 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(CODESET);]])],[rxvt_cv_func_nl_langinfo=yes],[rxvt_cv_func_nl_langinfo=no])])
 713 if test x$rxvt_cv_func_nl_langinfo = xyes; then
 714   AC_DEFINE(HAVE_NL_LANGINFO, 1, Define if nl_langinfo(CODESET) works)
 715 fi
 716
 717 SCM_RIGHTS_CHECK
 718
 719 PTY_CHECK
 720
 721 TTY_GROUP_CHECK
 722
 723 dnl# --------------------------------------------------------------------------
 724 dnl# now add and remove other stuff
 725 dnl# --------------------------------------------------------------------------
 726 if test x$support_xft = xyes; then
 727   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 728   if test $PKG_CONFIG != no && $PKG_CONFIG --exists xft; then
 729     LIBS="$LIBS `$PKG_CONFIG xft --libs`"
 730     CPPFLAGS="$CPPFLAGS `$PKG_CONFIG xft --cflags`"
 731   else
 732     AC_PATH_PROG(XFT_CONFIG, xft-config, no)
 733     if test $XFT_CONFIG != no; then
 734       LIBS="$LIBS `$XFT_CONFIG --libs`"
 735       CPPFLAGS="$CPPFLAGS `$XFT_CONFIG --cflags`"
 736     fi
 737   fi
 738
 739   AC_CHECK_HEADERS(X11/Xft/Xft.h,,[support_xft=no])
 740   AC_CHECK_LIB(Xft,XftDrawString32,,[support_xft=no])
 741
 742   if test x$support_xft = xyes; then
 743     AC_DEFINE(XFT, 1, Define to enable xft support)
 744   fi
 745 fi
 746 if test x$support_styles = xyes; then
 747   AC_DEFINE(ENABLE_STYLES, 1, Define if you want bold and italic support)
 748 fi
 749 if test x$support_iso14755 = xyes; then
 750   AC_DEFINE(ISO_14755, 1, Define if you want ISO 14755 extended support)
 751 fi
 752 if test x$support_8bitctrls = xyes; then
 753   AC_DEFINE(EIGHT_BIT_CONTROLS, 1, Define if you want 8 bit control sequences)
 754 fi
 755 if test x$support_fading = xyes; then
 756   AC_DEFINE(OFF_FOCUS_FADING, 1, Define if you want faded colors when focus is lost)
 757 fi
 758 if test x$support_inheritpixmap = xyes; then
 759   AC_DEFINE(ENABLE_TRANSPARENCY, 1, Define if you want your background to use the parent window background)
 760 fi
 761 if test x$support_keepscrolling = xno; then
 762   AC_DEFINE(NO_SCROLLBAR_BUTTON_CONTINUAL_SCROLLING, 1, Define for continual scrolling when you keep the scrollbar button pressed)
 763 fi
 764 if test x$support_selectionscrolling = xyes; then
 765   AC_DEFINE(SELECTION_SCROLLING, 1, Define to allow scrolling when the selection moves to the top or bottom of the screen)
 766 fi
 767 if test x$support_frills = xyes; then
 768   AC_DEFINE(ENABLE_FRILLS, 1, Define if you want handling for rarely used but handy features)
 769 fi
 770 if test x$support_mousewheel = xyes; then
 771   AC_DEFINE(MOUSE_WHEEL, 1, Define to use wheel events (button4 and button5) to scroll)
 772 fi
 773 if test x$support_mouseslipwheel = xyes; then
 774   AC_DEFINE(MOUSE_SLIP_WHEELING, 1, Define to have CTRL cause wheel events to accelerate scrolling. Release CTRL to halt scrolling)
 775 fi
 776 if test x$support_afterimage = xyes; then
 777   AC_DEFINE(HAVE_AFTERIMAGE, 1, Define if you want to use libAfterImage for image processing)
 778   AC_DEFINE(BG_IMAGE_FROM_FILE, 1, Define if you want to have sexy-looking background pixmaps. Needs libAfterImage)
 779 fi
 780
 781 dnl if test x$support_afterstep = xyes; then
 782 dnl   AC_DEFINE(AFTERSTEP_INTEGRATION, 1, Define if you want to integrate with AfterStep window manager)
 783 dnl fi
 784
 785 if test x$support_scroll_rxvt = xyes; then
 786   AC_DEFINE(RXVT_SCROLLBAR, 1, Support Rxvt original style scrollbars)
 787   scrolltypes="rxvt"
 788 fi
 789 if test x$support_scroll_next = xyes; then
 790   AC_DEFINE(NEXT_SCROLLBAR, 1, Support NeXT style scrollbars)
 791   scrolltypes="$scrolltypes next"
 792 fi
 793 if test x$support_scroll_xterm = xyes; then
 794   AC_DEFINE(XTERM_SCROLLBAR, 1, Support Xterm style scrollbars)
 795   scrolltypes="$scrolltypes xterm"
 796 fi
 797 if test x$support_scroll_plain = xyes; then
 798   AC_DEFINE(PLAIN_SCROLLBAR, 1, Support plain style scrollbars)
 799   scrolltypes="$scrolltypes plain"
 800 fi
 801 if test x$support_pointer_blank = xyes; then
 802   AC_DEFINE(POINTER_BLANK, 1, Define if you want hide the pointer while typing)
 803 fi
 804 if test x$support_text_blink = xyes; then
 805   AC_DEFINE(TEXT_BLINK, 1, Define if you want blinking text support)
 806 fi
 807 if test x$support_unicode3 = xyes; then
 808   AC_DEFINE(UNICODE_3, 1, Define if you want to represent unicode characters outside plane 0)
 809 fi
 810 if test x$support_combining = xyes; then
 811   AC_DEFINE(ENABLE_COMBINING, 1, Define if you want to automatically compose combining characters)
 812 fi
 813 if test x$codesets = xall; then
 814   codesets=jp,jp-ext,kr,zh,zh-ext
 815 fi
 816 AC_DEFINE(ENCODING_EU, 1, Define if you want european extended codesets)
 817 AC_DEFINE(ENCODING_VN, 1, Define if you want vietnamese codesets)
 818 for codeset in `echo $codesets | tr "[a-z,\\-]" "[A-Z _]"`; do
 819   case "$codeset" in
 820     JP     ) AC_DEFINE(ENCODING_JP,     1, Define if you want japanese codesets) ;;
 821     JP_EXT ) AC_DEFINE(ENCODING_JP_EXT, 1, Define if you want extended japanese codesets) ;;
 822     KR     ) AC_DEFINE(ENCODING_KR,     1, Define if you want korean codesets) ;;
 823     ZH     ) AC_DEFINE(ENCODING_ZH,     1, Define if you want chinese codesets) ;;
 824     ZH_EXT ) AC_DEFINE(ENCODING_ZH_EXT, 1, Define if you want extended chinese codesets) ;;
 825   esac
 826 done
 827
 828 IF_PERL=\#
 829 if test x$support_perl = xyes; then
 830   AC_PATH_PROG(PERL, perl5)
 831   AC_PATH_PROG(PERL, perl)
 832
 833   AC_MSG_CHECKING(for $PERL suitability)
 834   if $PERL -MExtUtils::Embed -e "use v5.8" >/dev/null 2>/dev/null; then
 835
 836      save_CXXFLAGS="$CXXFLAGS"
 837      save_LIBS="$LIBS"
 838      CXXFLAGS="$CXXFLAGS `$PERL -MExtUtils::Embed -e ccopts`"
 839      LIBS="$LIBS `$PERL -MExtUtils::Embed -e ldopts`"
 840      AC_TRY_LINK([
 841 #include <EXTERN.h>
 842 #include <perl.h>
 843 #include <XSUB.h>
 844 ],[
 845      PerlInterpreter *perl = perl_alloc ();
 846 ],[rxvt_perl_link=yes],[rxvt_perl_link=no])
 847      CXXFLAGS="$save_CXXFLAGS"
 848      LIBS="$save_LIBS"
 849
 850      if test x$rxvt_perl_link = xyes; then
 851         AC_MSG_RESULT(ok)
 852         AC_DEFINE(ENABLE_PERL, 1, Define if you can embed a perl interpreter)
 853         IF_PERL=
 854         PERL_O=rxvtperl.o
 855         PERLFLAGS="`$PERL -MExtUtils::Embed -e ccopts`"
 856         PERLLIB="`$PERL -MExtUtils::Embed -e ldopts`"
 857         PERLPRIVLIBEXP="`$PERL -MConfig -e 'print $Config{privlibexp}'`"
 858      else
 859         AC_MSG_ERROR([no, unable to link])
 860      fi
 861   else
 862      AC_MSG_ERROR([no working perl found, or perl not version >= 5.8])
 863   fi
 864 fi
 865 AC_SUBST(PERLLIB)
 866 AC_SUBST(PERLFLAGS)
 867 AC_SUBST(PERLPRIVLIBEXP)
 868 AC_SUBST(PERL)
 869 AC_SUBST(IF_PERL)
 870 AC_SUBST(PERL_O)
 871
 872 AC_SUBST(CFLAGS)
 873 AC_SUBST(CPPFLAGS)
 874 AC_SUBST(LDFLAGS)
 875 AC_SUBST(X_CFLAGS)
 876
 877 dnl# Attack the libs
 878 AC_SUBST(LIBS)
 879 AC_SUBST(X_LIBS)
 880 AC_SUBST(X_EXTRA_LIBS)
 881
 882 AC_SUBST(AFTERIMAGE_CFLAGS)
 883 AC_SUBST(AFTERIMAGE_LIBS)
 884
 885 AC_ARG_PROGRAM
 886
 887 dnl# test for "sun" or "__sun__" before include sys_ioctl
 888
 889 dnl# revert HAVE_BLAH_H into a "#include <blah.h>"
 890 AC_DEFUN([RXVT_DEFINE_TO_INCLUDE], dnl
 891 [if test "$$3" = "$4" -o "$$5" = "$6"; then
 892   $1="#include <$2>"
 893 else
 894   $1="/* #include <$2> */"
 895 fi dnl
 896 AC_SUBST($1)])
 897
 898 RXVT_DEFINE_TO_INCLUDE(include_stdint_h, stdint.h, ac_cv_header_stdint_h, yes, notset, dontmatch)
 899 RXVT_DEFINE_TO_INCLUDE(include_stdarg_h, cstdarg, ac_cv_header_stdarg_h, yes, notset, dontmatch)
 900 RXVT_DEFINE_TO_INCLUDE(include_stdlib_h, cstdlib, ac_cv_header_stdlib_h, yes, notset, dontmatch)
 901 RXVT_DEFINE_TO_INCLUDE(include_unistd_h, unistd.h, ac_cv_header_unistd_h, yes, notset, dontmatch)
 902 RXVT_DEFINE_TO_INCLUDE(include_string_h, cstring, ac_cv_header_string_h, yes, notset, dontmatch)
 903 RXVT_DEFINE_TO_INCLUDE(include_fcntl_h, fcntl.h, ac_cv_header_fcntl_h, yes, notset, dontmatch)
 904 RXVT_DEFINE_TO_INCLUDE(include_util_h, util.h, ac_cv_header_util_h, yes, notset, dontmatch)
 905 RXVT_DEFINE_TO_INCLUDE(include_assert_h, assert.h, ac_cv_header_assert_h, yes, notset, dontmatch)
 906 RXVT_DEFINE_TO_INCLUDE(include_sys_ioctl_h, sys/ioctl.h, rxvt_cv_header_sysioctl, yes, notset, dontmatch)
 907 RXVT_DEFINE_TO_INCLUDE(include_sys_select_h, sys/select.h, ac_cv_header_sys_select_h, yes, notset, dontmatch)
 908 RXVT_DEFINE_TO_INCLUDE(include_sys_strredir_h, sys/strredir.h, ac_cv_header_sys_strredir_h, yes, notset, dontmatch)
 909 RXVT_DEFINE_TO_INCLUDE(include_sys_time_h, sys/time.h, ac_cv_header_sys_time_h, yes, notset, dontmatch)
 910 RXVT_DEFINE_TO_INCLUDE(include_time_h, time.h, ac_cv_header_sys_time_h, no, ac_cv_header_time, yes)
 911
 912 AC_CONFIG_FILES([Makefile \
 913 doc/Makefile \
 914 src/Makefile \
 915 src/rxvtlib.h \
 916 ])
 917 AC_OUTPUT
 918
 919 echo "Configuration:
 920
 921   Rxvt version:               $VERSION : $DATE
 922   Source code location:       $srcdir
 923   Install path:               ${prefix}/bin
 924   Compiler:                   $CXX
 925   Compiler flags:             $CXXFLAGS
 926   Linker:                     $LINKER"
 927
 928 if test x$term != x; then
 929   echo "  set TERM to:                $term"
 930 fi
 931 if test x$terminfo != x; then
 932   echo "  set TERMINFO to:            $terminfo"
 933 fi
 934 echo "  default resource name:      $RESNAME"
 935 echo "  resource class:             $RESCLASS"
 936 if test x$RESFALLBACK != x; then
 937    echo "  resource class fallback:    $RESFALLBACK"
 938 fi
 939 echo
 940 echo "  embedded perl:              $support_perl"
 941 echo "  libafterimage:              $support_afterimage"
 942 dnl echo "  AfterStep integration:      $support_afterstep"
 943 echo
 944 if test x$support_xim = xyes -a x$rxvt_cv_func_xlocale = xno; then
 945   echo ".----------------------------------------------------------------."
 946   echo ". WARNING: --enable-xim was specified however the locale support ."
 947   echo ".          functions could not be found.                         ."
 948   echo ".          XIM is now being DISABLED!                            ."
 949   echo ".----------------------------------------------------------------."
 950 fi
 951
 952 echo "*** Optionally check src/feature.h for further, rarely used options ***"
 953 echo
 954