configure.ac

   1 dnl#
   2 dnl# Process this file with autoconf to produce a configure script.
   3 dnl#
   4
   5 AC_INIT
   6 AC_PREREQ(2.50)
   7 AC_CONFIG_SRCDIR([src/feature.h])
   8 AC_CONFIG_HEADER(config.h:config.h.in)
   9
  10 AC_CANONICAL_HOST
  11
  12 dnl RXVT version
  13 changequote(, )dnl
  14 VERSION=`sed -n -e 's/^.*[ \t]VERSION.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  15 DATE=`sed -n -e 's/^.*[ \t]DATE.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  16 dnl LIBVERSION=`sed -n -e 's/^.*[ \t]LIBVERSION.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  17 changequote([, ])dnl
  18 AC_SUBST(VERSION)dnl
  19 AC_SUBST(DATE)dnl
  20 AC_SUBST(LSMDATE)dnl
  21 AC_SUBST(LIBVERSION)dnl
  22 echo ""
  23 echo "configuring for rxvt $VERSION"
  24 echo ""
  25
  26 orig_CXXFLAGS="$CXXFLAGS"
  27
  28 dnl# Checks for programs.
  29 dnl AC_MAKE_SET
  30
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_PROG_CPP
  34 AC_PROG_INSTALL
  35
  36 AC_AIX
  37 AC_ISC_POSIX
  38 AC_LANG(C++)
  39
  40 dnl check wether we can link with gcc -lsupc++
  41 if test x$GCC = xyes && test x$GXX = xyes; then
  42    dnl FreeBSD (at least up to 5.3) has a broken GCC, workaround it
  43    AC_MSG_CHECKING([for working libsupc++])
  44    save_CXX="$CXX"
  45    save_LIBS="$LIBS"
  46    CXX="$CC"
  47    LIBS="$LIBS -lsupc++"
  48    LINKER="$CC"
  49    AC_LINK_IFELSE(
  50       [AC_LANG_PROGRAM([struct test { }; void f() try { throw new test; } catch (...) { throw; }],[])],
  51       [AC_MSG_RESULT(ok)],
  52       [
  53          AC_MSG_RESULT([no, making everything bigger and slower])
  54          LIBS="$save_LIBS"
  55          LINKER="$save_CXX"
  56       ]
  57    )
  58    CXX="$save_CXX"
  59 fi
  60 AC_SUBST(LINKER,[$LINKER])
  61
  62 dnl# --------------------------------------------------------------------------
  63 dnl# Supply default CXXFLAGS, if not specified by `CXXFLAGS=flags ./configure'
  64 dnl#
  65 if test -z "$orig_CXXFLAGS"; then
  66   if test x$GCC = xyes && test "x$GXX" = xyes; then
  67      CXXFLAGS="-g -O3 -fno-threadsafe-statics -fno-enforce-eh-specs"
  68     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [], [CXXFLAGS="-g -O3"])
  69   else
  70     CXXFLAGS="-O"
  71   fi
  72   CFLAGS="$CXXFLAGS"
  73 fi
  74
  75 AC_DEFINE(_GNU_SOURCE, 1, Use all glibc features.)
  76
  77 case $host in
  78    *-*-solaris* )
  79       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  80       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  81       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  82       ;;
  83 esac
  84
  85 dnl if test x$GXX = xyes; then
  86 dnl    CXXFLAGS="$CXXFLAGS" dnl I once had -fno-exceptions, but I am using them now...
  87 dnl fi
  88
  89 dnl# FreeBSD needs to link libxpg4
  90 AC_CHECK_FUNC(setlocale,     [], [AC_CHECK_LIB(xpg4,   setlocale,     [LIBS="$LIBS -lxpg4"])])
  91
  92 dnl# solaris needs to link libnsl and socket
  93 AC_CHECK_FUNC(gethostbyname, [], [AC_CHECK_LIB(nsl,    gethostbyname, [LIBS="$LIBS -lnsl"])])
  94 AC_CHECK_FUNC(socket,        [], [AC_CHECK_LIB(socket, socket,        [LIBS="$LIBS -lsocket"])])
  95
  96 dnl AC_ENABLE_SHARED(no)dnl#    libtool
  97 dnl AC_ENABLE_STATIC(yes)dnl#   libtool
  98 dnl AC_PROG_LIBTOOL()dnl#               libtool
  99
 100 support_frills=yes
 101 support_inheritpixmap=yes
 102 support_tinting=yes
 103 support_fading=yes
 104 support_keepscrolling=yes
 105 support_selectionscrolling=yes
 106 support_mousewheel=yes
 107 support_mouseslipwheel=yes
 108 support_text_blink=yes
 109 support_pointer_blank=yes
 110 support_scroll_rxvt=yes
 111 support_scroll_next=yes
 112 support_scroll_xterm=yes
 113 support_scroll_plain=yes
 114 support_xim=yes
 115 support_xpm=yes
 116 support_afterimage=yes
 117 support_afterstep=yes
 118 support_xft=yes
 119 support_unicode3=no
 120 support_combining=yes
 121 support_8bitctrls=no
 122 support_iso14755=yes
 123 support_styles=yes
 124 support_perl=yes
 125 codesets=all
 126
 127 dnl# --------------------------------------------------------------------------
 128 dnl# CHECKING COMMAND LINE OPTIONS
 129 dnl# --------------------------------------------------------------------------
 130
 131 if test "x$enable_shared" = xyes; then
 132     AC_DEFINE(LIBRXVT, 1, Build shared library version - specify via configure only)
 133     INSTALL_LIBRXVT=yes
 134 fi
 135 AC_SUBST(INSTALL_LIBRXVT)
 136
 137 AC_ARG_ENABLE(everything,
 138   [  --enable-everything     enable standard non-multichoice features
 139                      NOTE: this option is order dependent
 140                      NOTE: automatically enabled with --enable-shared],
 141   [
 142     if test x$enableval = xno; then
 143        support_frills=no
 144        support_inheritpixmap=no
 145        support_tinting=no
 146        support_fading=no
 147        support_keepscrolling=no
 148        support_selectionscrolling=no
 149        support_lastlog=no
 150        support_mousewheel=no
 151        support_mouseslipwheel=no
 152        support_text_blink=no
 153        support_pointer_blank=no
 154        support_scroll_rxvt=no
 155        support_scroll_next=no
 156        support_scroll_xterm=no
 157        support_scroll_plain=no
 158        support_utmp=no
 159        support_wtmp=no
 160        support_xim=no
 161        support_xpm=no
 162        support_afterimage=no
 163        support_afterstep=no
 164        support_xft=no
 165        support_unicode3=no
 166        support_combining=no
 167        support_8bitctrls=no
 168        support_iso14755=no
 169        support_styles=no
 170        support_perl=no
 171        codesets=
 172     fi
 173     if test x$enableval = xyes; then
 174        support_frills=yes
 175        support_inheritpixmap=yes
 176        support_tinting=yes
 177        support_fading=yes
 178        support_keepscrolling=yes
 179        support_selectionscrolling=yes
 180        support_lastlog=yes
 181        support_mousewheel=yes
 182        support_mouseslipwheel=yes
 183        support_text_blink=yes
 184        support_pointer_blank=yes
 185        support_scroll_rxvt=yes
 186        support_scroll_next=yes
 187        support_scroll_xterm=yes
 188        support_scroll_plain=yes
 189        support_utmp=yes
 190        support_wtmp=yes
 191        support_xim=yes
 192        support_xpm=yes
 193        support_afterimage=yes
 194        support_afterstep=yes
 195        support_xft=yes
 196        support_unicode3=yes
 197        support_combining=yes
 198        #support_8bitctrls=yes
 199        support_iso14755=yes
 200        support_styles=yes
 201        support_perl=yes
 202        codesets=all
 203     fi
 204   ])
 205
 206 AC_ARG_ENABLE(unicode3,
 207   [  --enable-unicode3       use 21 instead of 16 bits to represent unicode characters],
 208   [if test x$enableval = xyes -o x$enableval = xno; then
 209     support_unicode3=$enableval
 210   fi])
 211
 212 AC_ARG_ENABLE(combining,
 213   [  --enable-combining      enable composition of base and combining characters],
 214   [if test x$enableval = xyes -o x$enableval = xno; then
 215     support_combining=$enableval
 216   fi])
 217
 218 AC_ARG_ENABLE(xft,
 219   [  --enable-xft            enable xft support on systems that have it],
 220   [if test x$enableval = xyes -o x$enableval = xno; then
 221     support_xft=$enableval
 222   fi])
 223
 224 AC_ARG_ENABLE(font-styles,
 225   [  --enable-font-styles    enable bold and italic support],
 226   [if test x$enableval = xyes -o x$enableval = xno; then
 227     support_styles=$enableval
 228   fi])
 229
 230 AC_ARG_ENABLE(xpm-background,
 231   [  --enable-xpm-background enable background pixmaps],
 232   [if test x$enableval = xyes -o x$enableval = xno; then
 233     support_xpm=$enableval
 234   fi])
 235
 236 AC_ARG_ENABLE(afterimage,
 237   [  --enable-afterimage enable integration with libAfterImage for background images],
 238   [if test x$enableval = xyes -o x$enableval = xno; then
 239     support_afterimage=$enableval
 240   fi])
 241
 242 AC_ARG_WITH(afterimage_config,  [  --with-afterimage-config=DIR  use libAfterImage config script in DIR], afterimage_config="$withval",afterimage_config=NO)
 243
 244 AC_ARG_ENABLE(afterstep,
 245   [  --enable-afterstep enable integration with AfterStep window manager],
 246   [if test x$enableval = xyes -o x$enableval = xno; then
 247     support_afterstep=$enableval
 248   fi])
 249
 250 AC_ARG_ENABLE(transparency,
 251   [  --enable-transparency   enable transparent backgrounds],
 252   [if test x$enableval = xyes -o x$enableval = xno; then
 253     support_inheritpixmap=$enableval
 254   fi])
 255
 256 AC_ARG_ENABLE(tinting,
 257   [  --enable-tinting        enable tinting of transparent bg],
 258   [if test x$enableval = xyes -o x$enableval = xno; then
 259     support_tinting=$enableval
 260   fi])
 261
 262 AC_ARG_ENABLE(fading,
 263   [  --enable-fading         enable colors fading when off focus],
 264   [if test x$enableval = xyes -o x$enableval = xno; then
 265     support_fading=$enableval
 266   fi])
 267
 268 AC_ARG_ENABLE(rxvt-scroll,
 269   [  --enable-rxvt-scroll    enable rxvt style scrollbar],
 270   [if test x$enableval = xyes -o x$enableval = xno; then
 271     support_scroll_rxvt=$enableval
 272   fi])
 273
 274 AC_ARG_ENABLE(next-scroll,
 275   [  --enable-next-scroll    enable NeXT style scrollbar],
 276   [if test x$enableval = xyes -o x$enableval = xno; then
 277     support_scroll_next=$enableval
 278   fi])
 279
 280 AC_ARG_ENABLE(xterm-scroll,
 281   [  --enable-xterm-scroll   enable Xterm style scrollbar],
 282   [if test x$enableval = xyes -o x$enableval = xno; then
 283     support_scroll_xterm=$enableval
 284   fi])
 285
 286 AC_ARG_ENABLE(perl,
 287   [  --enable-perl           enable embedded perl interpreter],
 288   [if test x$enableval = xyes -o x$enableval = xno; then
 289     support_perl=$enableval
 290   fi])
 291
 292 AC_ARG_ENABLE(plain-scroll,
 293   [  --enable-plain-scroll   enable plain style scrollbar],
 294   [if test x$enableval = xyes -o x$enableval = xno; then
 295     support_scroll_plain=$enableval
 296   fi])
 297
 298 AC_ARG_WITH(codesets,
 299   [  --with-codesets=NAME,.. compile in additional codesets (jp,jp_ext,kr,zh,zh_ext,all)],
 300   [codesets="$withval"])
 301
 302 AC_ARG_ENABLE(xim,
 303   [  --enable-xim            XIM (X Input Method) protocol support],
 304   [if test x$enableval = xyes -o x$enableval = xno; then
 305     support_xim=$enableval
 306   fi])
 307
 308 AC_ARG_ENABLE(backspace-key,
 309   [  --disable-backspace-key disable handling of the backspace key],
 310   [if test x$enableval = xno; then
 311     AC_DEFINE(NO_BACKSPACE_KEY, 1, Define if you don't want support for the backspace key)
 312   fi])
 313
 314 AC_ARG_ENABLE(delete-key,
 315   [  --disable-delete-key    disable handling of the delete key],
 316   [if test x$enableval = xno; then
 317     AC_DEFINE(NO_DELETE_KEY, 1, Define if you don't want support for the (non-keypad) delete key)
 318   fi])
 319
 320 AC_ARG_ENABLE(resources,
 321   [  --disable-resources     disable all resource checking],
 322   [if test x$enableval = xno; then
 323     AC_DEFINE(NO_RESOURCES, 1, Define if you don't want any resources read)
 324   fi])
 325
 326 AC_ARG_ENABLE(8bitctrls,
 327   [  --enable-8bitctrls      enable 8 bit control sequences (not recommended)],
 328   [if test x$enableval = xyes -o x$enableval = xno; then
 329     support_8bitctrls=$enableval
 330   fi])
 331
 332 RESFALLBACK=Rxvt
 333 AC_ARG_ENABLE(fallback,
 334   [  --enable-fallback(=CLASS) fall back on CLASS resources in addition to URxvt ones (default: Rxvt)],
 335   [
 336    test x$enableval = xyes && enableval=Rxvt
 337    test x$enableval = xno  && enableval=
 338    RESFALLBACK="$enableval"
 339   ])
 340
 341 if test x$RESFALLBACK != x; then
 342    AC_DEFINE_UNQUOTED(RESFALLBACK, "$RESFALLBACK", [Fallback resource class])
 343 fi
 344
 345 RESNAME=urxvt
 346 AC_ARG_WITH(res-name,
 347   [  --with-res-name=NAME    use this as default resource name (default: urxvt)],
 348   [RESNAME="$withval"])
 349 AC_DEFINE_UNQUOTED(RESNAME,"$RESNAME", [Default resource name])
 350
 351 RESCLASS=URxvt
 352 AC_ARG_WITH(res-class,
 353   [  --with-res-class=CLASS  use this as the resource class (default: URxvt)],
 354   [RESCLASS="$withval"])
 355 AC_DEFINE_UNQUOTED(RESCLASS,"$RESCLASS", [Resource class])
 356
 357 RXVTNAME=urxvt
 358 AC_ARG_WITH(name,
 359   [  --with-name=NAME        set the basename for the installed binaries (default: urxvt)],
 360   [RXVTNAME="$withval"])
 361 AC_DEFINE_UNQUOTED(RXVTNAME,"$RXVTNAME", [Binary base name])
 362
 363 RXVTNAME=`echo "$RXVTNAME"|sed "$program_transform_name"`
 364 AC_SUBST(RXVTNAME)
 365
 366 AC_ARG_ENABLE(swapscreen,
 367   [  --disable-swapscreen    disable swap screen support],
 368   [if test x$enableval = xno; then
 369     AC_DEFINE(NO_SECONDARY_SCREEN, 1, Disable the secondary screen. Many programs use the secondary screen as their workplace)
 370   fi])
 371
 372 AC_ARG_ENABLE(iso14755,
 373   [  --enable-iso14755       enable support for extended ISO 14755 modes],
 374   [if test x$enableval = xyes -o x$enableval = xno; then
 375     support_iso14755=$enableval
 376   fi])
 377
 378 AC_ARG_ENABLE(frills,
 379   [  --enable-frills         enable support for rarely used features],
 380   [if test x$enableval = xyes -o x$enableval = xno; then
 381     support_frills=$enableval
 382   fi])
 383
 384 AC_ARG_ENABLE(keepscrolling,
 385   [  --enable-keepscrolling  enable continual scrolling on scrollbar arrow press],
 386   [if test x$enableval = xyes -o x$enableval = xno; then
 387     support_keepscrolling=$enableval
 388   fi])
 389
 390 AC_ARG_ENABLE(selectionscrolling,
 391   [  --enable-selectionscrolling  enable scrolling during selections],
 392   [if test x$enableval = xyes -o x$enableval = xno; then
 393     support_selectionscrolling=$enableval
 394   fi])
 395
 396 AC_ARG_ENABLE(mousewheel,
 397   [  --enable-mousewheel     enable scrolling via mouse wheel or buttons 4 & 5],
 398   [if test x$enableval = xyes -o x$enableval = xno; then
 399     support_mousewheel=$enableval
 400   fi])
 401
 402 AC_ARG_ENABLE(slipwheeling,
 403   [  --enable-slipwheeling   enable slip wheel scrolling     (requires previous)],
 404   [if test x$enableval = xyes -o x$enableval = xno; then
 405     support_mouseslipwheel=$enableval
 406   fi])
 407
 408 AC_ARG_ENABLE(smart-resize,
 409   [  --enable-smart-resize   enable smart growth/shrink behaviour],
 410   [if test x$enableval = xyes; then
 411     AC_DEFINE(SMART_RESIZE, 1, Define to use "smart" resize behavior)
 412   fi])
 413
 414 AC_ARG_ENABLE(text-blink,
 415   [  --enable-text-blink     enable blinking text],
 416   [if test x$enableval = xyes -o x$enableval = xno; then
 417     support_text_blink=$enableval
 418   fi])
 419
 420 AC_ARG_ENABLE(pointer-blank,
 421   [  --enable-pointer-blank  enable pointer blank when typing or inactive pointer],
 422   [if test x$enableval = xyes -o x$enableval = xno; then
 423     support_pointer_blank=$enableval
 424   fi])
 425
 426 AC_ARG_WITH(term,
 427   [  --with-term=NAME        set the terminal to NAME (default: rxvt)],
 428   [if test x$withval != x; then
 429     AC_DEFINE_UNQUOTED(TERMENV, "$withval",Set TERM to the value given by configure) term="$withval"
 430   fi])
 431
 432 AC_ARG_WITH(terminfo,
 433   [  --with-terminfo=PATH    set the path to the terminfo tree to PATH],
 434   [if test x$withval != x; then
 435     AC_DEFINE_UNQUOTED(RXVT_TERMINFO, "$withval", Set TERMINFO value to the value given by configure) terminfo="$withval"
 436   fi])
 437
 438 dnl# --------------------------------------------------------------------------
 439
 440 AC_PATH_PROG(MV, mv, mv)
 441 AC_PATH_PROG(CP, cp, cp)
 442 AC_PATH_PROG(LN, ln, ln)
 443 AC_PATH_PROG(SED, sed, sed)
 444 AC_PATH_PROG(ECHO, echo, echo)
 445 AC_PATH_PROG(CMP, cmp, cmp)
 446 AC_PATH_PROG(TIC, tic)
 447
 448 dnl# need a neat way to detect SVR4 or its features
 449 dnl# in src/command.c we use these functions:
 450 dnl# grantpt(), unlockpt(), ptsname(), which are defined in <sys/ptms.h>
 451 dnl# - but are these also defined for other systems?
 452
 453 dnl# hack to find if this is SVR4 -- who knows?
 454 dnl## AC_MSG_CHECKING(for SVR4)
 455 dnl## AC_EGREP_CPP(yes,
 456 dnl## [#if defined (SVR4) || defined (_SVR4) || defined (__svr4__)
 457 dnl##   yes;
 458 dnl## #endif
 459 dnl## ], [AC_MSG_RESULT(yes); AC_DEFINE(PERHAPS_SVR4)], AC_MSG_RESULT(perhaps not?))
 460
 461 AC_PATH_XTRA
 462
 463 dnl# the only reasonable way to find libXpm is do-it-yourself
 464 dnl# only check if we want xpm-background
 465
 466 LIBAFTERIMAGE_CFLAGS=
 467 AFTERIMAGE_LIBS=
 468 have_afterimage=
 469
 470 if test x$support_afterimage == xyes; then
 471         AC_MSG_CHECKING(installed libAfterImage)
 472         support_afterimage=no
 473         if test "$afterimage_config" = "NO" ; then
 474                 if afterimage-config --version > /dev/null 2>&1 ; then
 475                         afterimage_config=afterimage-config
 476                 else
 477                         if test -x /usr/local/bin/afterimage-config; then
 478                                 afterimage_config=/usr/local/bin/afterimage-config
 479                         fi
 480                 fi
 481         else
 482             afterimage_config=$afterimage_config/afterimage-config
 483         fi
 484         if $afterimage_config --version > /dev/null 2>&1 ; then
 485                 LIBAFTERIMAGE_CFLAGS=`$afterimage_config --cflags`
 486                 AFTERIMAGE_LIBS=`$afterimage_config --libs`
 487                 if test "x$AFTERIMAGE_LIBS" != "x"; then
 488                         support_afterimage=yes
 489                 fi
 490         fi
 491
 492         if test "x$support_afterimage" = "xyes"; then
 493                 AC_MSG_RESULT($AFTERIMAGE_LIBS)
 494         else
 495                 AC_MSG_RESULT(afterimage-config not found in $afterimage_config - can't use libAfterImage for images.)
 496         fi
 497 fi
 498
 499 if test x$support_afterimage != xyes -a x$support_xpm = xyes ; then
 500   VT_FIND_LIBXPM
 501   if test x$no_xpm = xyes; then
 502     support_xpm=needsmanualspecification
 503   fi
 504 fi
 505
 506 dnl# --------------------------------------------------------------------------
 507 dnl# CHECKING FOR HEADER FILES
 508 dnl# --------------------------------------------------------------------------
 509 AC_HEADER_SYS_WAIT
 510 AC_CHECK_HEADERS( \
 511         assert.h \
 512         fcntl.h \
 513         stdarg.h \
 514         stdlib.h \
 515         string.h \
 516         termios.h \
 517         unistd.h \
 518         sys/byteorder.h \
 519         sys/ioctl.h \
 520         sys/select.h \
 521         sys/sockio.h \
 522         sys/strredir.h \
 523         sys/time.h \
 524         stdint.h \
 525         wchar.h \
 526         cwchar \
 527         clocale \
 528 )
 529
 530 AC_HEADER_TIME
 531
 532 dnl# check to allow both <termios.h> and <sys/ioctl.h>
 533 AC_CACHE_CHECK(whether termios.h and sys/ioctl.h may both be included, rxvt_cv_header_sysioctl,
 534 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 535 #include <sys/ioctl.h>
 536 #ifdef HAVE_TERMIOS_H
 537 #include <termios.h>
 538 #endif]], [[int a = ECHO;]])],[rxvt_cv_header_sysioctl=yes],[rxvt_cv_header_sysioctl=no])])
 539
 540 dnl# ELF systems may want to store paths for dynamic libraries.
 541 dnl# Lets see if the compiler can accept "-Rpath" or "-Wl,-Rpath"
 542 dnl# At least one version of SunOS wants "-R path" but it's not checked yet.
 543 if test -n "$GCC"; then
 544   LDARG="-Wl,"
 545 else
 546   LDARG=""
 547 fi
 548 changequote(, )dnl
 549 R_TRANSLATE='s/-L\([^ ]*\)/-L\1 '$LDARG'-rpath '$LDARG'\1/g'
 550 changequote([, ])dnl
 551
 552 ac_save_CFLAGS=$CFLAGS
 553 ac_save_LIBS=$LIBS
 554 CFLAGS="$CFLAGS $X_CFLAGS"
 555 LIBS=`echo "$LIBS $X_LIBS $X_EXTRA_LIBS -lX11" | sed "$R_TRANSLATE"`
 556 AC_CACHE_CHECK([for -rpath dynamic library path recording], rxvt_cv_rpath,
 557 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <X11/Xlib.h>
 558 #include <stdlib.h>
 559 main()
 560 {
 561     exit(0);
 562     (void) XOpenDisplay("foobar");
 563 }]])],[rxvt_cv_rpath=yes],[rxvt_cv_rpath=no],[dnl
 564   AC_MSG_WARN(You may need to check the LIBS line)])])
 565 if test x$rxvt_cv_rpath != xyes; then
 566   changequote(, )dnl
 567   R_TRANSLATE='s/-L\([^ ]*\)/-L\1 '$LDARG'-R\1/g'
 568   changequote([, ])dnl
 569   LIBS=`echo "$ac_save_LIBS $X_LIBS $X_EXTRA_LIBS -lX11" | sed "$R_TRANSLATE"`
 570   AC_CACHE_CHECK([for -R dynamic library path recording], rxvt_cv_R,
 571 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <X11/Xlib.h>
 572 #include <stdlib.h>
 573 main()
 574 {
 575     exit(0);
 576     (void) XOpenDisplay("foobar");
 577 }]])],[rxvt_cv_R=yes],[rxvt_cv_R=no],[rxvt_cv_R=no])])
 578   if test x$rxvt_cv_R != xyes; then
 579     LIBS="$ac_save_LIBS $X_LIBS $X_EXTRA_LIBS -lX11"
 580   fi
 581 fi
 582
 583 AC_CACHE_CHECK([for XPointer], rxvt_cv_xpointer,
 584 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XPointer dummy;]])],[rxvt_cv_xpointer=yes],[rxvt_cv_xpointer=no])])
 585 if test x$rxvt_cv_xpointer = xyes; then
 586   AC_DEFINE(HAVE_XPOINTER, 1, Define if you have XPointer typedef)
 587 fi
 588 LIBS=$ac_save_LIBS
 589 CFLAGS=$ac_save_CFLAGS
 590
 591 AC_CACHE_CHECK([for XLIB_ILLEGAL_ACCESS], rxvt_xlib_illegal_access,
 592 [AC_COMPILE_IFELSE(
 593    [AC_LANG_PROGRAM([
 594 #define XLIB_ILLEGAL_ACCESS
 595 #include <X11/Xlib.h>
 596    ],[
 597       Display *dpy;
 598       dpy->xdefaults = (char *)0;
 599    ])],
 600    [rxvt_xlib_illegal_access=yes],[rxvt_xlib_illegal_access=no]
 601 )])
 602 if test x$rxvt_xlib_illegal_access = xyes; then
 603    AC_DEFINE(XLIB_ILLEGAL_ACCESS, 1, Define ONLY iff Xlib.h supports it)
 604 fi
 605
 606 AC_C_CONST
 607 AC_C_INLINE
 608
 609 dnl> AC_HEADER_STDC      dnl# skip this test, Sun always fails anyhow.
 610
 611 dnl# --------------------------------------------------------------------------
 612 dnl# CHECKING FOR MISSING TYPEDEFS
 613 dnl# --------------------------------------------------------------------------
 614 dnl# Missing typedefs and replacements
 615 AC_TYPE_MODE_T
 616 dnl> AC_CHECK_TYPE(umode_t, int)
 617 dnl> AC_CHECK_TYPE(off_t, long)
 618 AC_TYPE_PID_T
 619 AC_TYPE_UID_T
 620
 621 AC_CHECK_SIZEOF(short, 2)
 622 AC_CHECK_SIZEOF(int, 4)
 623 dnl AC_CHECK_SIZEOF(long, 4)
 624 AC_CHECK_SIZEOF(long long, 8)
 625 AC_CHECK_SIZEOF(int *, 4)
 626
 627 dnl# see usage below
 628 AC_DEFUN([RXVT_CHECK_SIZE],
 629   [AC_CACHE_CHECK([for $2], $1,
 630     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdint.h>]], [[$2 dummy;]])],[$1=yes],[dnl
 631 if test "$ac_cv_sizeof_char" -ge $3; then
 632   $1="$4 char"
 633 else
 634   if test "$ac_cv_sizeof_short" -ge $3; then
 635     $1="$4 short"
 636   else
 637     if test "$ac_cv_sizeof_int" -ge $3; then
 638       $1="$4 int"
 639     else
 640       if test "$ac_cv_sizeof_long" -ge $3; then
 641         $1="$4 long"
 642       else
 643         if test "$ac_cv_sizeof_long_long" -ge $3; then
 644           $1="$4 long long"
 645         else
 646           $1="$4 $5" # we _must_ have a (possibly wrong) default
 647         fi
 648       fi
 649     fi
 650   fi
 651 fi])])]
 652 if test x"$$1" != xyes; then
 653   $6="typedef $$1 $2;"
 654 else
 655   if test x"$4" = x; then
 656     $6="/* typedef $5 $2; */"
 657   else
 658     $6="/* typedef $4 $5 $2; */"
 659   fi
 660 fi dnl
 661 )
 662 dnl#
 663 dnl# Look for types the system may know about anyway.
 664 dnl#
 665 RXVT_CHECK_SIZE(rxvt_cv_int16_t, int16_t, 2, , short, rxvt_int16_typedef)
 666 AC_SUBST(rxvt_int16_typedef)
 667 RXVT_CHECK_SIZE(rxvt_cv_uint16_t, uint16_t, 2, unsigned, short, rxvt_uint16_typedef)
 668 AC_SUBST(rxvt_uint16_typedef)
 669 RXVT_CHECK_SIZE(rxvt_cv_int32_t, int32_t, 4, , int, rxvt_int32_typedef)
 670 AC_SUBST(rxvt_int32_typedef)
 671 RXVT_CHECK_SIZE(rxvt_cv_uint32_t, uint32_t, 4, unsigned, int, rxvt_uint32_typedef)
 672 AC_SUBST(rxvt_uint32_typedef)
 673 dnl RXVT_CHECK_SIZE(rxvt_cv_int64_t, int64_t, 8, , long long, rxvt_int64_typedef)
 674 dnl AC_SUBST(rxvt_int64_typedef)
 675 dnl RXVT_CHECK_SIZE(rxvt_cv_uint64_t, uint64_t, 8, unsigned, long long, rxvt_uint64_typedef)
 676 dnl AC_SUBST(rxvt_uint64_typedef)
 677 dnl#
 678 dnl# Now look for another we use
 679 dnl#
 680 if test "$ac_cv_sizeof_int_p" -eq 8; then
 681   rxvt_intp_define="#define intp_t int64_t"
 682   rxvt_u_intp_define="#define u_intp_t u_int64_t"
 683 else
 684   if test "$ac_cv_sizeof_int_p" -eq 4; then
 685     rxvt_intp_define="#define intp_t int32_t"
 686     rxvt_u_intp_define="#define u_intp_t u_int32_t"
 687   else
 688     if test "$ac_cv_sizeof_int_p" -eq 2; then
 689       rxvt_intp_define="#define intp_t int16_t"
 690       rxvt_u_intp_define="#define u_intp_t u_int16_t"
 691     else
 692       rxvt_intp_define="#error set intp_t"
 693       rxvt_u_intp_define="#error set u_intp_t"
 694     fi
 695   fi
 696 fi
 697 AC_SUBST(rxvt_intp_define)
 698 AC_SUBST(rxvt_u_intp_define)
 699
 700 dnl# --------------------------------------------------------------------------
 701 dnl# CHECKING FOR LIBRARY FUNCTIONS
 702 dnl# --------------------------------------------------------------------------
 703 AC_TYPE_SIGNAL
 704 dnl> AC_FUNC_VPRINTF
 705
 706 AC_CHECK_FUNCS( \
 707         unsetenv \
 708         setutent \
 709         on_exit \
 710 )
 711
 712 UTMP_CHECK
 713
 714 dnl# --------------------------------------------------------------------------
 715
 716 dnl# find ttys/ttytab
 717 AC_CACHE_CHECK(where ttys/ttytab is located, rxvt_cv_path_ttytab,
 718 [for ttys_file in   dnl
 719   /etc/ttys /etc/ttytab;
 720 do
 721   if test -f "$ttys_file" ; then
 722     rxvt_cv_path_ttytab=$ttys_file
 723     break
 724   fi
 725 done
 726 ])
 727 if test x$rxvt_cv_path_ttytab != x; then
 728   AC_DEFINE_UNQUOTED(TTYTAB_FILENAME, "$rxvt_cv_path_ttytab", Define location of ttys/ttytab)
 729 fi
 730
 731 dnl# --------------------------------------------------------------------------
 732 dnl# --------------------------------------------------------------------------
 733
 734 dnl# this is a really hack test for some basic Xlocale stuff
 735 ac_save_LIBS=$LIBS
 736 ac_save_CFLAGS=$CFLAGS
 737 CFLAGS="$CFLAGS $X_CFLAGS"
 738 LIBS="$LIBS $X_LIBS $X_EXTRA_LIBS -lX11"
 739 if test x$rxvt_cv_rpath = xyes -o x$rxvt_cv_R = xyes; then
 740   LIBS=`echo $LIBS | sed "$R_TRANSLATE"`
 741 fi
 742 AC_CACHE_CHECK(for working Xlocale, rxvt_cv_func_xlocale,
 743 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <X11/Xlib.h>
 744 #include <stdlib.h>
 745 main() {
 746 char *p;
 747 if ((p = XSetLocaleModifiers("@im=none")) != NULL && *p)
 748 exit (XSupportsLocale() ? 0 : 1);
 749 else
 750 exit (1);}]])],[dnl
 751   rxvt_cv_func_xlocale=yes],[rxvt_cv_func_xlocale=no],[dnl
 752   AC_MSG_WARN(Define NO_XLOCALE in config.h manually)])])
 753 if test x$rxvt_cv_func_xlocale = xyes; then
 754   AC_DEFINE(HAVE_XLOCALE, 1, Define if Xlocale support works)
 755 fi
 756
 757 AC_CACHE_CHECK(for working X setlocale, rxvt_cv_func_xsetlocale,
 758 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define X_LOCALE 1
 759 #include <X11/Xlocale.h>]], [[setlocale(LC_CTYPE, "");]])],[rxvt_cv_func_xsetlocale=yes],[rxvt_cv_func_xsetlocale=no])])
 760 if test x$rxvt_cv_func_xsetlocale = xyes; then
 761   AC_DEFINE(HAVE_XSETLOCALE, 1, Define if setlocale (defined to Xsetlocale) works)
 762 fi
 763 LIBS=$ac_save_LIBS
 764 CFLAGS=$ac_save_CFLAGS
 765
 766 AC_CACHE_CHECK(for working plain setlocale, rxvt_cv_func_setlocale,
 767 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <clocale>]], [[setlocale(LC_CTYPE, "");]])],[rxvt_cv_func_setlocale=yes],[rxvt_cv_func_setlocale=no])])
 768 if test x$rxvt_cv_func_setlocale = xyes; then
 769   AC_DEFINE(HAVE_SETLOCALE, 1, Define if plain old setlocale works)
 770 fi
 771
 772 AC_CACHE_CHECK(for working nl_langinfo, rxvt_cv_func_nl_langinfo,
 773 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(CODESET);]])],[rxvt_cv_func_nl_langinfo=yes],[rxvt_cv_func_nl_langinfo=no])])
 774 if test x$rxvt_cv_func_nl_langinfo = xyes; then
 775   AC_DEFINE(HAVE_NL_LANGINFO, 1, Define if nl_langinfo(CODESET) works)
 776 fi
 777
 778 SCM_RIGHTS_CHECK
 779
 780 AC_CACHE_CHECK(for broken XIM callback, rxvt_broken_ximcb,
 781 [AC_COMPILE_IFELSE([
 782 #include <X11/Xlib.h>
 783
 784 void im_destroy_cb (XIC unused1, XPointer client_data, XPointer unused3);
 785
 786 void f() {
 787   XIMCallback cb;
 788   cb.callback = im_destroy_cb;
 789 }
 790 ],rxvt_broken_ximcb=yes,rxvt_broken_ximcb=no)])
 791
 792 if test x$rxvt_broken_ximcb = xyes; then
 793    AC_DEFINE(XIMCB_PROTO_BROKEN, 1, Define if your XIMCallback specifies XIC as first type.)
 794 fi
 795
 796 PTY_CHECK
 797
 798 TTY_GROUP_CHECK
 799
 800 dnl# --------------------------------------------------------------------------
 801 dnl# now add and remove other stuff
 802 dnl# --------------------------------------------------------------------------
 803 if test x$support_xft = xyes; then
 804   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 805   if test $PKG_CONFIG != no && $PKG_CONFIG --exists xft; then
 806     LIBS="$LIBS `$PKG_CONFIG xft --libs`"
 807     CPPFLAGS="$CPPFLAGS `$PKG_CONFIG xft --cflags`"
 808   else
 809     AC_PATH_PROG(XFT_CONFIG, xft-config, no)
 810     if test $XFT_CONFIG != no; then
 811       LIBS="$LIBS `$XFT_CONFIG --libs`"
 812       CPPFLAGS="$CPPFLAGS `$XFT_CONFIG --cflags`"
 813     fi
 814   fi
 815
 816   AC_CHECK_HEADERS(X11/Xft/Xft.h,,[support_xft=no])
 817   AC_CHECK_LIB(Xft,XftDrawString32,,[support_xft=no])
 818
 819   if test x$support_xft = xyes; then
 820     AC_DEFINE(XFT, 1, Define to enable xft support)
 821   fi
 822 fi
 823 if test x$support_styles = xyes; then
 824   AC_DEFINE(ENABLE_STYLES, 1, Define if you want bold and italic support)
 825 fi
 826 if test x$support_iso14755 = xyes; then
 827   AC_DEFINE(ISO_14755, 1, Define if you want ISO 14755 extended support)
 828 fi
 829 if test x$support_8bitctrls = xyes; then
 830   AC_DEFINE(EIGHT_BIT_CONTROLS, 1, Define if you want 8 bit control sequences)
 831 fi
 832 if test x$support_fading = xyes; then
 833   AC_DEFINE(OFF_FOCUS_FADING, 1, Define if you want faded colors when focus is lost)
 834 fi
 835 if test x$support_tinting = xyes; then
 836   AC_DEFINE(TINTING, 1, Define if you want your background to be tinted)
 837 fi
 838 if test x$support_inheritpixmap = xyes; then
 839   AC_DEFINE(TRANSPARENT, 1, Define if you want your background to use the parent window background)
 840 fi
 841 if test x$support_keepscrolling = xno; then
 842   AC_DEFINE(NO_SCROLLBAR_BUTTON_CONTINUAL_SCROLLING, 1, Define for continual scrolling when you keep the scrollbar button pressed)
 843 fi
 844 if test x$support_selectionscrolling = xyes; then
 845   AC_DEFINE(SELECTION_SCROLLING, 1, Define to allow scrolling when the selection moves to the top or bottom of the screen)
 846 fi
 847 if test x$support_frills = xyes; then
 848   AC_DEFINE(ENABLE_FRILLS, 1, Define if you want handling for rarely used but handy features)
 849 fi
 850 if test x$support_mousewheel = xyes; then
 851   AC_DEFINE(MOUSE_WHEEL, 1, Define to use wheel events (button4 and button5) to scroll)
 852 fi
 853 if test x$support_mouseslipwheel = xyes; then
 854   AC_DEFINE(MOUSE_SLIP_WHEELING, 1, Define to have CTRL cause wheel events to accelerate scrolling. Release CTRL to halt scrolling)
 855 fi
 856 if test x$support_xim = xyes -o x$multichar_set = xyes; then
 857   if test x$rxvt_cv_func_xlocale = xyes; then
 858     AC_DEFINE(USE_XIM, 1, Define if you want to have XIM (X Input Method) protocol support - required for multibyte characters input)
 859   fi
 860 fi
 861 if test x$support_xpm = xyes -o x$support_afterimage = xyes ; then
 862   AC_DEFINE(XPM_BACKGROUND, 1, Define if you want to have sexy-looking background pixmaps. Needs libXpm or libAfterImage)
 863 fi
 864
 865 if test x$support_afterimage = xyes; then
 866   AC_DEFINE(HAVE_AFTERIMAGE, 1, Define if you want to use libAfterImage for image processing)
 867 fi
 868
 869 if test x$support_afterstep = xyes; then
 870   AC_DEFINE(AFTERSTEP_INTEGRATION, 1, Define if you want to integrate with AfterStep window manager)
 871 fi
 872
 873 if test x$support_scroll_rxvt = xyes; then
 874   AC_DEFINE(RXVT_SCROLLBAR, 1, Support Rxvt original style scrollbars)
 875   scrolltypes="rxvt"
 876 fi
 877 if test x$support_scroll_next = xyes; then
 878   AC_DEFINE(NEXT_SCROLLBAR, 1, Support NeXT style scrollbars)
 879   scrolltypes="$scrolltypes next"
 880 fi
 881 if test x$support_scroll_xterm = xyes; then
 882   AC_DEFINE(XTERM_SCROLLBAR, 1, Support Xterm style scrollbars)
 883   scrolltypes="$scrolltypes xterm"
 884 fi
 885 if test x$support_scroll_plain = xyes; then
 886   AC_DEFINE(PLAIN_SCROLLBAR, 1, Support plain style scrollbars)
 887   scrolltypes="$scrolltypes plain"
 888 fi
 889 if test x$support_pointer_blank = xyes; then
 890   AC_DEFINE(POINTER_BLANK, 1, Define if you want hide the pointer while typing)
 891 fi
 892 if test x$support_text_blink = xyes; then
 893   AC_DEFINE(TEXT_BLINK, 1, Define if you want blinking text support)
 894 fi
 895 if test x$support_unicode3 = xyes; then
 896   AC_DEFINE(UNICODE_3, 1, Define if you want to represent unicode characters outside plane 0)
 897 fi
 898 if test x$support_combining = xyes; then
 899   AC_DEFINE(ENABLE_COMBINING, 1, Define if you want to automatically compose combining characters)
 900 fi
 901 if test x$codesets = xall; then
 902   codesets=jp,jp-ext,kr,zh,zh-ext
 903 fi
 904 AC_DEFINE(ENCODING_EU, 1, Define if you want european extended codesets)
 905 AC_DEFINE(ENCODING_VN, 1, Define if you want vietnamese codesets)
 906 for codeset in `echo $codesets | tr "[a-z,\\-]" "[A-Z _]"`; do
 907   case "$codeset" in
 908     JP     ) AC_DEFINE(ENCODING_JP,     1, Define if you want japanese codesets) ;;
 909     JP_EXT ) AC_DEFINE(ENCODING_JP_EXT, 1, Define if you want extended japanese codesets) ;;
 910     KR     ) AC_DEFINE(ENCODING_KR,     1, Define if you want korean codesets) ;;
 911     ZH     ) AC_DEFINE(ENCODING_ZH,     1, Define if you want chinese codesets) ;;
 912     ZH_EXT ) AC_DEFINE(ENCODING_ZH_EXT, 1, Define if you want extended chinese codesets) ;;
 913   esac
 914 done
 915
 916 IF_PERL=\#
 917 if test x$support_perl = xyes; then
 918   AC_PATH_PROG(PERL, perl5)
 919   AC_PATH_PROG(PERL, perl)
 920
 921   AC_MSG_CHECKING(for $PERL suitability)
 922   if $PERL -MExtUtils::Embed -e "use v5.8" >/dev/null 2>/dev/null; then
 923
 924      save_CXXFLAGS="$CXXFLAGS"
 925      save_LIBS="$LIBS"
 926      CXXFLAGS="$CXXFLAGS `$PERL -MExtUtils::Embed -e ccopts`"
 927      LIBS="$LIBS `$PERL -MExtUtils::Embed -e ldopts`"
 928      AC_TRY_LINK([
 929 #include <EXTERN.h>
 930 #include <perl.h>
 931 #include <XSUB.h>
 932 ],[
 933      PerlInterpreter *perl = perl_alloc ();
 934 ],[rxvt_perl_link=yes],[rxvt_perl_link=no])
 935      CXXFLAGS="$save_CXXFLAGS"
 936      LIBS="$save_LIBS"
 937
 938      if test x$rxvt_perl_link = xyes; then
 939         AC_MSG_RESULT(ok)
 940         AC_DEFINE(ENABLE_PERL, 1, Define if you can embed a perl interpreter)
 941         IF_PERL=
 942         PERL_O=rxvtperl.o
 943         PERLFLAGS="`$PERL -MExtUtils::Embed -e ccopts`"
 944         PERLLIB="`$PERL -MExtUtils::Embed -e ldopts`"
 945         PERLPRIVLIBEXP="`$PERL -MConfig -e 'print $Config{privlibexp}'`"
 946      else
 947         AC_MSG_ERROR([no, unable to link])
 948      fi
 949   else
 950      AC_MSG_ERROR([no working perl found, or perl not version >= 5.8])
 951   fi
 952 fi
 953 AC_SUBST(PERLLIB)
 954 AC_SUBST(PERLFLAGS)
 955 AC_SUBST(PERLPRIVLIBEXP)
 956 AC_SUBST(PERL)
 957 AC_SUBST(IF_PERL)
 958 AC_SUBST(PERL_O)
 959
 960 if test x$support_perl = xyes; then
 961    support_frills=yes
 962 fi
 963
 964 AC_SUBST(DEBUG)
 965 AC_SUBST(DINCLUDE)
 966 AC_SUBST(CFLAGS)
 967 AC_SUBST(CPPFLAGS)
 968 AC_SUBST(LDFLAGS)
 969 AC_SUBST(X_CFLAGS)
 970
 971 dnl# Attack the libs
 972 if test x$rxvt_cv_rpath = xyes -o x$rxvt_cv_R = xyes; then
 973   DLIB=`echo $DLIB | sed "$R_TRANSLATE"`
 974   LIBS=`echo $LIBS | sed "$R_TRANSLATE"`
 975   X_LIBS=`echo $X_LIBS | sed "$R_TRANSLATE"`
 976   X_EXTRA_LIBS=`echo $X_EXTRA_LIBS | sed "$R_TRANSLATE"`
 977   XPM_LIBS=`echo $XPM_LIBS | sed "$R_TRANSLATE"`
 978 fi
 979 AC_SUBST(DLIB)
 980 AC_SUBST(LIBS)
 981 AC_SUBST(X_LIBS)
 982 AC_SUBST(X_EXTRA_LIBS)
 983
 984 AC_SUBST(LIBAFTERIMAGE_CFLAGS)
 985 AC_SUBST(AFTERIMAGE_LIBS)
 986
 987 AC_ARG_PROGRAM
 988
 989 dnl# test for "sun" or "__sun__" before include sys_ioctl
 990
 991 dnl# revert HAVE_BLAH_H into a "#include <blah.h>"
 992 AC_DEFUN([RXVT_DEFINE_TO_INCLUDE], dnl
 993 [if test "$$3" = "$4" -o "$$5" = "$6"; then
 994   $1="#include <$2>"
 995 else
 996   $1="/* #include <$2> */"
 997 fi dnl
 998 AC_SUBST($1)])
 999
1000 RXVT_DEFINE_TO_INCLUDE(include_stdint_h, stdint.h, ac_cv_header_stdint_h, yes, notset, dontmatch)
1001 RXVT_DEFINE_TO_INCLUDE(include_stdarg_h, cstdarg, ac_cv_header_stdarg_h, yes, notset, dontmatch)
1002 RXVT_DEFINE_TO_INCLUDE(include_stdlib_h, cstdlib, ac_cv_header_stdlib_h, yes, notset, dontmatch)
1003 RXVT_DEFINE_TO_INCLUDE(include_unistd_h, unistd.h, ac_cv_header_unistd_h, yes, notset, dontmatch)
1004 RXVT_DEFINE_TO_INCLUDE(include_string_h, cstring, ac_cv_header_string_h, yes, notset, dontmatch)
1005 RXVT_DEFINE_TO_INCLUDE(include_fcntl_h, fcntl.h, ac_cv_header_fcntl_h, yes, notset, dontmatch)
1006 RXVT_DEFINE_TO_INCLUDE(include_util_h, util.h, ac_cv_header_util_h, yes, notset, dontmatch)
1007 RXVT_DEFINE_TO_INCLUDE(include_assert_h, assert.h, ac_cv_header_assert_h, yes, notset, dontmatch)
1008 RXVT_DEFINE_TO_INCLUDE(include_sys_ioctl_h, sys/ioctl.h, rxvt_cv_header_sysioctl, yes, notset, dontmatch)
1009 RXVT_DEFINE_TO_INCLUDE(include_sys_select_h, sys/select.h, ac_cv_header_sys_select_h, yes, notset, dontmatch)
1010 RXVT_DEFINE_TO_INCLUDE(include_sys_strredir_h, sys/strredir.h, ac_cv_header_sys_strredir_h, yes, notset, dontmatch)
1011 RXVT_DEFINE_TO_INCLUDE(include_sys_time_h, sys/time.h, ac_cv_header_sys_time_h, yes, notset, dontmatch)
1012 RXVT_DEFINE_TO_INCLUDE(include_time_h, time.h, ac_cv_header_sys_time_h, no, ac_cv_header_time, yes)
1013
1014 AC_CONFIG_FILES([Makefile \
1015 doc/Makefile \
1016 src/Makefile \
1017 src/rxvtlib.h \
1018 ])
1019 AC_OUTPUT
1020
1021 echo "Configuration:
1022
1023   Rxvt version:               $VERSION : $DATE
1024   Source code location:       $srcdir
1025   Install path:               ${prefix}/bin
1026   Compiler:                   $CXX
1027   Compiler flags:             $CXXFLAGS
1028   Linker:                     $LINKER"
1029
1030 if test x$support_xpm = xyes; then
1031   echo "  Xpm library:                $XPM_LIBS"
1032 fi
1033
1034 if test x$support_afterimage = xyes; then
1035   echo "  AfterImage library:                $AFTERIMAGE_LIBS"
1036 fi
1037
1038 if test x$support_afterstep = xyes; then
1039   echo "  With AfterStep integration"
1040 fi
1041
1042 if test x$term != x; then
1043   echo "  set TERM to:                $term"
1044 fi
1045 if test x$terminfo != x; then
1046   echo "  set TERMINFO to:            $terminfo"
1047 fi
1048 echo "  default resource name:      $RESNAME"
1049 echo "  resource class:             $RESCLASS"
1050 if test x$RESFALLBACK != x; then
1051    echo "  resource class fallback:    $RESFALLBACK"
1052 fi
1053 echo
1054 echo "  embedded perl:              $support_perl"
1055 echo
1056 if test x$support_xpm = xneedsmanualspecification; then
1057   echo ".----------------------------------------------------------------."
1058   echo ". WARNING: --enable-xpm-background was specified however the     ."
1059   echo ".          XPM includes files and libraries could not be found.  ."
1060   echo ".          XPM backgrounds are now being DISABLED!  If you want  ."
1061   echo ".          to use them you should rerun   configure   with the   ."
1062   echo ".          appropriate --with-xpm-includes=/path/to/xpm/includes ."
1063   echo ".          and --with-xpm-library=/path/to/xpm/library lines.    ."
1064   echo ".----------------------------------------------------------------."
1065 fi
1066 if test x$support_xim = xyes -a x$rxvt_cv_func_xlocale = xno; then
1067   echo ".----------------------------------------------------------------."
1068   echo ". WARNING: --enable-xim was specified however the locale support ."
1069   echo ".          functions could not be found.                         ."
1070   echo ".          XIM is now being DISABLED!                            ."
1071   echo ".----------------------------------------------------------------."
1072 fi
1073
1074 echo "*** Optionally check src/feature.h for further, rarely used options ***"
1075 echo
1076