configure.ac

   1 dnl#
   2 dnl# Process this file with autoconf to produce a configure script.
   3 dnl#
   4
   5 AC_INIT
   6 AC_PREREQ(2.50)
   7 AC_CONFIG_SRCDIR([src/feature.h])
   8 AC_CONFIG_HEADER(config.h:config.h.in)
   9
  10 AC_CANONICAL_HOST
  11
  12 dnl RXVT version
  13 changequote(, )dnl
  14 VERSION=`sed -n -e 's/^.*[ \t]VERSION.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  15 DATE=`sed -n -e 's/^.*[ \t]DATE.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  16 changequote([, ])dnl
  17 AC_SUBST(VERSION)dnl
  18 AC_SUBST(DATE)dnl
  19
  20 echo ""
  21 echo "configuring for rxvt $VERSION"
  22 echo ""
  23
  24 orig_CXXFLAGS="$CXXFLAGS"
  25
  26 dnl# Checks for programs.
  27 AC_PROG_CC
  28 AC_PROG_CXX
  29 AC_PROG_CPP
  30 AC_PROG_INSTALL
  31
  32 AC_AIX
  33 AC_GNU_SOURCE
  34 AC_ISC_POSIX
  35 AC_LANG(C++)
  36
  37 dnl check wether we can link with gcc -lsupc++
  38 if test x$GCC = xyes && test x$GXX = xyes; then
  39    dnl FreeBSD (at least up to 5.3) has a broken GCC, workaround it
  40    AC_MSG_CHECKING([for working libsupc++])
  41    save_CXX="$CXX"
  42    save_LIBS="$LIBS"
  43    CXX="$CC"
  44    LIBS="$LIBS -lsupc++"
  45    LINKER="$CC"
  46    AC_LINK_IFELSE(
  47       [AC_LANG_PROGRAM([struct test { }; void f() try { throw new test; } catch (...) { throw; }],[])],
  48       [AC_MSG_RESULT(ok)],
  49       [
  50          AC_MSG_RESULT([no, making everything bigger and slower])
  51          LIBS="$save_LIBS"
  52          LINKER="$save_CXX"
  53       ]
  54    )
  55    CXX="$save_CXX"
  56 fi
  57 AC_SUBST(LINKER,[$LINKER])
  58
  59 dnl# --------------------------------------------------------------------------
  60 dnl# Supply default CXXFLAGS, if not specified by `CXXFLAGS=flags ./configure'
  61 dnl#
  62 if test -z "$orig_CXXFLAGS"; then
  63   if test x$GCC = xyes && test "x$GXX" = xyes; then
  64     CXXFLAGS="-g -O3 -fno-rtti -fvisibility-inlines-hidden -fno-threadsafe-statics -fno-enforce-eh-specs"
  65     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [], [CXXFLAGS="-g -O3"])
  66   else
  67     CXXFLAGS="-O"
  68   fi
  69   CFLAGS="$CXXFLAGS"
  70 fi
  71
  72 case $host in
  73    *-*-solaris* )
  74       AC_DEFINE(_XOPEN_SOURCE, 500, Needed to get declarations for msg_control and msg_controllen on Solaris)
  75       ;;
  76 esac
  77
  78 dnl# FreeBSD needs to link libxpg4
  79 AC_CHECK_FUNC(setlocale,     [], [AC_CHECK_LIB(xpg4,   setlocale,     [LIBS="$LIBS -lxpg4"])])
  80
  81 dnl# solaris needs to link libnsl and socket
  82 AC_CHECK_FUNC(gethostbyname, [], [AC_CHECK_LIB(nsl,    gethostbyname, [LIBS="$LIBS -lnsl"])])
  83 AC_CHECK_FUNC(socket,        [], [AC_CHECK_LIB(socket, socket,        [LIBS="$LIBS -lsocket"])])
  84
  85 support_frills=yes
  86 support_inheritpixmap=yes
  87 support_fading=yes
  88 support_keepscrolling=yes
  89 support_selectionscrolling=yes
  90 support_mousewheel=yes
  91 support_mouseslipwheel=yes
  92 support_text_blink=yes
  93 support_pointer_blank=yes
  94 support_scroll_rxvt=yes
  95 support_scroll_next=yes
  96 support_scroll_xterm=yes
  97 support_scroll_plain=yes
  98 support_xim=yes
  99 support_afterimage=yes
 100 support_afterstep=yes
 101 support_xft=yes
 102 support_unicode3=no
 103 support_combining=yes
 104 support_8bitctrls=no
 105 support_iso14755=yes
 106 support_styles=yes
 107 support_perl=yes
 108 codesets=all
 109
 110 dnl# --------------------------------------------------------------------------
 111 dnl# CHECKING COMMAND LINE OPTIONS
 112 dnl# --------------------------------------------------------------------------
 113
 114 AC_ARG_ENABLE(everything,
 115   [  --enable-everything     enable standard non-multichoice features
 116                      NOTE: this option is order dependent],
 117   [
 118     if test x$enableval = xno; then
 119        support_frills=no
 120        support_inheritpixmap=no
 121        support_fading=no
 122        support_keepscrolling=no
 123        support_selectionscrolling=no
 124        support_lastlog=no
 125        support_mousewheel=no
 126        support_mouseslipwheel=no
 127        support_text_blink=no
 128        support_pointer_blank=no
 129        support_scroll_rxvt=no
 130        support_scroll_next=no
 131        support_scroll_xterm=no
 132        support_scroll_plain=no
 133        support_utmp=no
 134        support_wtmp=no
 135        support_xim=no
 136        support_afterimage=no
 137        support_afterstep=no
 138        support_xft=no
 139        support_unicode3=no
 140        support_combining=no
 141        support_8bitctrls=no
 142        support_iso14755=no
 143        support_styles=no
 144        support_perl=no
 145        codesets=
 146     fi
 147     if test x$enableval = xyes; then
 148        support_frills=yes
 149        support_inheritpixmap=yes
 150        support_fading=yes
 151        support_keepscrolling=yes
 152        support_selectionscrolling=yes
 153        support_lastlog=yes
 154        support_mousewheel=yes
 155        support_mouseslipwheel=yes
 156        support_text_blink=yes
 157        support_pointer_blank=yes
 158        support_scroll_rxvt=yes
 159        support_scroll_next=yes
 160        support_scroll_xterm=yes
 161        support_scroll_plain=yes
 162        support_utmp=yes
 163        support_wtmp=yes
 164        support_xim=yes
 165        support_afterimage=yes
 166        support_afterstep=yes
 167        support_xft=yes
 168        support_unicode3=yes
 169        support_combining=yes
 170        #support_8bitctrls=yes
 171        support_iso14755=yes
 172        support_styles=yes
 173        support_perl=yes
 174        codesets=all
 175     fi
 176   ])
 177
 178 WARNINGS=no
 179 AC_ARG_ENABLE(warnings,
 180   [  --enable-warnings       turn on g++ warnings],
 181   [if test x$enableval = xyes; then
 182     WARNINGS=yes
 183   fi])
 184 if test x$GXX = xyes; then
 185   if test $WARNINGS = yes; then
 186     save_CXXFLAGS="$CXXFLAGS"
 187     CXXFLAGS="$CXXFLAGS -Wall -Wno-sign-compare -Wno-reorder -Wno-non-virtual-dtor"
 188     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [], [CXXFLAGS="$save_CXXFLAGS"])
 189   else
 190     CXXFLAGS="$CXXFLAGS -w"
 191   fi
 192 fi
 193
 194 AC_ARG_ENABLE(unicode3,
 195   [  --enable-unicode3       use 21 instead of 16 bits to represent unicode characters],
 196   [if test x$enableval = xyes -o x$enableval = xno; then
 197     support_unicode3=$enableval
 198   fi])
 199
 200 AC_ARG_ENABLE(combining,
 201   [  --enable-combining      enable composition of base and combining characters],
 202   [if test x$enableval = xyes -o x$enableval = xno; then
 203     support_combining=$enableval
 204   fi])
 205
 206 AC_ARG_ENABLE(xft,
 207   [  --enable-xft            enable xft support on systems that have it],
 208   [if test x$enableval = xyes -o x$enableval = xno; then
 209     support_xft=$enableval
 210   fi])
 211
 212 AC_ARG_ENABLE(font-styles,
 213   [  --enable-font-styles    enable bold and italic support],
 214   [if test x$enableval = xyes -o x$enableval = xno; then
 215     support_styles=$enableval
 216   fi])
 217
 218 AC_ARG_ENABLE(afterimage,
 219   [  --enable-afterimage enable integration with libAfterImage for background images],
 220   [if test x$enableval = xyes -o x$enableval = xno; then
 221     support_afterimage=$enableval
 222   fi])
 223
 224 AC_ARG_WITH(afterimage_config,
 225   [  --with-afterimage-config=DIR  use libAfterImage config script in DIR],
 226   [if test "x$withval" != x; then
 227     afterimage_config=$withval/afterimage-config
 228   fi])
 229
 230 dnl AC_ARG_ENABLE(afterstep,
 231 dnl   [  --enable-afterstep enable integration with AfterStep window manager],
 232 dnl   [if test x$enableval = xyes -o x$enableval = xno; then
 233 dnl     support_afterstep=$enableval
 234 dnl   fi])
 235
 236 AC_ARG_ENABLE(transparency,
 237   [  --enable-transparency   enable transparent backgrounds],
 238   [if test x$enableval = xyes -o x$enableval = xno; then
 239     support_inheritpixmap=$enableval
 240   fi])
 241
 242 AC_ARG_ENABLE(fading,
 243   [  --enable-fading         enable colors fading when off focus],
 244   [if test x$enableval = xyes -o x$enableval = xno; then
 245     support_fading=$enableval
 246   fi])
 247
 248 AC_ARG_ENABLE(rxvt-scroll,
 249   [  --enable-rxvt-scroll    enable rxvt style scrollbar],
 250   [if test x$enableval = xyes -o x$enableval = xno; then
 251     support_scroll_rxvt=$enableval
 252   fi])
 253
 254 AC_ARG_ENABLE(next-scroll,
 255   [  --enable-next-scroll    enable NeXT style scrollbar],
 256   [if test x$enableval = xyes -o x$enableval = xno; then
 257     support_scroll_next=$enableval
 258   fi])
 259
 260 AC_ARG_ENABLE(xterm-scroll,
 261   [  --enable-xterm-scroll   enable Xterm style scrollbar],
 262   [if test x$enableval = xyes -o x$enableval = xno; then
 263     support_scroll_xterm=$enableval
 264   fi])
 265
 266 AC_ARG_ENABLE(plain-scroll,
 267   [  --enable-plain-scroll   enable plain style scrollbar],
 268   [if test x$enableval = xyes -o x$enableval = xno; then
 269     support_scroll_plain=$enableval
 270   fi])
 271
 272 AC_ARG_ENABLE(perl,
 273   [  --enable-perl           enable embedded perl interpreter],
 274   [if test x$enableval = xyes -o x$enableval = xno; then
 275     support_perl=$enableval
 276   fi])
 277
 278 AC_ARG_WITH(codesets,
 279   [  --with-codesets=CS,...  compile in additional codesets (jp,jp_ext,kr,zh,zh_ext,all)],
 280   [codesets="$withval"])
 281
 282 AC_ARG_ENABLE(xim,
 283   [  --enable-xim            XIM (X Input Method) protocol support],
 284   [if test x$enableval = xyes -o x$enableval = xno; then
 285     support_xim=$enableval
 286   fi])
 287
 288 AC_ARG_ENABLE(backspace-key,
 289   [  --disable-backspace-key disable handling of the backspace key],
 290   [if test x$enableval = xno; then
 291     AC_DEFINE(NO_BACKSPACE_KEY, 1, Define if you don't want support for the backspace key)
 292   fi])
 293
 294 AC_ARG_ENABLE(delete-key,
 295   [  --disable-delete-key    disable handling of the delete key],
 296   [if test x$enableval = xno; then
 297     AC_DEFINE(NO_DELETE_KEY, 1, Define if you don't want support for the (non-keypad) delete key)
 298   fi])
 299
 300 AC_ARG_ENABLE(resources,
 301   [  --disable-resources     disable all resource checking],
 302   [if test x$enableval = xno; then
 303     AC_DEFINE(NO_RESOURCES, 1, Define if you don't want any resources read)
 304   fi])
 305
 306 AC_ARG_ENABLE(8bitctrls,
 307   [  --enable-8bitctrls      enable 8 bit control sequences (not recommended)],
 308   [if test x$enableval = xyes -o x$enableval = xno; then
 309     support_8bitctrls=$enableval
 310   fi])
 311
 312 RESFALLBACK=Rxvt
 313 AC_ARG_ENABLE(fallback,
 314   [  --enable-fallback@<:@=CLASS@:>@ fall back on CLASS resources in addition to URxvt ones (default: Rxvt)],
 315   [
 316    test x$enableval = xyes && enableval=Rxvt
 317    test x$enableval = xno  && enableval=
 318    RESFALLBACK="$enableval"
 319   ])
 320
 321 if test x$RESFALLBACK != x; then
 322    AC_DEFINE_UNQUOTED(RESFALLBACK, "$RESFALLBACK", [Fallback resource class])
 323 fi
 324
 325 RESNAME=urxvt
 326 AC_ARG_WITH(res-name,
 327   [  --with-res-name=NAME    use this as default resource name (default: urxvt)],
 328   [RESNAME="$withval"])
 329 AC_DEFINE_UNQUOTED(RESNAME,"$RESNAME", [Default resource name])
 330
 331 RESCLASS=URxvt
 332 AC_ARG_WITH(res-class,
 333   [  --with-res-class=CLASS  use this as the resource class (default: URxvt)],
 334   [RESCLASS="$withval"])
 335 AC_DEFINE_UNQUOTED(RESCLASS,"$RESCLASS", [Resource class])
 336
 337 RXVTNAME=urxvt
 338 AC_ARG_WITH(name,
 339   [  --with-name=NAME        set the basename for the installed binaries (default: urxvt)],
 340   [RXVTNAME="$withval"])
 341 AC_DEFINE_UNQUOTED(RXVTNAME,"$RXVTNAME", [Binary base name])
 342
 343 RXVTNAME=`echo "$RXVTNAME"|sed "$program_transform_name"`
 344 AC_SUBST(RXVTNAME)
 345
 346 AC_ARG_ENABLE(swapscreen,
 347   [  --disable-swapscreen    disable swap screen support],
 348   [if test x$enableval = xno; then
 349     AC_DEFINE(NO_SECONDARY_SCREEN, 1, Disable the secondary screen. Many programs use the secondary screen as their workplace)
 350   fi])
 351
 352 AC_ARG_ENABLE(iso14755,
 353   [  --enable-iso14755       enable support for extended ISO 14755 modes],
 354   [if test x$enableval = xyes -o x$enableval = xno; then
 355     support_iso14755=$enableval
 356   fi])
 357
 358 AC_ARG_ENABLE(frills,
 359   [  --enable-frills         enable support for rarely used features],
 360   [if test x$enableval = xyes -o x$enableval = xno; then
 361     support_frills=$enableval
 362   fi])
 363
 364 AC_ARG_ENABLE(keepscrolling,
 365   [  --enable-keepscrolling  enable continual scrolling on scrollbar arrow press],
 366   [if test x$enableval = xyes -o x$enableval = xno; then
 367     support_keepscrolling=$enableval
 368   fi])
 369
 370 AC_ARG_ENABLE(selectionscrolling,
 371   [  --enable-selectionscrolling  enable scrolling during selections],
 372   [if test x$enableval = xyes -o x$enableval = xno; then
 373     support_selectionscrolling=$enableval
 374   fi])
 375
 376 AC_ARG_ENABLE(mousewheel,
 377   [  --enable-mousewheel     enable scrolling via mouse wheel or buttons 4 & 5],
 378   [if test x$enableval = xyes -o x$enableval = xno; then
 379     support_mousewheel=$enableval
 380   fi])
 381
 382 AC_ARG_ENABLE(slipwheeling,
 383   [  --enable-slipwheeling   enable slip wheel scrolling (requires --enable-mousewheel)],
 384   [if test x$enableval = xyes -o x$enableval = xno; then
 385     support_mouseslipwheel=$enableval
 386   fi])
 387
 388 AC_ARG_ENABLE(smart-resize,
 389   [  --enable-smart-resize   enable smart growth/shrink behaviour],
 390   [if test x$enableval = xyes; then
 391     AC_DEFINE(SMART_RESIZE, 1, Define to use "smart" resize behavior)
 392   fi])
 393
 394 AC_ARG_ENABLE(text-blink,
 395   [  --enable-text-blink     enable blinking text],
 396   [if test x$enableval = xyes -o x$enableval = xno; then
 397     support_text_blink=$enableval
 398   fi])
 399
 400 AC_ARG_ENABLE(pointer-blank,
 401   [  --enable-pointer-blank  enable pointer blank when typing or inactive pointer],
 402   [if test x$enableval = xyes -o x$enableval = xno; then
 403     support_pointer_blank=$enableval
 404   fi])
 405
 406 AC_ARG_WITH(term,
 407   [  --with-term=NAME        set the terminal to NAME (default: rxvt)],
 408   [if test x$withval != x; then
 409     AC_DEFINE_UNQUOTED(TERMENV, "$withval",Set TERM to the value given by configure) term="$withval"
 410   fi])
 411
 412 AC_ARG_WITH(terminfo,
 413   [  --with-terminfo=PATH    set the path to the terminfo tree to PATH],
 414   [if test x$withval != x; then
 415     AC_DEFINE_UNQUOTED(RXVT_TERMINFO, "$withval", Set TERMINFO value to the value given by configure) terminfo="$withval"
 416   fi])
 417
 418 dnl# --------------------------------------------------------------------------
 419
 420 LIBEV_M4_AVOID_LIBRT=1
 421 m4_include([libev/libev.m4])
 422
 423 dnl# --------------------------------------------------------------------------
 424
 425 AC_PATH_PROG(TIC, tic, :)
 426
 427 AC_PATH_XTRA
 428
 429 AFTERIMAGE_CFLAGS=
 430 AFTERIMAGE_LIBS=
 431 AFTERIMAGE_VERSION=
 432
 433 if test x$support_afterimage = xyes; then
 434   support_afterimage=no
 435
 436   if test "x$afterimage_config" = "x" ; then
 437     AC_PATH_PROG(afterimage_config, afterimage-config, no)
 438   fi
 439   if test "x$afterimage_config" != "xno" ; then
 440     AC_MSG_CHECKING(for libAfterImage version >= 1.15)
 441     xAFTERIMAGE_VERSION=`$afterimage_config --version`
 442     if test -n "$xAFTERIMAGE_VERSION" ; then
 443       xAFTERIMAGE_CFLAGS=`$afterimage_config --cflags`
 444       xAFTERIMAGE_LIBS=`$afterimage_config --libs`
 445       if test "x$xAFTERIMAGE_LIBS" != "x"; then
 446         libai_ver_major=`echo $xAFTERIMAGE_VERSION | cut -f 1 -d .`
 447         libai_ver_minor=`echo $xAFTERIMAGE_VERSION | cut -f 2 -d .`
 448         if test $libai_ver_major -gt 1 -o \( $libai_ver_major -eq 1 -a $libai_ver_minor -ge 15 \); then
 449           support_afterimage=yes
 450           AFTERIMAGE_CFLAGS="$xAFTERIMAGE_CFLAGS"
 451           AFTERIMAGE_LIBS="$xAFTERIMAGE_LIBS"
 452           AFTERIMAGE_VERSION="$xAFTERIMAGE_VERSION"
 453         fi
 454       fi
 455     fi
 456     if test "x$support_afterimage" = "xyes"; then
 457       AC_MSG_RESULT($AFTERIMAGE_LIBS)
 458     else
 459       AC_MSG_RESULT(no)
 460     fi
 461   fi
 462 fi
 463
 464 dnl# --------------------------------------------------------------------------
 465 dnl# CHECKING FOR HEADER FILES
 466 dnl# --------------------------------------------------------------------------
 467 AC_CHECK_HEADERS( \
 468         sys/byteorder.h \
 469         sys/ioctl.h \
 470         sys/sockio.h \
 471         sys/strredir.h \
 472         stdint.h \
 473         wchar.h \
 474         cwchar \
 475 )
 476
 477 AC_CACHE_CHECK([for XPointer], rxvt_cv_xpointer,
 478 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XPointer dummy;]])],[rxvt_cv_xpointer=yes],[rxvt_cv_xpointer=no])])
 479 if test x$rxvt_cv_xpointer = xyes; then
 480   AC_DEFINE(HAVE_XPOINTER, 1, Define if you have XPointer typedef)
 481 fi
 482
 483 AC_CACHE_CHECK([for XLIB_ILLEGAL_ACCESS], rxvt_xlib_illegal_access,
 484 [AC_COMPILE_IFELSE(
 485    [AC_LANG_PROGRAM([
 486 #define XLIB_ILLEGAL_ACCESS
 487 #include <X11/Xlib.h>
 488    ],[
 489       Display *dpy;
 490       dpy->xdefaults = (char *)0;
 491    ])],
 492    [rxvt_xlib_illegal_access=yes],[rxvt_xlib_illegal_access=no]
 493 )])
 494 if test x$rxvt_xlib_illegal_access = xyes; then
 495    AC_DEFINE(XLIB_ILLEGAL_ACCESS, 1, Define ONLY iff Xlib.h supports it)
 496 fi
 497
 498 dnl# --------------------------------------------------------------------------
 499 dnl# CHECKING FOR MISSING TYPEDEFS
 500 dnl# --------------------------------------------------------------------------
 501 dnl# Missing typedefs and replacements
 502 AC_TYPE_MODE_T
 503 AC_TYPE_PID_T
 504 AC_TYPE_UID_T
 505 AC_TYPE_INT16_T
 506 AC_TYPE_UINT16_T
 507 AC_TYPE_INT32_T
 508 AC_TYPE_UINT32_T
 509
 510 dnl# --------------------------------------------------------------------------
 511 dnl# CHECKING FOR LIBRARY FUNCTIONS
 512 dnl# --------------------------------------------------------------------------
 513 AC_CHECK_FUNCS(unsetenv)
 514
 515 UTMP_CHECK
 516
 517 dnl# --------------------------------------------------------------------------
 518
 519 dnl# --------------------------------------------------------------------------
 520 dnl# --------------------------------------------------------------------------
 521
 522 dnl# this is a really hack test for some basic Xlocale stuff
 523 save_LIBS=$LIBS
 524 save_CFLAGS=$CFLAGS
 525 CFLAGS="$CFLAGS $X_CFLAGS"
 526 LIBS="$LIBS $X_LIBS $X_EXTRA_LIBS -lX11"
 527 if test x$support_xim = xyes; then
 528   AC_CACHE_CHECK(for working Xlocale, rxvt_cv_func_xlocale,
 529   [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <X11/Xlib.h>
 530   #include <stdlib.h>
 531   main() {
 532   char *p;
 533   if ((p = XSetLocaleModifiers("@im=none")) != NULL && *p)
 534   exit (XSupportsLocale() ? 0 : 1);
 535   else
 536   exit (1);}]])],[dnl
 537     rxvt_cv_func_xlocale=yes],[rxvt_cv_func_xlocale=no],[dnl
 538     :])])
 539   if test x$rxvt_cv_func_xlocale = xyes; then
 540     AC_DEFINE(USE_XIM, 1, Define if you want to have XIM (X Input Method) protocol support - required for multibyte characters input)
 541     AC_CACHE_CHECK(for broken XIM callback, rxvt_broken_ximcb,
 542     [AC_COMPILE_IFELSE([
 543     #include <X11/Xlib.h>
 544
 545     void im_destroy_cb (XIC unused1, XPointer client_data, XPointer unused3);
 546
 547     void f() {
 548       XIMCallback cb;
 549       cb.callback = im_destroy_cb;
 550     }
 551     ],rxvt_broken_ximcb=yes,rxvt_broken_ximcb=no)])
 552
 553     if test x$rxvt_broken_ximcb = xyes; then
 554        AC_DEFINE(XIMCB_PROTO_BROKEN, 1, Define if your XIMCallback specifies XIC as first type.)
 555     fi
 556   fi
 557 fi
 558
 559 AC_CACHE_CHECK(for working X setlocale, rxvt_cv_func_xsetlocale,
 560 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define X_LOCALE 1
 561 #include <X11/Xlocale.h>]], [[setlocale(LC_CTYPE, "");]])],[rxvt_cv_func_xsetlocale=yes],[rxvt_cv_func_xsetlocale=no])])
 562 if test x$rxvt_cv_func_xsetlocale = xyes; then
 563   AC_DEFINE(HAVE_XSETLOCALE, 1, Define if setlocale (defined to Xsetlocale) works)
 564 fi
 565 LIBS=$save_LIBS
 566 CFLAGS=$save_CFLAGS
 567
 568 AC_CACHE_CHECK(for working plain setlocale, rxvt_cv_func_setlocale,
 569 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <clocale>]], [[setlocale(LC_CTYPE, "");]])],[rxvt_cv_func_setlocale=yes],[rxvt_cv_func_setlocale=no])])
 570 if test x$rxvt_cv_func_setlocale = xyes; then
 571   AC_DEFINE(HAVE_SETLOCALE, 1, Define if plain old setlocale works)
 572 fi
 573
 574 AC_CACHE_CHECK(for working nl_langinfo, rxvt_cv_func_nl_langinfo,
 575 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(CODESET);]])],[rxvt_cv_func_nl_langinfo=yes],[rxvt_cv_func_nl_langinfo=no])])
 576 if test x$rxvt_cv_func_nl_langinfo = xyes; then
 577   AC_DEFINE(HAVE_NL_LANGINFO, 1, Define if nl_langinfo(CODESET) works)
 578 fi
 579
 580 SCM_RIGHTS_CHECK
 581
 582 PTY_CHECK
 583
 584 TTY_GROUP_CHECK
 585
 586 dnl# --------------------------------------------------------------------------
 587 dnl# now add and remove other stuff
 588 dnl# --------------------------------------------------------------------------
 589 if test x$support_xft = xyes; then
 590   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 591   if test $PKG_CONFIG != no && $PKG_CONFIG --exists xft; then
 592     X_LIBS="`$PKG_CONFIG xft --libs` $X_LIBS"
 593     CPPFLAGS="$CPPFLAGS `$PKG_CONFIG xft --cflags`"
 594   else
 595     AC_PATH_PROG(XFT_CONFIG, xft-config, no)
 596     if test $XFT_CONFIG != no; then
 597       X_LIBS="`$XFT_CONFIG --libs` $X_LIBS"
 598       CPPFLAGS="$CPPFLAGS `$XFT_CONFIG --cflags`"
 599     fi
 600   fi
 601
 602   save_LIBS="$LIBS"
 603   LIBS="$LIBS $X_LIBS"
 604   AC_CHECK_HEADERS(X11/Xft/Xft.h,,[support_xft=no])
 605   AC_CHECK_LIB(Xft,XftDrawString32,:,[support_xft=no])
 606   LIBS="$save_LIBS"
 607
 608   if test x$support_xft = xyes; then
 609     AC_DEFINE(XFT, 1, Define to enable xft support)
 610   fi
 611 fi
 612 if test x$support_styles = xyes; then
 613   AC_DEFINE(ENABLE_STYLES, 1, Define if you want bold and italic support)
 614 fi
 615 if test x$support_iso14755 = xyes; then
 616   AC_DEFINE(ISO_14755, 1, Define if you want ISO 14755 extended support)
 617 fi
 618 if test x$support_8bitctrls = xyes; then
 619   AC_DEFINE(EIGHT_BIT_CONTROLS, 1, Define if you want 8 bit control sequences)
 620 fi
 621 if test x$support_fading = xyes; then
 622   AC_DEFINE(OFF_FOCUS_FADING, 1, Define if you want faded colors when focus is lost)
 623 fi
 624 if test x$support_inheritpixmap = xyes; then
 625   AC_DEFINE(ENABLE_TRANSPARENCY, 1, Define if you want your background to use the parent window background)
 626 fi
 627 if test x$support_keepscrolling = xno; then
 628   AC_DEFINE(NO_SCROLLBAR_BUTTON_CONTINUAL_SCROLLING, 1, Define for continual scrolling when you keep the scrollbar button pressed)
 629 fi
 630 if test x$support_selectionscrolling = xyes; then
 631   AC_DEFINE(SELECTION_SCROLLING, 1, Define to allow scrolling when the selection moves to the top or bottom of the screen)
 632 fi
 633 if test x$support_frills = xyes; then
 634   AC_DEFINE(ENABLE_FRILLS, 1, Define if you want handling for rarely used but handy features)
 635 fi
 636 if test x$support_mousewheel = xyes; then
 637   AC_DEFINE(MOUSE_WHEEL, 1, Define to use wheel events (button4 and button5) to scroll)
 638 fi
 639 if test x$support_mouseslipwheel = xyes; then
 640   AC_DEFINE(MOUSE_SLIP_WHEELING, 1, Define to have CTRL cause wheel events to accelerate scrolling. Release CTRL to halt scrolling)
 641 fi
 642 if test x$support_afterimage = xyes; then
 643   AC_DEFINE(HAVE_AFTERIMAGE, 1, Define if you want to use libAfterImage for image processing)
 644   AC_DEFINE(BG_IMAGE_FROM_FILE, 1, Define if you want to have sexy-looking background pixmaps. Needs libAfterImage)
 645 fi
 646
 647 dnl if test x$support_afterstep = xyes; then
 648 dnl   AC_DEFINE(AFTERSTEP_INTEGRATION, 1, Define if you want to integrate with AfterStep window manager)
 649 dnl fi
 650
 651 if test x$support_scroll_rxvt = xyes; then
 652   AC_DEFINE(RXVT_SCROLLBAR, 1, Support Rxvt original style scrollbars)
 653   scrolltypes="rxvt"
 654 fi
 655 if test x$support_scroll_next = xyes; then
 656   AC_DEFINE(NEXT_SCROLLBAR, 1, Support NeXT style scrollbars)
 657   scrolltypes="$scrolltypes next"
 658 fi
 659 if test x$support_scroll_xterm = xyes; then
 660   AC_DEFINE(XTERM_SCROLLBAR, 1, Support Xterm style scrollbars)
 661   scrolltypes="$scrolltypes xterm"
 662 fi
 663 if test x$support_scroll_plain = xyes; then
 664   AC_DEFINE(PLAIN_SCROLLBAR, 1, Support plain style scrollbars)
 665   scrolltypes="$scrolltypes plain"
 666 fi
 667 if test x$support_pointer_blank = xyes; then
 668   AC_DEFINE(POINTER_BLANK, 1, Define if you want hide the pointer while typing)
 669 fi
 670 if test x$support_text_blink = xyes; then
 671   AC_DEFINE(TEXT_BLINK, 1, Define if you want blinking text support)
 672 fi
 673 if test x$support_unicode3 = xyes; then
 674   AC_DEFINE(UNICODE_3, 1, Define if you want to represent unicode characters outside plane 0)
 675 fi
 676 if test x$support_combining = xyes; then
 677   AC_DEFINE(ENABLE_COMBINING, 1, Define if you want to automatically compose combining characters)
 678 fi
 679 if test x$codesets = xall; then
 680   codesets=jp,jp-ext,kr,zh,zh-ext
 681 fi
 682 AC_DEFINE(ENCODING_EU, 1, Define if you want european extended codesets)
 683 AC_DEFINE(ENCODING_VN, 1, Define if you want vietnamese codesets)
 684 for codeset in `echo $codesets | tr "[a-z,\\-]" "[A-Z _]"`; do
 685   case "$codeset" in
 686     JP     ) AC_DEFINE(ENCODING_JP,     1, Define if you want japanese codesets) ;;
 687     JP_EXT ) AC_DEFINE(ENCODING_JP_EXT, 1, Define if you want extended japanese codesets) ;;
 688     KR     ) AC_DEFINE(ENCODING_KR,     1, Define if you want korean codesets) ;;
 689     ZH     ) AC_DEFINE(ENCODING_ZH,     1, Define if you want chinese codesets) ;;
 690     ZH_EXT ) AC_DEFINE(ENCODING_ZH_EXT, 1, Define if you want extended chinese codesets) ;;
 691   esac
 692 done
 693
 694 IF_PERL=\#
 695 if test x$support_perl = xyes; then
 696   AC_PATH_PROG(PERL, perl5)
 697   AC_PATH_PROG(PERL, perl)
 698
 699   AC_MSG_CHECKING(for $PERL suitability)
 700   if $PERL -MExtUtils::Embed -e "use v5.8" >/dev/null 2>/dev/null; then
 701
 702      save_CXXFLAGS="$CXXFLAGS"
 703      save_LIBS="$LIBS"
 704      CXXFLAGS="$CXXFLAGS `$PERL -MExtUtils::Embed -e ccopts`"
 705      LIBS="$LIBS `$PERL -MExtUtils::Embed -e ldopts`"
 706      AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 707 #include <EXTERN.h>
 708 #include <perl.h>
 709 #include <XSUB.h>
 710 ]], [[
 711      PerlInterpreter *perl = perl_alloc ();
 712 ]])],[rxvt_perl_link=yes],[rxvt_perl_link=no])
 713      CXXFLAGS="$save_CXXFLAGS"
 714      LIBS="$save_LIBS"
 715
 716      if test x$rxvt_perl_link = xyes; then
 717         AC_MSG_RESULT(ok)
 718         AC_DEFINE(ENABLE_PERL, 1, Define if you can embed a perl interpreter)
 719         IF_PERL=
 720         PERL_O=rxvtperl.o
 721         PERLFLAGS="`$PERL -MExtUtils::Embed -e ccopts`"
 722         PERLLIB="`$PERL -MExtUtils::Embed -e ldopts`"
 723         PERLPRIVLIBEXP="`$PERL -MConfig -e 'print $Config{privlibexp}'`"
 724      else
 725         AC_MSG_ERROR([no, unable to link])
 726      fi
 727   else
 728      AC_MSG_ERROR([no working perl found, or perl not version >= 5.8])
 729   fi
 730 fi
 731 AC_SUBST(PERLLIB)
 732 AC_SUBST(PERLFLAGS)
 733 AC_SUBST(PERLPRIVLIBEXP)
 734 AC_SUBST(PERL)
 735 AC_SUBST(IF_PERL)
 736 AC_SUBST(PERL_O)
 737
 738 AC_SUBST(CFLAGS)
 739 AC_SUBST(CPPFLAGS)
 740 AC_SUBST(LDFLAGS)
 741 AC_SUBST(X_CFLAGS)
 742
 743 dnl# Attack the libs
 744 AC_SUBST(LIBS)
 745 AC_SUBST(X_LIBS)
 746 AC_SUBST(X_EXTRA_LIBS)
 747
 748 AC_SUBST(AFTERIMAGE_CFLAGS)
 749 AC_SUBST(AFTERIMAGE_LIBS)
 750
 751 AC_ARG_PROGRAM
 752
 753 AC_CONFIG_FILES([Makefile \
 754 doc/Makefile \
 755 src/Makefile \
 756 ])
 757 AC_OUTPUT
 758
 759 echo "Configuration:
 760
 761   Rxvt version:               $VERSION : $DATE
 762   Source code location:       $srcdir
 763   Install path:               ${prefix}/bin
 764   Compiler:                   $CXX
 765   Compiler flags:             $CXXFLAGS
 766   Linker:                     $LINKER"
 767
 768 if test x$term != x; then
 769   echo "  set TERM to:                $term"
 770 fi
 771 if test x$terminfo != x; then
 772   echo "  set TERMINFO to:            $terminfo"
 773 fi
 774 echo "  default resource name:      $RESNAME"
 775 echo "  resource class:             $RESCLASS"
 776 if test x$RESFALLBACK != x; then
 777    echo "  resource class fallback:    $RESFALLBACK"
 778 fi
 779 echo
 780 echo "  embedded perl:              $support_perl"
 781 echo "  libafterimage:              $support_afterimage"
 782 dnl echo "  AfterStep integration:      $support_afterstep"
 783 echo
 784 if test x$support_xim = xyes -a x$rxvt_cv_func_xlocale = xno; then
 785   echo ".----------------------------------------------------------------."
 786   echo ". WARNING: --enable-xim was specified however the locale support ."
 787   echo ".          functions could not be found.                         ."
 788   echo ".          XIM is now being DISABLED!                            ."
 789   echo ".----------------------------------------------------------------."
 790 fi
 791
 792 echo "*** Optionally check src/feature.h for further, rarely used options ***"
 793 echo
 794