configure.ac

   1 dnl#
   2 dnl# Process this file with autoconf to produce a configure script.
   3 dnl#
   4
   5 AC_INIT
   6 AC_PREREQ(2.50)
   7 AC_CONFIG_SRCDIR([src/feature.h])
   8 AC_CONFIG_HEADER(config.h:config.h.in)
   9
  10 AC_CANONICAL_HOST
  11
  12 dnl RXVT version
  13 changequote(, )dnl
  14 VERSION=`sed -n -e 's/^.*[ \t]VERSION.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  15 DATE=`sed -n -e 's/^.*[ \t]DATE.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  16 dnl LIBVERSION=`sed -n -e 's/^.*[ \t]LIBVERSION.*"\(.*\)"$/\1/p' ${srcdir}/src/version.h`
  17 changequote([, ])dnl
  18 AC_SUBST(VERSION)dnl
  19 AC_SUBST(DATE)dnl
  20 dnl AC_SUBST(LIBVERSION)dnl
  21
  22 echo ""
  23 echo "configuring for rxvt $VERSION"
  24 echo ""
  25
  26 orig_CXXFLAGS="$CXXFLAGS"
  27
  28 dnl# Checks for programs.
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31 AC_PROG_CPP
  32 AC_PROG_INSTALL
  33
  34 AC_AIX
  35 AC_GNU_SOURCE
  36 AC_ISC_POSIX
  37 AC_LANG(C++)
  38
  39 dnl check wether we can link with gcc -lsupc++
  40 if test x$GCC = xyes && test x$GXX = xyes; then
  41    dnl FreeBSD (at least up to 5.3) has a broken GCC, workaround it
  42    AC_MSG_CHECKING([for working libsupc++])
  43    save_CXX="$CXX"
  44    save_LIBS="$LIBS"
  45    CXX="$CC"
  46    LIBS="$LIBS -lsupc++"
  47    LINKER="$CC"
  48    AC_LINK_IFELSE(
  49       [AC_LANG_PROGRAM([struct test { }; void f() try { throw new test; } catch (...) { throw; }],[])],
  50       [AC_MSG_RESULT(ok)],
  51       [
  52          AC_MSG_RESULT([no, making everything bigger and slower])
  53          LIBS="$save_LIBS"
  54          LINKER="$save_CXX"
  55       ]
  56    )
  57    CXX="$save_CXX"
  58 fi
  59 AC_SUBST(LINKER,[$LINKER])
  60
  61 dnl# --------------------------------------------------------------------------
  62 dnl# Supply default CXXFLAGS, if not specified by `CXXFLAGS=flags ./configure'
  63 dnl#
  64 if test -z "$orig_CXXFLAGS"; then
  65   if test x$GCC = xyes && test "x$GXX" = xyes; then
  66     CXXFLAGS="-g -O3 -fno-rtti -fvisibility-inlines-hidden -fno-threadsafe-statics -fno-enforce-eh-specs"
  67     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [], [CXXFLAGS="-g -O3"])
  68   else
  69     CXXFLAGS="-O"
  70   fi
  71   CFLAGS="$CXXFLAGS"
  72 fi
  73
  74 case $host in
  75    *-*-solaris* )
  76       AC_DEFINE(_XOPEN_SOURCE, 500, Needed to get declarations for msg_control and msg_controllen on Solaris)
  77       ;;
  78 esac
  79
  80 dnl# FreeBSD needs to link libxpg4
  81 AC_CHECK_FUNC(setlocale,     [], [AC_CHECK_LIB(xpg4,   setlocale,     [LIBS="$LIBS -lxpg4"])])
  82
  83 dnl# solaris needs to link libnsl and socket
  84 AC_CHECK_FUNC(gethostbyname, [], [AC_CHECK_LIB(nsl,    gethostbyname, [LIBS="$LIBS -lnsl"])])
  85 AC_CHECK_FUNC(socket,        [], [AC_CHECK_LIB(socket, socket,        [LIBS="$LIBS -lsocket"])])
  86
  87 dnl AC_ENABLE_SHARED(no)dnl#    libtool
  88 dnl AC_ENABLE_STATIC(yes)dnl#   libtool
  89 dnl AC_PROG_LIBTOOL()dnl#               libtool
  90
  91 support_frills=yes
  92 support_inheritpixmap=yes
  93 support_fading=yes
  94 support_keepscrolling=yes
  95 support_selectionscrolling=yes
  96 support_mousewheel=yes
  97 support_mouseslipwheel=yes
  98 support_text_blink=yes
  99 support_pointer_blank=yes
 100 support_scroll_rxvt=yes
 101 support_scroll_next=yes
 102 support_scroll_xterm=yes
 103 support_scroll_plain=yes
 104 support_xim=yes
 105 support_afterimage=yes
 106 support_afterstep=yes
 107 support_xft=yes
 108 support_unicode3=no
 109 support_combining=yes
 110 support_8bitctrls=no
 111 support_iso14755=yes
 112 support_styles=yes
 113 support_perl=yes
 114 codesets=all
 115
 116 dnl# --------------------------------------------------------------------------
 117 dnl# CHECKING COMMAND LINE OPTIONS
 118 dnl# --------------------------------------------------------------------------
 119
 120 dnl if test "x$enable_shared" = xyes; then
 121 dnl     AC_DEFINE(LIBRXVT, 1, Build shared library version - specify via configure only)
 122 dnl     INSTALL_LIBRXVT=yes
 123 dnl fi
 124 dnl AC_SUBST(INSTALL_LIBRXVT)
 125
 126 AC_ARG_ENABLE(everything,
 127   [  --enable-everything     enable standard non-multichoice features
 128                      NOTE: this option is order dependent],
 129   [
 130     if test x$enableval = xno; then
 131        support_frills=no
 132        support_inheritpixmap=no
 133        support_fading=no
 134        support_keepscrolling=no
 135        support_selectionscrolling=no
 136        support_lastlog=no
 137        support_mousewheel=no
 138        support_mouseslipwheel=no
 139        support_text_blink=no
 140        support_pointer_blank=no
 141        support_scroll_rxvt=no
 142        support_scroll_next=no
 143        support_scroll_xterm=no
 144        support_scroll_plain=no
 145        support_utmp=no
 146        support_wtmp=no
 147        support_xim=no
 148        support_afterimage=no
 149        support_afterstep=no
 150        support_xft=no
 151        support_unicode3=no
 152        support_combining=no
 153        support_8bitctrls=no
 154        support_iso14755=no
 155        support_styles=no
 156        support_perl=no
 157        codesets=
 158     fi
 159     if test x$enableval = xyes; then
 160        support_frills=yes
 161        support_inheritpixmap=yes
 162        support_fading=yes
 163        support_keepscrolling=yes
 164        support_selectionscrolling=yes
 165        support_lastlog=yes
 166        support_mousewheel=yes
 167        support_mouseslipwheel=yes
 168        support_text_blink=yes
 169        support_pointer_blank=yes
 170        support_scroll_rxvt=yes
 171        support_scroll_next=yes
 172        support_scroll_xterm=yes
 173        support_scroll_plain=yes
 174        support_utmp=yes
 175        support_wtmp=yes
 176        support_xim=yes
 177        support_afterimage=yes
 178        support_afterstep=yes
 179        support_xft=yes
 180        support_unicode3=yes
 181        support_combining=yes
 182        #support_8bitctrls=yes
 183        support_iso14755=yes
 184        support_styles=yes
 185        support_perl=yes
 186        codesets=all
 187     fi
 188   ])
 189
 190 WARNINGS=no
 191 AC_ARG_ENABLE(warnings,
 192   [  --enable-warnings       turn on g++ warnings],
 193   [if test x$enableval = xyes; then
 194     WARNINGS=yes
 195   fi])
 196 if test x$GXX = xyes; then
 197   if test $WARNINGS = yes; then
 198     save_CXXFLAGS="$CXXFLAGS"
 199     CXXFLAGS="$CXXFLAGS -Wall -Wno-sign-compare -Wno-reorder -Wno-non-virtual-dtor"
 200     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [], [CXXFLAGS="$save_CXXFLAGS"])
 201   else
 202     CXXFLAGS="$CXXFLAGS -w"
 203   fi
 204 fi
 205
 206 AC_ARG_ENABLE(unicode3,
 207   [  --enable-unicode3       use 21 instead of 16 bits to represent unicode characters],
 208   [if test x$enableval = xyes -o x$enableval = xno; then
 209     support_unicode3=$enableval
 210   fi])
 211
 212 AC_ARG_ENABLE(combining,
 213   [  --enable-combining      enable composition of base and combining characters],
 214   [if test x$enableval = xyes -o x$enableval = xno; then
 215     support_combining=$enableval
 216   fi])
 217
 218 AC_ARG_ENABLE(xft,
 219   [  --enable-xft            enable xft support on systems that have it],
 220   [if test x$enableval = xyes -o x$enableval = xno; then
 221     support_xft=$enableval
 222   fi])
 223
 224 AC_ARG_ENABLE(font-styles,
 225   [  --enable-font-styles    enable bold and italic support],
 226   [if test x$enableval = xyes -o x$enableval = xno; then
 227     support_styles=$enableval
 228   fi])
 229
 230 AC_ARG_ENABLE(afterimage,
 231   [  --enable-afterimage enable integration with libAfterImage for background images],
 232   [if test x$enableval = xyes -o x$enableval = xno; then
 233     support_afterimage=$enableval
 234   fi])
 235
 236 AC_ARG_WITH(afterimage_config,
 237   [  --with-afterimage-config=DIR  use libAfterImage config script in DIR],
 238   [if test "x$withval" != x; then
 239     afterimage_config=$withval/afterimage-config
 240   fi])
 241
 242 dnl AC_ARG_ENABLE(afterstep,
 243 dnl   [  --enable-afterstep enable integration with AfterStep window manager],
 244 dnl   [if test x$enableval = xyes -o x$enableval = xno; then
 245 dnl     support_afterstep=$enableval
 246 dnl   fi])
 247
 248 AC_ARG_ENABLE(transparency,
 249   [  --enable-transparency   enable transparent backgrounds],
 250   [if test x$enableval = xyes -o x$enableval = xno; then
 251     support_inheritpixmap=$enableval
 252   fi])
 253
 254 AC_ARG_ENABLE(fading,
 255   [  --enable-fading         enable colors fading when off focus],
 256   [if test x$enableval = xyes -o x$enableval = xno; then
 257     support_fading=$enableval
 258   fi])
 259
 260 AC_ARG_ENABLE(rxvt-scroll,
 261   [  --enable-rxvt-scroll    enable rxvt style scrollbar],
 262   [if test x$enableval = xyes -o x$enableval = xno; then
 263     support_scroll_rxvt=$enableval
 264   fi])
 265
 266 AC_ARG_ENABLE(next-scroll,
 267   [  --enable-next-scroll    enable NeXT style scrollbar],
 268   [if test x$enableval = xyes -o x$enableval = xno; then
 269     support_scroll_next=$enableval
 270   fi])
 271
 272 AC_ARG_ENABLE(xterm-scroll,
 273   [  --enable-xterm-scroll   enable Xterm style scrollbar],
 274   [if test x$enableval = xyes -o x$enableval = xno; then
 275     support_scroll_xterm=$enableval
 276   fi])
 277
 278 AC_ARG_ENABLE(plain-scroll,
 279   [  --enable-plain-scroll   enable plain style scrollbar],
 280   [if test x$enableval = xyes -o x$enableval = xno; then
 281     support_scroll_plain=$enableval
 282   fi])
 283
 284 AC_ARG_ENABLE(perl,
 285   [  --enable-perl           enable embedded perl interpreter],
 286   [if test x$enableval = xyes -o x$enableval = xno; then
 287     support_perl=$enableval
 288   fi])
 289
 290 AC_ARG_WITH(codesets,
 291   [  --with-codesets=CS,...  compile in additional codesets (jp,jp_ext,kr,zh,zh_ext,all)],
 292   [codesets="$withval"])
 293
 294 AC_ARG_ENABLE(xim,
 295   [  --enable-xim            XIM (X Input Method) protocol support],
 296   [if test x$enableval = xyes -o x$enableval = xno; then
 297     support_xim=$enableval
 298   fi])
 299
 300 AC_ARG_ENABLE(backspace-key,
 301   [  --disable-backspace-key disable handling of the backspace key],
 302   [if test x$enableval = xno; then
 303     AC_DEFINE(NO_BACKSPACE_KEY, 1, Define if you don't want support for the backspace key)
 304   fi])
 305
 306 AC_ARG_ENABLE(delete-key,
 307   [  --disable-delete-key    disable handling of the delete key],
 308   [if test x$enableval = xno; then
 309     AC_DEFINE(NO_DELETE_KEY, 1, Define if you don't want support for the (non-keypad) delete key)
 310   fi])
 311
 312 AC_ARG_ENABLE(resources,
 313   [  --disable-resources     disable all resource checking],
 314   [if test x$enableval = xno; then
 315     AC_DEFINE(NO_RESOURCES, 1, Define if you don't want any resources read)
 316   fi])
 317
 318 AC_ARG_ENABLE(8bitctrls,
 319   [  --enable-8bitctrls      enable 8 bit control sequences (not recommended)],
 320   [if test x$enableval = xyes -o x$enableval = xno; then
 321     support_8bitctrls=$enableval
 322   fi])
 323
 324 RESFALLBACK=Rxvt
 325 AC_ARG_ENABLE(fallback,
 326   [  --enable-fallback@<:@=CLASS@:>@ fall back on CLASS resources in addition to URxvt ones (default: Rxvt)],
 327   [
 328    test x$enableval = xyes && enableval=Rxvt
 329    test x$enableval = xno  && enableval=
 330    RESFALLBACK="$enableval"
 331   ])
 332
 333 if test x$RESFALLBACK != x; then
 334    AC_DEFINE_UNQUOTED(RESFALLBACK, "$RESFALLBACK", [Fallback resource class])
 335 fi
 336
 337 RESNAME=urxvt
 338 AC_ARG_WITH(res-name,
 339   [  --with-res-name=NAME    use this as default resource name (default: urxvt)],
 340   [RESNAME="$withval"])
 341 AC_DEFINE_UNQUOTED(RESNAME,"$RESNAME", [Default resource name])
 342
 343 RESCLASS=URxvt
 344 AC_ARG_WITH(res-class,
 345   [  --with-res-class=CLASS  use this as the resource class (default: URxvt)],
 346   [RESCLASS="$withval"])
 347 AC_DEFINE_UNQUOTED(RESCLASS,"$RESCLASS", [Resource class])
 348
 349 RXVTNAME=urxvt
 350 AC_ARG_WITH(name,
 351   [  --with-name=NAME        set the basename for the installed binaries (default: urxvt)],
 352   [RXVTNAME="$withval"])
 353 AC_DEFINE_UNQUOTED(RXVTNAME,"$RXVTNAME", [Binary base name])
 354
 355 RXVTNAME=`echo "$RXVTNAME"|sed "$program_transform_name"`
 356 AC_SUBST(RXVTNAME)
 357
 358 AC_ARG_ENABLE(swapscreen,
 359   [  --disable-swapscreen    disable swap screen support],
 360   [if test x$enableval = xno; then
 361     AC_DEFINE(NO_SECONDARY_SCREEN, 1, Disable the secondary screen. Many programs use the secondary screen as their workplace)
 362   fi])
 363
 364 AC_ARG_ENABLE(iso14755,
 365   [  --enable-iso14755       enable support for extended ISO 14755 modes],
 366   [if test x$enableval = xyes -o x$enableval = xno; then
 367     support_iso14755=$enableval
 368   fi])
 369
 370 AC_ARG_ENABLE(frills,
 371   [  --enable-frills         enable support for rarely used features],
 372   [if test x$enableval = xyes -o x$enableval = xno; then
 373     support_frills=$enableval
 374   fi])
 375
 376 AC_ARG_ENABLE(keepscrolling,
 377   [  --enable-keepscrolling  enable continual scrolling on scrollbar arrow press],
 378   [if test x$enableval = xyes -o x$enableval = xno; then
 379     support_keepscrolling=$enableval
 380   fi])
 381
 382 AC_ARG_ENABLE(selectionscrolling,
 383   [  --enable-selectionscrolling  enable scrolling during selections],
 384   [if test x$enableval = xyes -o x$enableval = xno; then
 385     support_selectionscrolling=$enableval
 386   fi])
 387
 388 AC_ARG_ENABLE(mousewheel,
 389   [  --enable-mousewheel     enable scrolling via mouse wheel or buttons 4 & 5],
 390   [if test x$enableval = xyes -o x$enableval = xno; then
 391     support_mousewheel=$enableval
 392   fi])
 393
 394 AC_ARG_ENABLE(slipwheeling,
 395   [  --enable-slipwheeling   enable slip wheel scrolling (requires --enable-mousewheel)],
 396   [if test x$enableval = xyes -o x$enableval = xno; then
 397     support_mouseslipwheel=$enableval
 398   fi])
 399
 400 AC_ARG_ENABLE(smart-resize,
 401   [  --enable-smart-resize   enable smart growth/shrink behaviour],
 402   [if test x$enableval = xyes; then
 403     AC_DEFINE(SMART_RESIZE, 1, Define to use "smart" resize behavior)
 404   fi])
 405
 406 AC_ARG_ENABLE(text-blink,
 407   [  --enable-text-blink     enable blinking text],
 408   [if test x$enableval = xyes -o x$enableval = xno; then
 409     support_text_blink=$enableval
 410   fi])
 411
 412 AC_ARG_ENABLE(pointer-blank,
 413   [  --enable-pointer-blank  enable pointer blank when typing or inactive pointer],
 414   [if test x$enableval = xyes -o x$enableval = xno; then
 415     support_pointer_blank=$enableval
 416   fi])
 417
 418 AC_ARG_WITH(term,
 419   [  --with-term=NAME        set the terminal to NAME (default: rxvt)],
 420   [if test x$withval != x; then
 421     AC_DEFINE_UNQUOTED(TERMENV, "$withval",Set TERM to the value given by configure) term="$withval"
 422   fi])
 423
 424 AC_ARG_WITH(terminfo,
 425   [  --with-terminfo=PATH    set the path to the terminfo tree to PATH],
 426   [if test x$withval != x; then
 427     AC_DEFINE_UNQUOTED(RXVT_TERMINFO, "$withval", Set TERMINFO value to the value given by configure) terminfo="$withval"
 428   fi])
 429
 430 dnl# --------------------------------------------------------------------------
 431
 432 LIBEV_M4_AVOID_LIBRT=1
 433 m4_include([libev/libev.m4])
 434
 435 dnl# --------------------------------------------------------------------------
 436
 437 AC_PATH_PROG(TIC, tic, :)
 438
 439 AC_PATH_XTRA
 440
 441 AFTERIMAGE_CFLAGS=
 442 AFTERIMAGE_LIBS=
 443 AFTERIMAGE_VERSION=
 444
 445 if test x$support_afterimage = xyes; then
 446   support_afterimage=no
 447
 448   if test "x$afterimage_config" = "x" ; then
 449     AC_PATH_PROG(afterimage_config, afterimage-config, no)
 450   fi
 451   if test "x$afterimage_config" != "xno" ; then
 452     AC_MSG_CHECKING(for libAfterImage version >= 1.15)
 453     xAFTERIMAGE_VERSION=`$afterimage_config --version`
 454     if test -n "$xAFTERIMAGE_VERSION" ; then
 455       xAFTERIMAGE_CFLAGS=`$afterimage_config --cflags`
 456       xAFTERIMAGE_LIBS=`$afterimage_config --libs`
 457       if test "x$xAFTERIMAGE_LIBS" != "x"; then
 458         libai_ver_major=`echo $xAFTERIMAGE_VERSION | cut -f 1 -d .`
 459         libai_ver_minor=`echo $xAFTERIMAGE_VERSION | cut -f 2 -d .`
 460         if test $libai_ver_major -gt 1 -o \( $libai_ver_major -eq 1 -a $libai_ver_minor -ge 15 \); then
 461           support_afterimage=yes
 462           AFTERIMAGE_CFLAGS="$xAFTERIMAGE_CFLAGS"
 463           AFTERIMAGE_LIBS="$xAFTERIMAGE_LIBS"
 464           AFTERIMAGE_VERSION="$xAFTERIMAGE_VERSION"
 465         fi
 466       fi
 467     fi
 468     if test "x$support_afterimage" = "xyes"; then
 469       AC_MSG_RESULT($AFTERIMAGE_LIBS)
 470     else
 471       AC_MSG_RESULT(no)
 472     fi
 473   fi
 474 fi
 475
 476 dnl# --------------------------------------------------------------------------
 477 dnl# CHECKING FOR HEADER FILES
 478 dnl# --------------------------------------------------------------------------
 479 AC_CHECK_HEADERS( \
 480         sys/byteorder.h \
 481         sys/ioctl.h \
 482         sys/sockio.h \
 483         sys/strredir.h \
 484         stdint.h \
 485         wchar.h \
 486         cwchar \
 487         clocale \
 488 )
 489
 490 dnl# check to allow both <termios.h> and <sys/ioctl.h>
 491 AC_CACHE_CHECK(whether termios.h and sys/ioctl.h may both be included, rxvt_cv_header_sysioctl,
 492 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 493 #include <sys/ioctl.h>
 494 #include <termios.h>
 495 ]], [[int a = ECHO;]])],[rxvt_cv_header_sysioctl=yes],[rxvt_cv_header_sysioctl=no])])
 496
 497 AC_CACHE_CHECK([for XPointer], rxvt_cv_xpointer,
 498 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XPointer dummy;]])],[rxvt_cv_xpointer=yes],[rxvt_cv_xpointer=no])])
 499 if test x$rxvt_cv_xpointer = xyes; then
 500   AC_DEFINE(HAVE_XPOINTER, 1, Define if you have XPointer typedef)
 501 fi
 502
 503 AC_CACHE_CHECK([for XLIB_ILLEGAL_ACCESS], rxvt_xlib_illegal_access,
 504 [AC_COMPILE_IFELSE(
 505    [AC_LANG_PROGRAM([
 506 #define XLIB_ILLEGAL_ACCESS
 507 #include <X11/Xlib.h>
 508    ],[
 509       Display *dpy;
 510       dpy->xdefaults = (char *)0;
 511    ])],
 512    [rxvt_xlib_illegal_access=yes],[rxvt_xlib_illegal_access=no]
 513 )])
 514 if test x$rxvt_xlib_illegal_access = xyes; then
 515    AC_DEFINE(XLIB_ILLEGAL_ACCESS, 1, Define ONLY iff Xlib.h supports it)
 516 fi
 517
 518 dnl# --------------------------------------------------------------------------
 519 dnl# CHECKING FOR MISSING TYPEDEFS
 520 dnl# --------------------------------------------------------------------------
 521 dnl# Missing typedefs and replacements
 522 AC_TYPE_MODE_T
 523 dnl> AC_CHECK_TYPE(umode_t, int)
 524 dnl> AC_CHECK_TYPE(off_t, long)
 525 AC_TYPE_PID_T
 526 AC_TYPE_UID_T
 527
 528 AC_CHECK_SIZEOF(short, 2)
 529 AC_CHECK_SIZEOF(int, 4)
 530 dnl AC_CHECK_SIZEOF(long, 4)
 531 AC_CHECK_SIZEOF(long long, 8)
 532 AC_CHECK_SIZEOF(int *, 4)
 533
 534 dnl# see usage below
 535 AC_DEFUN([RXVT_CHECK_SIZE],
 536   [AC_CACHE_CHECK([for $2], $1,
 537     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdint.h>]], [[$2 dummy;]])],[$1=yes],[dnl
 538 if test "$ac_cv_sizeof_char" -ge $3; then
 539   $1="$4 char"
 540 else
 541   if test "$ac_cv_sizeof_short" -ge $3; then
 542     $1="$4 short"
 543   else
 544     if test "$ac_cv_sizeof_int" -ge $3; then
 545       $1="$4 int"
 546     else
 547       if test "$ac_cv_sizeof_long" -ge $3; then
 548         $1="$4 long"
 549       else
 550         if test "$ac_cv_sizeof_long_long" -ge $3; then
 551           $1="$4 long long"
 552         else
 553           $1="$4 $5" # we _must_ have a (possibly wrong) default
 554         fi
 555       fi
 556     fi
 557   fi
 558 fi])])]
 559 if test x"$$1" != xyes; then
 560   $6="typedef $$1 $2;"
 561 else
 562   if test x"$4" = x; then
 563     $6="/* typedef $5 $2; */"
 564   else
 565     $6="/* typedef $4 $5 $2; */"
 566   fi
 567 fi dnl
 568 )
 569 dnl#
 570 dnl# Look for types the system may know about anyway.
 571 dnl#
 572 RXVT_CHECK_SIZE(rxvt_cv_int16_t, int16_t, 2, , short, rxvt_int16_typedef)
 573 AC_SUBST(rxvt_int16_typedef)
 574 RXVT_CHECK_SIZE(rxvt_cv_uint16_t, uint16_t, 2, unsigned, short, rxvt_uint16_typedef)
 575 AC_SUBST(rxvt_uint16_typedef)
 576 RXVT_CHECK_SIZE(rxvt_cv_int32_t, int32_t, 4, , int, rxvt_int32_typedef)
 577 AC_SUBST(rxvt_int32_typedef)
 578 RXVT_CHECK_SIZE(rxvt_cv_uint32_t, uint32_t, 4, unsigned, int, rxvt_uint32_typedef)
 579 AC_SUBST(rxvt_uint32_typedef)
 580 dnl RXVT_CHECK_SIZE(rxvt_cv_int64_t, int64_t, 8, , long long, rxvt_int64_typedef)
 581 dnl AC_SUBST(rxvt_int64_typedef)
 582 dnl RXVT_CHECK_SIZE(rxvt_cv_uint64_t, uint64_t, 8, unsigned, long long, rxvt_uint64_typedef)
 583 dnl AC_SUBST(rxvt_uint64_typedef)
 584
 585 dnl# --------------------------------------------------------------------------
 586 dnl# CHECKING FOR LIBRARY FUNCTIONS
 587 dnl# --------------------------------------------------------------------------
 588 AC_CHECK_FUNCS(unsetenv)
 589
 590 UTMP_CHECK
 591
 592 dnl# --------------------------------------------------------------------------
 593
 594 dnl# --------------------------------------------------------------------------
 595 dnl# --------------------------------------------------------------------------
 596
 597 dnl# this is a really hack test for some basic Xlocale stuff
 598 save_LIBS=$LIBS
 599 save_CFLAGS=$CFLAGS
 600 CFLAGS="$CFLAGS $X_CFLAGS"
 601 LIBS="$LIBS $X_LIBS $X_EXTRA_LIBS -lX11"
 602 if test x$support_xim = xyes; then
 603   AC_CACHE_CHECK(for working Xlocale, rxvt_cv_func_xlocale,
 604   [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <X11/Xlib.h>
 605   #include <stdlib.h>
 606   main() {
 607   char *p;
 608   if ((p = XSetLocaleModifiers("@im=none")) != NULL && *p)
 609   exit (XSupportsLocale() ? 0 : 1);
 610   else
 611   exit (1);}]])],[dnl
 612     rxvt_cv_func_xlocale=yes],[rxvt_cv_func_xlocale=no],[dnl
 613     :])])
 614   if test x$rxvt_cv_func_xlocale = xyes; then
 615     AC_DEFINE(USE_XIM, 1, Define if you want to have XIM (X Input Method) protocol support - required for multibyte characters input)
 616     AC_CACHE_CHECK(for broken XIM callback, rxvt_broken_ximcb,
 617     [AC_COMPILE_IFELSE([
 618     #include <X11/Xlib.h>
 619
 620     void im_destroy_cb (XIC unused1, XPointer client_data, XPointer unused3);
 621
 622     void f() {
 623       XIMCallback cb;
 624       cb.callback = im_destroy_cb;
 625     }
 626     ],rxvt_broken_ximcb=yes,rxvt_broken_ximcb=no)])
 627
 628     if test x$rxvt_broken_ximcb = xyes; then
 629        AC_DEFINE(XIMCB_PROTO_BROKEN, 1, Define if your XIMCallback specifies XIC as first type.)
 630     fi
 631   fi
 632 fi
 633
 634 AC_CACHE_CHECK(for working X setlocale, rxvt_cv_func_xsetlocale,
 635 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define X_LOCALE 1
 636 #include <X11/Xlocale.h>]], [[setlocale(LC_CTYPE, "");]])],[rxvt_cv_func_xsetlocale=yes],[rxvt_cv_func_xsetlocale=no])])
 637 if test x$rxvt_cv_func_xsetlocale = xyes; then
 638   AC_DEFINE(HAVE_XSETLOCALE, 1, Define if setlocale (defined to Xsetlocale) works)
 639 fi
 640 LIBS=$save_LIBS
 641 CFLAGS=$save_CFLAGS
 642
 643 AC_CACHE_CHECK(for working plain setlocale, rxvt_cv_func_setlocale,
 644 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <clocale>]], [[setlocale(LC_CTYPE, "");]])],[rxvt_cv_func_setlocale=yes],[rxvt_cv_func_setlocale=no])])
 645 if test x$rxvt_cv_func_setlocale = xyes; then
 646   AC_DEFINE(HAVE_SETLOCALE, 1, Define if plain old setlocale works)
 647 fi
 648
 649 AC_CACHE_CHECK(for working nl_langinfo, rxvt_cv_func_nl_langinfo,
 650 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(CODESET);]])],[rxvt_cv_func_nl_langinfo=yes],[rxvt_cv_func_nl_langinfo=no])])
 651 if test x$rxvt_cv_func_nl_langinfo = xyes; then
 652   AC_DEFINE(HAVE_NL_LANGINFO, 1, Define if nl_langinfo(CODESET) works)
 653 fi
 654
 655 SCM_RIGHTS_CHECK
 656
 657 PTY_CHECK
 658
 659 TTY_GROUP_CHECK
 660
 661 dnl# --------------------------------------------------------------------------
 662 dnl# now add and remove other stuff
 663 dnl# --------------------------------------------------------------------------
 664 if test x$support_xft = xyes; then
 665   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 666   if test $PKG_CONFIG != no && $PKG_CONFIG --exists xft; then
 667     X_LIBS="`$PKG_CONFIG xft --libs` $X_LIBS"
 668     CPPFLAGS="$CPPFLAGS `$PKG_CONFIG xft --cflags`"
 669   else
 670     AC_PATH_PROG(XFT_CONFIG, xft-config, no)
 671     if test $XFT_CONFIG != no; then
 672       X_LIBS="`$XFT_CONFIG --libs` $X_LIBS"
 673       CPPFLAGS="$CPPFLAGS `$XFT_CONFIG --cflags`"
 674     fi
 675   fi
 676
 677   save_LIBS="$LIBS"
 678   LIBS="$LIBS $X_LIBS"
 679   AC_CHECK_HEADERS(X11/Xft/Xft.h,,[support_xft=no])
 680   AC_CHECK_LIB(Xft,XftDrawString32,:,[support_xft=no])
 681   LIBS="$save_LIBS"
 682
 683   if test x$support_xft = xyes; then
 684     AC_DEFINE(XFT, 1, Define to enable xft support)
 685   fi
 686 fi
 687 if test x$support_styles = xyes; then
 688   AC_DEFINE(ENABLE_STYLES, 1, Define if you want bold and italic support)
 689 fi
 690 if test x$support_iso14755 = xyes; then
 691   AC_DEFINE(ISO_14755, 1, Define if you want ISO 14755 extended support)
 692 fi
 693 if test x$support_8bitctrls = xyes; then
 694   AC_DEFINE(EIGHT_BIT_CONTROLS, 1, Define if you want 8 bit control sequences)
 695 fi
 696 if test x$support_fading = xyes; then
 697   AC_DEFINE(OFF_FOCUS_FADING, 1, Define if you want faded colors when focus is lost)
 698 fi
 699 if test x$support_inheritpixmap = xyes; then
 700   AC_DEFINE(ENABLE_TRANSPARENCY, 1, Define if you want your background to use the parent window background)
 701 fi
 702 if test x$support_keepscrolling = xno; then
 703   AC_DEFINE(NO_SCROLLBAR_BUTTON_CONTINUAL_SCROLLING, 1, Define for continual scrolling when you keep the scrollbar button pressed)
 704 fi
 705 if test x$support_selectionscrolling = xyes; then
 706   AC_DEFINE(SELECTION_SCROLLING, 1, Define to allow scrolling when the selection moves to the top or bottom of the screen)
 707 fi
 708 if test x$support_frills = xyes; then
 709   AC_DEFINE(ENABLE_FRILLS, 1, Define if you want handling for rarely used but handy features)
 710 fi
 711 if test x$support_mousewheel = xyes; then
 712   AC_DEFINE(MOUSE_WHEEL, 1, Define to use wheel events (button4 and button5) to scroll)
 713 fi
 714 if test x$support_mouseslipwheel = xyes; then
 715   AC_DEFINE(MOUSE_SLIP_WHEELING, 1, Define to have CTRL cause wheel events to accelerate scrolling. Release CTRL to halt scrolling)
 716 fi
 717 if test x$support_afterimage = xyes; then
 718   AC_DEFINE(HAVE_AFTERIMAGE, 1, Define if you want to use libAfterImage for image processing)
 719   AC_DEFINE(BG_IMAGE_FROM_FILE, 1, Define if you want to have sexy-looking background pixmaps. Needs libAfterImage)
 720 fi
 721
 722 dnl if test x$support_afterstep = xyes; then
 723 dnl   AC_DEFINE(AFTERSTEP_INTEGRATION, 1, Define if you want to integrate with AfterStep window manager)
 724 dnl fi
 725
 726 if test x$support_scroll_rxvt = xyes; then
 727   AC_DEFINE(RXVT_SCROLLBAR, 1, Support Rxvt original style scrollbars)
 728   scrolltypes="rxvt"
 729 fi
 730 if test x$support_scroll_next = xyes; then
 731   AC_DEFINE(NEXT_SCROLLBAR, 1, Support NeXT style scrollbars)
 732   scrolltypes="$scrolltypes next"
 733 fi
 734 if test x$support_scroll_xterm = xyes; then
 735   AC_DEFINE(XTERM_SCROLLBAR, 1, Support Xterm style scrollbars)
 736   scrolltypes="$scrolltypes xterm"
 737 fi
 738 if test x$support_scroll_plain = xyes; then
 739   AC_DEFINE(PLAIN_SCROLLBAR, 1, Support plain style scrollbars)
 740   scrolltypes="$scrolltypes plain"
 741 fi
 742 if test x$support_pointer_blank = xyes; then
 743   AC_DEFINE(POINTER_BLANK, 1, Define if you want hide the pointer while typing)
 744 fi
 745 if test x$support_text_blink = xyes; then
 746   AC_DEFINE(TEXT_BLINK, 1, Define if you want blinking text support)
 747 fi
 748 if test x$support_unicode3 = xyes; then
 749   AC_DEFINE(UNICODE_3, 1, Define if you want to represent unicode characters outside plane 0)
 750 fi
 751 if test x$support_combining = xyes; then
 752   AC_DEFINE(ENABLE_COMBINING, 1, Define if you want to automatically compose combining characters)
 753 fi
 754 if test x$codesets = xall; then
 755   codesets=jp,jp-ext,kr,zh,zh-ext
 756 fi
 757 AC_DEFINE(ENCODING_EU, 1, Define if you want european extended codesets)
 758 AC_DEFINE(ENCODING_VN, 1, Define if you want vietnamese codesets)
 759 for codeset in `echo $codesets | tr "[a-z,\\-]" "[A-Z _]"`; do
 760   case "$codeset" in
 761     JP     ) AC_DEFINE(ENCODING_JP,     1, Define if you want japanese codesets) ;;
 762     JP_EXT ) AC_DEFINE(ENCODING_JP_EXT, 1, Define if you want extended japanese codesets) ;;
 763     KR     ) AC_DEFINE(ENCODING_KR,     1, Define if you want korean codesets) ;;
 764     ZH     ) AC_DEFINE(ENCODING_ZH,     1, Define if you want chinese codesets) ;;
 765     ZH_EXT ) AC_DEFINE(ENCODING_ZH_EXT, 1, Define if you want extended chinese codesets) ;;
 766   esac
 767 done
 768
 769 IF_PERL=\#
 770 if test x$support_perl = xyes; then
 771   AC_PATH_PROG(PERL, perl5)
 772   AC_PATH_PROG(PERL, perl)
 773
 774   AC_MSG_CHECKING(for $PERL suitability)
 775   if $PERL -MExtUtils::Embed -e "use v5.8" >/dev/null 2>/dev/null; then
 776
 777      save_CXXFLAGS="$CXXFLAGS"
 778      save_LIBS="$LIBS"
 779      CXXFLAGS="$CXXFLAGS `$PERL -MExtUtils::Embed -e ccopts`"
 780      LIBS="$LIBS `$PERL -MExtUtils::Embed -e ldopts`"
 781      AC_TRY_LINK([
 782 #include <EXTERN.h>
 783 #include <perl.h>
 784 #include <XSUB.h>
 785 ],[
 786      PerlInterpreter *perl = perl_alloc ();
 787 ],[rxvt_perl_link=yes],[rxvt_perl_link=no])
 788      CXXFLAGS="$save_CXXFLAGS"
 789      LIBS="$save_LIBS"
 790
 791      if test x$rxvt_perl_link = xyes; then
 792         AC_MSG_RESULT(ok)
 793         AC_DEFINE(ENABLE_PERL, 1, Define if you can embed a perl interpreter)
 794         IF_PERL=
 795         PERL_O=rxvtperl.o
 796         PERLFLAGS="`$PERL -MExtUtils::Embed -e ccopts`"
 797         PERLLIB="`$PERL -MExtUtils::Embed -e ldopts`"
 798         PERLPRIVLIBEXP="`$PERL -MConfig -e 'print $Config{privlibexp}'`"
 799      else
 800         AC_MSG_ERROR([no, unable to link])
 801      fi
 802   else
 803      AC_MSG_ERROR([no working perl found, or perl not version >= 5.8])
 804   fi
 805 fi
 806 AC_SUBST(PERLLIB)
 807 AC_SUBST(PERLFLAGS)
 808 AC_SUBST(PERLPRIVLIBEXP)
 809 AC_SUBST(PERL)
 810 AC_SUBST(IF_PERL)
 811 AC_SUBST(PERL_O)
 812
 813 AC_SUBST(CFLAGS)
 814 AC_SUBST(CPPFLAGS)
 815 AC_SUBST(LDFLAGS)
 816 AC_SUBST(X_CFLAGS)
 817
 818 dnl# Attack the libs
 819 AC_SUBST(LIBS)
 820 AC_SUBST(X_LIBS)
 821 AC_SUBST(X_EXTRA_LIBS)
 822
 823 AC_SUBST(AFTERIMAGE_CFLAGS)
 824 AC_SUBST(AFTERIMAGE_LIBS)
 825
 826 AC_ARG_PROGRAM
 827
 828 dnl# test for "sun" or "__sun__" before include sys_ioctl
 829
 830 dnl# revert HAVE_BLAH_H into a "#include <blah.h>"
 831 AC_DEFUN([RXVT_DEFINE_TO_INCLUDE], dnl
 832 [if test "$$3" = "$4" -o "$$5" = "$6"; then
 833   $1="#include <$2>"
 834 else
 835   $1="/* #include <$2> */"
 836 fi dnl
 837 AC_SUBST($1)])
 838
 839 RXVT_DEFINE_TO_INCLUDE(include_stdint_h, stdint.h, ac_cv_header_stdint_h, yes, notset, dontmatch)
 840 RXVT_DEFINE_TO_INCLUDE(include_sys_ioctl_h, sys/ioctl.h, rxvt_cv_header_sysioctl, yes, notset, dontmatch)
 841 RXVT_DEFINE_TO_INCLUDE(include_sys_strredir_h, sys/strredir.h, ac_cv_header_sys_strredir_h, yes, notset, dontmatch)
 842
 843 AC_CONFIG_FILES([Makefile \
 844 doc/Makefile \
 845 src/Makefile \
 846 src/rxvtlib.h \
 847 ])
 848 AC_OUTPUT
 849
 850 echo "Configuration:
 851
 852   Rxvt version:               $VERSION : $DATE
 853   Source code location:       $srcdir
 854   Install path:               ${prefix}/bin
 855   Compiler:                   $CXX
 856   Compiler flags:             $CXXFLAGS
 857   Linker:                     $LINKER"
 858
 859 if test x$term != x; then
 860   echo "  set TERM to:                $term"
 861 fi
 862 if test x$terminfo != x; then
 863   echo "  set TERMINFO to:            $terminfo"
 864 fi
 865 echo "  default resource name:      $RESNAME"
 866 echo "  resource class:             $RESCLASS"
 867 if test x$RESFALLBACK != x; then
 868    echo "  resource class fallback:    $RESFALLBACK"
 869 fi
 870 echo
 871 echo "  embedded perl:              $support_perl"
 872 echo "  libafterimage:              $support_afterimage"
 873 dnl echo "  AfterStep integration:      $support_afterstep"
 874 echo
 875 if test x$support_xim = xyes -a x$rxvt_cv_func_xlocale = xno; then
 876   echo ".----------------------------------------------------------------."
 877   echo ". WARNING: --enable-xim was specified however the locale support ."
 878   echo ".          functions could not be found.                         ."
 879   echo ".          XIM is now being DISABLED!                            ."
 880   echo ".----------------------------------------------------------------."
 881 fi
 882
 883 echo "*** Optionally check src/feature.h for further, rarely used options ***"
 884 echo
 885