src/urxvt.pm

   1 =encoding utf8
   2
   3 =head1 NAME
   4
   5 @@RXVT_NAME@@perl - rxvt-unicode's embedded perl interpreter
   6
   7 =head1 SYNOPSIS
   8
   9    # create a file grab_test in $HOME:
  10
  11    sub on_sel_grab {
  12       warn "you selected ", $_[0]->selection;
  13       ()
  14    }
  15
  16    # start a @@RXVT_NAME@@ using it:
  17
  18    @@RXVT_NAME@@ --perl-lib $HOME -pe grab_test
  19
  20 =head1 DESCRIPTION
  21
  22 Everytime a terminal object gets created, extension scripts specified via
  23 the C<perl> resource are loaded and associated with it.
  24
  25 Scripts are compiled in a 'use strict' and 'use utf8' environment, and
  26 thus must be encoded as UTF-8.
  27
  28 Each script will only ever be loaded once, even in @@RXVT_NAME@@d, where
  29 scripts will be shared (but not enabled) for all terminals.
  30
  31 =head2 Prepackaged Extensions
  32
  33 This section describes the extensiosn delivered with this version. You can
  34 find them in F<@@RXVT_LIBDIR@@/urxvt/perl/>.
  35
  36 You can activate them like this:
  37
  38   @@RXVT_NAME@@ -pe <extensionname>
  39
  40 =over 4
  41
  42 =item selection
  43
  44 Intelligent selection. This extension tries to be more intelligent when
  45 the user extends selections (double-click). Right now, it tries to select
  46 urls and complete shell-quoted arguments, which is very convenient, too,
  47 if your F<ls> supports C<--quoting-style=shell>.
  48
  49 It also offers the following bindable event:
  50
  51 =over 4
  52
  53 =item rot13
  54
  55 Rot-13 the selection when activated. Used via keyboard trigger:
  56
  57    URxvt.keysym.C-M-r: perl:selection:rot13
  58
  59 =back
  60
  61 =item digital-clock
  62
  63 Displays a digital clock using the built-in overlay.
  64
  65 =item mark-urls
  66
  67 Uses per-line display filtering (C<on_line_update>) to underline urls.
  68
  69 =item block-graphics-to-ascii
  70
  71 A not very useful example of filtering all text output to the terminal,
  72 by replacing all line-drawing characters (U+2500 .. U+259F) by a
  73 similar-looking ascii character.
  74
  75 =item example-refresh-hooks
  76
  77 Displays a very simple digital clock in the upper right corner of the
  78 window. Illustrates overwriting the refresh callbacks to create your own
  79 overlays or changes.
  80
  81 =back
  82
  83 =head2 General API Considerations
  84
  85 All objects (such as terminals, time watchers etc.) are typical
  86 reference-to-hash objects. The hash can be used to store anything you
  87 like. All members starting with an underscore (such as C<_ptr> or
  88 C<_hook>) are reserved for internal uses and B<MUST NOT> be accessed or
  89 modified).
  90
  91 When objects are destroyed on the C++ side, the perl object hashes are
  92 emptied, so its best to store related objects such as time watchers and
  93 the like inside the terminal object so they get destroyed as soon as the
  94 terminal is destroyed.
  95
  96 Argument names also often indicate the type of a parameter. Here are some
  97 hints on what they mean:
  98
  99 =over 4
 100
 101 =item $text
 102
 103 Rxvt-unicodes special way of encoding text, where one "unicode" character
 104 always represents one screen cell. See L<row_t> for a discussion of this format.
 105
 106 =item $string
 107
 108 A perl text string, with an emphasis on I<text>. It can store all unicode
 109 characters and is to be distinguished with text encoded in a specific
 110 encoding (often locale-specific) and binary data.
 111
 112 =item $octets
 113
 114 Either binary data or - more common - a text string encoded in a
 115 locale-specific way.
 116
 117 =back
 118
 119 =head2 Hooks
 120
 121 The following subroutines can be declared in extension files, and will be
 122 called whenever the relevant event happens.
 123
 124 The first argument passed to them is an object private to each terminal
 125 and extension package. You can call all C<urxvt::term> methods on it, but
 126 its not a real C<urxvt::term> object. Instead, the real C<urxvt::term>
 127 object that is shared between all packages is stored in the C<term>
 128 member. It is, however, blessed intot he package of the extension script,
 129 so for all practical purposes you can treat an extension script as a class.
 130
 131 All of them must return a boolean value. If it is true, then the event
 132 counts as being I<consumed>, and the invocation of other hooks is skipped,
 133 and the relevant action might not be carried out by the C++ code.
 134
 135 When in doubt, return a false value (preferably C<()>).
 136
 137 =over 4
 138
 139 =item on_init $term
 140
 141 Called after a new terminal object has been initialized, but before
 142 windows are created or the command gets run. Most methods are unsafe to
 143 call or deliver senseless data, as terminal size and other characteristics
 144 have not yet been determined. You can safely query and change resources,
 145 though.
 146
 147 =item on_reset $term
 148
 149 Called after the screen is "reset" for any reason, such as resizing or
 150 control sequences. Here is where you can react on changes to size-related
 151 variables.
 152
 153 =item on_start $term
 154
 155 Called at the very end of initialisation of a new terminal, just before
 156 returning to the mainloop.
 157
 158 =item on_sel_make $term, $eventtime
 159
 160 Called whenever a selection has been made by the user, but before the
 161 selection text is copied, so changes to the beginning, end or type of the
 162 selection will be honored.
 163
 164 Returning a true value aborts selection making by urxvt, in which case you
 165 have to make a selection yourself by calling C<< $term->selection_grab >>.
 166
 167 =item on_sel_grab $term, $eventtime
 168
 169 Called whenever a selection has been copied, but before the selection is
 170 requested from the server.  The selection text can be queried and changed
 171 by calling C<< $term->selection >>.
 172
 173 Returning a true value aborts selection grabbing. It will still be hilighted.
 174
 175 =item on_sel_extend $term
 176
 177 Called whenever the user tries to extend the selection (e.g. with a double
 178 click) and is either supposed to return false (normal operation), or
 179 should extend the selection itelf and return true to suppress the built-in
 180 processing.
 181
 182 See the F<selection> example extension.
 183
 184 =item on_view_change $term, $offset
 185
 186 Called whenever the view offset changes, i..e the user or program
 187 scrolls. Offset C<0> means display the normal terminal, positive values
 188 show this many lines of scrollback.
 189
 190 =item on_scroll_back $term, $lines, $saved
 191
 192 Called whenever lines scroll out of the terminal area into the scrollback
 193 buffer. C<$lines> is the number of lines scrolled out and may be larger
 194 than the scroll back buffer or the terminal.
 195
 196 It is called before lines are scrolled out (so rows 0 .. min ($lines - 1,
 197 $nrow - 1) represent the lines to be scrolled out). C<$saved> is the total
 198 number of lines that will be in the scrollback buffer.
 199
 200 =item on_tty_activity $term *NYI*
 201
 202 Called whenever the program(s) running in the urxvt window send output.
 203
 204 =item on_osc_seq $term, $string
 205
 206 Called whenever the B<ESC ] 777 ; string ST> command sequence (OSC =
 207 operating system command) is processed. Cursor position and other state
 208 information is up-to-date when this happens. For interoperability, the
 209 string should start with the extension name and a colon, to distinguish
 210 it from commands for other extensions, and this might be enforced in the
 211 future.
 212
 213 Be careful not ever to trust (in a security sense) the data you receive,
 214 as its source can not easily be controleld (e-mail content, messages from
 215 other users on the same system etc.).
 216
 217 =item on_add_lines $term, $string
 218
 219 Called whenever text is about to be output, with the text as argument. You
 220 can filter/change and output the text yourself by returning a true value
 221 and calling C<< $term->scr_add_lines >> yourself. Please note that this
 222 might be very slow, however, as your hook is called for B<all> text being
 223 output.
 224
 225 =item on_line_update $term, $row
 226
 227 Called whenever a line was updated or changed. Can be used to filter
 228 screen output (e.g. underline urls or other useless stuff). Only lines
 229 that are being shown will be filtered, and, due to performance reasons,
 230 not always immediately.
 231
 232 The row number is always the topmost row of the line if the line spans
 233 multiple rows.
 234
 235 Please note that, if you change the line, then the hook might get called
 236 later with the already-modified line (e.g. if unrelated parts change), so
 237 you cannot just toggle rendition bits, but only set them.
 238
 239 =item on_refresh_begin $term
 240
 241 Called just before the screen gets redrawn. Can be used for overlay
 242 or similar effects by modify terminal contents in refresh_begin, and
 243 restoring them in refresh_end. The built-in overlay and selection display
 244 code is run after this hook, and takes precedence.
 245
 246 =item on_refresh_end $term
 247
 248 Called just after the screen gets redrawn. See C<on_refresh_begin>.
 249
 250 =item on_keyboard_command $term, $string
 251
 252 Called whenever the user presses a key combination that has a
 253 C<perl:string> action bound to it (see description of the B<keysym>
 254 resource in the @@RXVT_NAME@@(1) manpage).
 255
 256 =item on_focus_in $term
 257
 258 Called whenever the window gets the keyboard focus, before rxvt-unicode
 259 does focus in processing.
 260
 261 =item on_focus_out $term
 262
 263 Called wheneever the window loses keyboard focus, before rxvt-unicode does
 264 focus out processing.
 265
 266 =item on_key_press $term, $event, $octets
 267
 268 =item on_key_release $term, $event
 269
 270 =item on_button_press $term, $event
 271
 272 =item on_button_release $term, $event
 273
 274 =item on_motion_notify $term, $event
 275
 276 =item on_map_notify $term, $event
 277
 278 =item on_unmap_notify $term, $event
 279
 280 Called whenever the corresponding X event is received for the terminal If
 281 the hook returns true, then the even will be ignored by rxvt-unicode.
 282
 283 The event is a hash with most values as named by Xlib (see the XEvent
 284 manpage), with the additional members C<row> and C<col>, which are the row
 285 and column under the mouse cursor.
 286
 287 C<on_key_press> additionally receives the string rxvt-unicode would
 288 output, if any, in locale-specific encoding.
 289
 290 subwindow.
 291
 292 =back
 293
 294 =head2 Variables in the C<urxvt> Package
 295
 296 =over 4
 297
 298 =item $urxvt::TERM
 299
 300 The current terminal. This variable stores the current C<urxvt::term>
 301 object, whenever a callback/hook is executing.
 302
 303 =back
 304
 305 =head2 Functions in the C<urxvt> Package
 306
 307 =over 4
 308
 309 =item $term = new urxvt [arg...]
 310
 311 Creates a new terminal, very similar as if you had started it with
 312 C<system $binfile, arg...>. Croaks (and probably outputs an error message)
 313 if the new instance couldn't be created.  Returns C<undef> if the new
 314 instance didn't initialise perl, and the terminal object otherwise. The
 315 C<init> and C<start> hooks will be called during the call.
 316
 317 =item urxvt::fatal $errormessage
 318
 319 Fatally aborts execution with the given error message. Avoid at all
 320 costs! The only time this is acceptable is when the terminal process
 321 starts up.
 322
 323 =item urxvt::warn $string
 324
 325 Calls C<rxvt_warn> with the given string which should not include a
 326 newline. The module also overwrites the C<warn> builtin with a function
 327 that calls this function.
 328
 329 Using this function has the advantage that its output ends up in the
 330 correct place, e.g. on stderr of the connecting urxvtc client.
 331
 332 =item $time = urxvt::NOW
 333
 334 Returns the "current time" (as per the event loop).
 335
 336 =item urxvt::CurrentTime
 337
 338 =item urxvt::ShiftMask, LockMask, ControlMask, Mod1Mask, Mod2Mask,
 339 Mod3Mask, Mod4Mask, Mod5Mask, Button1Mask, Button2Mask, Button3Mask,
 340 Button4Mask, Button5Mask, AnyModifier
 341
 342 Various constants for use in X events.
 343
 344 =back
 345
 346 =head2 RENDITION
 347
 348 Rendition bitsets contain information about colour, font, font styles and
 349 similar information for each screen cell.
 350
 351 The following "macros" deal with changes in rendition sets. You should
 352 never just create a bitset, you should always modify an existing one,
 353 as they contain important information required for correct operation of
 354 rxvt-unicode.
 355
 356 =over 4
 357
 358 =item $rend = urxvt::DEFAULT_RSTYLE
 359
 360 Returns the default rendition, as used when the terminal is starting up or
 361 being reset. Useful as a base to start when creating renditions.
 362
 363 =item $rend = urxvt::OVERLAY_RSTYLE
 364
 365 Return the rendition mask used for overlays by default.
 366
 367 =item $rendbit = urxvt::RS_Bold, RS_Italic, RS_Blink, RS_RVid, RS_Uline
 368
 369 Return the bit that enabled bold, italic, blink, reverse-video and
 370 underline, respectively. To enable such a style, just logically OR it into
 371 the bitset.
 372
 373 =item $foreground = urxvt::GET_BASEFG $rend
 374
 375 =item $background = urxvt::GET_BASEBG $rend
 376
 377 Return the foreground/background colour index, respectively.
 378
 379 =item $rend = urxvt::SET_FGCOLOR ($rend, $new_colour)
 380
 381 =item $rend = urxvt::SET_BGCOLOR ($rend, $new_colour)
 382
 383 Replace the foreground/background colour in the rendition mask with the
 384 specified one.
 385
 386 =item $value = urxvt::GET_CUSTOM ($rend)
 387
 388 Return the "custom" value: Every rendition has 5 bits for use by
 389 extensions. They can be set and changed as you like and are initially
 390 zero.
 391
 392 =item $rend = urxvt::SET_CUSTOM ($rend, $new_value)
 393
 394 Change the custom value.
 395
 396 =back
 397
 398 =cut
 399
 400 package urxvt;
 401
 402 use utf8;
 403 use strict;
 404 use Scalar::Util ();
 405 use List::Util ();
 406
 407 our $TERM;
 408 our @HOOKNAME;
 409 our $LIBDIR;
 410
 411 BEGIN {
 412    urxvt->bootstrap;
 413
 414    # overwrite perl's warn
 415    *CORE::GLOBAL::warn = sub {
 416       my $msg = join "", @_;
 417       $msg .= "\n"
 418          unless $msg =~ /\n$/;
 419       urxvt::warn ($msg);
 420    };
 421 }
 422
 423 my @hook_count;
 424 my $verbosity = $ENV{URXVT_PERL_VERBOSITY};
 425
 426 sub verbose {
 427    my ($level, $msg) = @_;
 428    warn "$msg\n" if $level <= $verbosity;
 429 }
 430
 431 # find on_xxx subs in the package and register them
 432 # as hooks
 433 sub register_package($) {
 434    my ($pkg) = @_;
 435
 436    for my $htype (0.. $#HOOKNAME) {
 437       my $name = $HOOKNAME[$htype];
 438
 439       my $ref = $pkg->can ("on_" . lc $name)
 440          or next;
 441
 442       $TERM->{_hook}[$htype]{$pkg} = $ref;
 443       $hook_count[$htype]++
 444          or set_should_invoke $htype, 1;
 445    }
 446 }
 447
 448 my $extension_pkg = "extension0000";
 449 my %extension_pkg;
 450
 451 # load a single script into its own package, once only
 452 sub extension_package($) {
 453    my ($path) = @_;
 454
 455    $extension_pkg{$path} ||= do {
 456       my $pkg = "urxvt::" . ($extension_pkg++);
 457
 458       verbose 3, "loading extension '$path' into package '$pkg'";
 459
 460       open my $fh, "<:raw", $path
 461          or die "$path: $!";
 462
 463       my $source = "package $pkg; use strict; use utf8;\n"
 464                    . "use base urxvt::term::proxy::;\n"
 465                    . "#line 1 \"$path\"\n{\n"
 466                    . (do { local $/; <$fh> })
 467                    . "\n};\n1";
 468
 469       eval $source or die "$path: $@";
 470
 471       $pkg
 472    }
 473 }
 474
 475 our $retval; # return value for urxvt
 476
 477 # called by the rxvt core
 478 sub invoke {
 479    local $TERM = shift;
 480    my $htype = shift;
 481
 482    if ($htype == 0) { # INIT
 483       my @dirs = ((split /:/, $TERM->resource ("perl_lib")), "$LIBDIR/perl");
 484
 485       for my $ext (map { split /,/, $TERM->resource ("perl_ext_$_") } 1, 2) {
 486          my @files = grep -f $_, map "$_/$ext", @dirs;
 487
 488          if (@files) {
 489             register_package extension_package $files[0];
 490          } else {
 491             warn "perl extension '$ext' not found in perl library search path\n";
 492          }
 493       }
 494    }
 495
 496    $retval = undef;
 497
 498    if (my $cb = $TERM->{_hook}[$htype]) {
 499       verbose 10, "$HOOKNAME[$htype] (" . (join ", ", $TERM, @_) . ")"
 500          if $verbosity >= 10;
 501
 502       keys %$cb;
 503
 504       while (my ($pkg, $cb) = each %$cb) {
 505          eval {
 506             $retval = $cb->(
 507                $TERM->{_pkg}{$pkg} ||= do {
 508                   my $proxy = bless { }, $pkg;
 509                   Scalar::Util::weaken ($proxy->{term} = $TERM);
 510                   $proxy
 511                },
 512                @_,
 513             ) and last;
 514          };
 515          warn $@ if $@;#d#
 516       }
 517    }
 518
 519    if ($htype == 1) { # DESTROY
 520       # remove hooks if unused
 521       if (my $hook = $TERM->{_hook}) {
 522          for my $htype (0..$#$hook) {
 523             $hook_count[$htype] -= scalar keys %{ $hook->[$htype] || {} }
 524                or set_should_invoke $htype, 0;
 525          }
 526       }
 527
 528       # clear package objects
 529       %$_ = () for values %{ $TERM->{_pkg} };
 530
 531       # clear package
 532       %$TERM = ();
 533    }
 534
 535    $retval
 536 }
 537
 538 sub urxvt::term::proxy::AUTOLOAD {
 539    $urxvt::term::proxy::AUTOLOAD =~ /:([^:]+)$/
 540       or die "FATAL: \$AUTOLOAD '$urxvt::term::proxy::AUTOLOAD' unparsable";
 541
 542    eval qq{
 543       sub $urxvt::term::proxy::AUTOLOAD {
 544          my \$proxy = shift;
 545          \$proxy->{term}->$1 (\@_)
 546       }
 547       1
 548    } or die "FATAL: unable to compile method forwarder: $@";
 549
 550    goto &$urxvt::term::proxy::AUTOLOAD;
 551 }
 552
 553 sub urxvt::destroy_hook::DESTROY {
 554    ${$_[0]}->();
 555 }
 556
 557 sub urxvt::destroy_hook(&) {
 558    bless \shift, urxvt::destroy_hook::
 559 }
 560
 561 =head2 The C<urxvt::term> Class
 562
 563 =over 4
 564
 565 =item $term->destroy
 566
 567 Destroy the terminal object (close the window, free resources etc.).
 568
 569 =item $value = $term->resource ($name[, $newval])
 570
 571 Returns the current resource value associated with a given name and
 572 optionally sets a new value. Setting values is most useful in the C<init>
 573 hook. Unset resources are returned and accepted as C<undef>.
 574
 575 The new value must be properly encoded to a suitable character encoding
 576 before passing it to this method. Similarly, the returned value may need
 577 to be converted from the used encoding to text.
 578
 579 Resource names are as defined in F<src/rsinc.h>. Colours can be specified
 580 as resource names of the form C<< color+<index> >>, e.g. C<color+5>. (will
 581 likely change).
 582
 583 Please note that resource strings will currently only be freed when the
 584 terminal is destroyed, so changing options frequently will eat memory.
 585
 586 Here is a a likely non-exhaustive list of resource names, not all of which
 587 are supported in every build, please see the source to see the actual
 588 list:
 589
 590   answerbackstring backgroundPixmap backspace_key boldFont boldItalicFont
 591   borderLess color cursorBlink cursorUnderline cutchars delete_key
 592   display_name embed ext_bwidth fade font geometry hold iconName
 593   imFont imLocale inputMethod insecure int_bwidth intensityStyles
 594   italicFont jumpScroll lineSpace loginShell mapAlert menu meta8 modifier
 595   mouseWheelScrollPage name pastableTabs path perl_eval perl_ext_1 perl_ext_2
 596   perl_lib pointerBlank pointerBlankDelay preeditType print_pipe pty_fd
 597   reverseVideo saveLines scrollBar scrollBar_align scrollBar_floating
 598   scrollBar_right scrollBar_thickness scrollTtyKeypress scrollTtyOutput
 599   scrollWithBuffer scrollstyle secondaryScreen secondaryScroll selectstyle
 600   shade term_name title transparent transparent_all tripleclickwords
 601   utmpInhibit visualBell
 602
 603 =cut
 604
 605 sub urxvt::term::resource($$;$) {
 606    my ($self, $name) = (shift, shift);
 607    unshift @_, $self, $name, ($name =~ s/\s*\+\s*(\d+)$// ? $1 : 0);
 608    &urxvt::term::_resource
 609 }
 610
 611 =item $rend = $term->rstyle ([$new_rstyle])
 612
 613 Return and optionally change the current rendition. Text that is output by
 614 the terminal application will use this style.
 615
 616 =item ($row, $col) = $term->screen_cur ([$row, $col])
 617
 618 Return the current coordinates of the text cursor position and optionally
 619 set it (which is usually bad as applications don't expect that).
 620
 621 =item ($row, $col) = $term->selection_mark ([$row, $col])
 622
 623 =item ($row, $col) = $term->selection_beg ([$row, $col])
 624
 625 =item ($row, $col) = $term->selection_end ([$row, $col])
 626
 627 Return the current values of the selection mark, begin or end positions,
 628 and optionally set them to new values.
 629
 630 =item $success = $term->selection_grab ($eventtime)
 631
 632 Try to request the primary selection from the server (for example, as set
 633 by the next method).
 634
 635 =item $oldtext = $term->selection ([$newtext])
 636
 637 Return the current selection text and optionally replace it by C<$newtext>.
 638
 639 #=item $term->overlay ($x, $y, $text)
 640 #
 641 #Create a simple multi-line overlay box. See the next method for details.
 642 #
 643 #=cut
 644 #
 645 #sub urxvt::term::scr_overlay {
 646 #   my ($self, $x, $y, $text) = @_;
 647 #
 648 #   my @lines = split /\n/, $text;
 649 #
 650 #   my $w = 0;
 651 #   for (map $self->strwidth ($_), @lines) {
 652 #      $w = $_ if $w < $_;
 653 #   }
 654 #
 655 #   $self->scr_overlay_new ($x, $y, $w, scalar @lines);
 656 #   $self->scr_overlay_set (0, $_, $lines[$_]) for 0.. $#lines;
 657 #}
 658
 659 =item $term->overlay ($x, $y, $width, $height[, $rstyle[, $border]])
 660
 661 Create a new (empty) overlay at the given position with the given
 662 width/height. C<$rstyle> defines the initial rendition style
 663 (default: C<OVERLAY_RSTYLE>).
 664
 665 If C<$border> is C<2> (default), then a decorative border will be put
 666 around the box.
 667
 668 If either C<$x> or C<$y> is negative, then this is counted from the
 669 right/bottom side, respectively.
 670
 671 This method returns an urxvt::overlay object. The overlay will be visible
 672 as long as the perl object is referenced.
 673
 674 The methods currently supported on C<urxvt::overlay> objects are:
 675
 676 =over 4
 677
 678 =item $overlay->set ($x, $y, $text, $rend)
 679
 680 Similar to C<< $term->ROW_t >> and C<< $term->ROW_r >> in that it puts
 681 text in rxvt-unicode's special encoding and an array of rendition values
 682 at a specific position inside the overlay.
 683
 684 =item $overlay->hide
 685
 686 If visible, hide the overlay, but do not destroy it.
 687
 688 =item $overlay->show
 689
 690 If hidden, display the overlay again.
 691
 692 =back
 693
 694 =item $popup = $term->popup ($event)
 695
 696 Creates a new C<urxvt::popup> object that implements a popup menu. The
 697 C<$event> I<must> be the event causing the menu to pop up (a button event,
 698 currently).
 699
 700 =cut
 701
 702 sub urxvt::term::popup {
 703    my ($self, $event) = @_;
 704
 705    $self->grab ($event->{time}, 1)
 706       or return;
 707
 708    my $popup = bless {
 709       term  => $self,
 710       event => $event,
 711    }, urxvt::popup::;
 712
 713    Scalar::Util::weaken $popup->{term};
 714
 715    $self->{_destroy}{$popup} = urxvt::destroy_hook { $popup->{popup}->destroy };
 716    Scalar::Util::weaken $self->{_destroy}{$popup};
 717
 718    $popup
 719 }
 720
 721 =item $cellwidth = $term->strwidth ($string)
 722
 723 Returns the number of screen-cells this string would need. Correctly
 724 accounts for wide and combining characters.
 725
 726 =item $octets = $term->locale_encode ($string)
 727
 728 Convert the given text string into the corresponding locale encoding.
 729
 730 =item $string = $term->locale_decode ($octets)
 731
 732 Convert the given locale-encoded octets into a perl string.
 733
 734 =item $term->scr_add_lines ($string)
 735
 736 Write the given text string to the screen, as if output by the application
 737 running inside the terminal. It may not contain command sequences (escape
 738 codes), but is free to use line feeds, carriage returns and tabs. The
 739 string is a normal text string, not in locale-dependent encoding.
 740
 741 Normally its not a good idea to use this function, as programs might be
 742 confused by changes in cursor position or scrolling. Its useful inside a
 743 C<on_add_lines> hook, though.
 744
 745 =item $term->cmd_parse ($octets)
 746
 747 Similar to C<scr_add_lines>, but the argument must be in the
 748 locale-specific encoding of the terminal and can contain command sequences
 749 (escape codes) that will be interpreted.
 750
 751 =item $term->tt_write ($octets)
 752
 753 Write the octets given in C<$data> to the tty (i.e. as program input). To
 754 pass characters instead of octets, you should convert your strings first
 755 to the locale-specific encoding using C<< $term->locale_encode >>.
 756
 757 =item $windowid = $term->parent
 758
 759 Return the window id of the toplevel window.
 760
 761 =item $windowid = $term->vt
 762
 763 Return the window id of the terminal window.
 764
 765 =item $window_width = $term->width
 766
 767 =item $window_height = $term->height
 768
 769 =item $font_width = $term->fwidth
 770
 771 =item $font_height = $term->fheight
 772
 773 =item $font_ascent = $term->fbase
 774
 775 =item $terminal_rows = $term->nrow
 776
 777 =item $terminal_columns = $term->ncol
 778
 779 =item $has_focus = $term->focus
 780
 781 =item $is_mapped = $term->mapped
 782
 783 =item $max_scrollback = $term->saveLines
 784
 785 =item $nrow_plus_saveLines = $term->total_rows
 786
 787 =item $lines_in_scrollback = $term->nsaved
 788
 789 Return various integers describing terminal characteristics.
 790
 791 =item $modifiermask = $term->ModLevel3Mask
 792
 793 =item $modifiermask = $term->ModMetaMask
 794
 795 =item $modifiermask = $term->ModNumLockMask
 796
 797 Return the modifier masks corresponding to the "ISO Level 3 Shift" (often
 798 AltGr), the meta key (often Alt) and the num lock key, if applicable.
 799
 800 =item $view_start = $term->view_start ([$newvalue])
 801
 802 Returns the negative row number of the topmost line. Minimum value is
 803 C<0>, which displays the normal terminal contents. Larger values scroll
 804 this many lines into the scrollback buffer.
 805
 806 =item $term->want_refresh
 807
 808 Requests a screen refresh. At the next opportunity, rxvt-unicode will
 809 compare the on-screen display with its stored representation. If they
 810 differ, it redraws the differences.
 811
 812 Used after changing terminal contents to display them.
 813
 814 =item $text = $term->ROW_t ($row_number[, $new_text[, $start_col]])
 815
 816 Returns the text of the entire row with number C<$row_number>. Row C<0>
 817 is the topmost terminal line, row C<< $term->$ncol-1 >> is the bottommost
 818 terminal line. The scrollback buffer starts at line C<-1> and extends to
 819 line C<< -$term->nsaved >>. Nothing will be returned if a nonexistent line
 820 is requested.
 821
 822 If C<$new_text> is specified, it will replace characters in the current
 823 line, starting at column C<$start_col> (default C<0>), which is useful
 824 to replace only parts of a line. The font index in the rendition will
 825 automatically be updated.
 826
 827 C<$text> is in a special encoding: tabs and wide characters that use more
 828 than one cell when displayed are padded with urxvt::NOCHAR characters
 829 (C<chr 65535>). Characters with combining characters and other characters
 830 that do not fit into the normal tetx encoding will be replaced with
 831 characters in the private use area.
 832
 833 You have to obey this encoding when changing text. The advantage is
 834 that C<substr> and similar functions work on screen cells and not on
 835 characters.
 836
 837 The methods C<< $term->special_encode >> and C<< $term->special_decode >>
 838 can be used to convert normal strings into this encoding and vice versa.
 839
 840 =item $rend = $term->ROW_r ($row_number[, $new_rend[, $start_col]])
 841
 842 Like C<< $term->ROW_t >>, but returns an arrayref with rendition
 843 bitsets. Rendition bitsets contain information about colour, font, font
 844 styles and similar information. See also C<< $term->ROW_t >>.
 845
 846 When setting rendition, the font mask will be ignored.
 847
 848 See the section on RENDITION, above.
 849
 850 =item $length = $term->ROW_l ($row_number[, $new_length])
 851
 852 Returns the number of screen cells that are in use ("the line
 853 length"). Unlike the urxvt core, this returns C<< $term->ncol >> if the
 854 line is joined with the following one.
 855
 856 =item $bool = $term->is_longer ($row_number)
 857
 858 Returns true if the row is part of a multiple-row logical "line" (i.e.
 859 joined with the following row), which means all characters are in use
 860 and it is continued on the next row (and possibly a continuation of the
 861 previous row(s)).
 862
 863 =item $line = $term->line ($row_number)
 864
 865 Create and return a new C<urxvt::line> object that stores information
 866 about the logical line that row C<$row_number> is part of. It supports the
 867 following methods:
 868
 869 =over 4
 870
 871 =item $text = $line->t ([$new_text])
 872
 873 Returns or replaces the full text of the line, similar to C<ROW_t>
 874
 875 =item $rend = $line->r ([$new_rend])
 876
 877 Returns or replaces the full rendition array of the line, similar to C<ROW_r>
 878
 879 =item $length = $line->l
 880
 881 Returns the length of the line in cells, similar to C<ROW_l>.
 882
 883 =item $rownum = $line->beg
 884
 885 =item $rownum = $line->end
 886
 887 Return the row number of the first/last row of the line, respectively.
 888
 889 =item $offset = $line->offset_of ($row, $col)
 890
 891 Returns the character offset of the given row|col pair within the logical
 892 line.
 893
 894 =item ($row, $col) = $line->coord_of ($offset)
 895
 896 Translates a string offset into terminal coordinates again.
 897
 898 =back
 899
 900 =cut
 901
 902 sub urxvt::term::line {
 903    my ($self, $row) = @_;
 904
 905    my $maxrow = $self->nrow - 1;
 906
 907    my ($beg, $end) = ($row, $row);
 908
 909    --$beg while $self->ROW_is_longer ($beg - 1);
 910    ++$end while $self->ROW_is_longer ($end) && $end < $maxrow;
 911
 912    bless {
 913       term => $self,
 914       beg  => $beg,
 915       end  => $end,
 916       ncol => $self->ncol,
 917       len  => ($end - $beg) * $self->ncol + $self->ROW_l ($end),
 918    }, urxvt::line::
 919 }
 920
 921 sub urxvt::line::t {
 922    my ($self) = @_;
 923
 924    if (@_ > 1)
 925      {
 926        $self->{term}->ROW_t ($_, $_[1], 0, ($_ - $self->{beg}) * $self->{ncol}, $self->{ncol})
 927           for $self->{beg} .. $self->{end};
 928      }
 929
 930    defined wantarray &&
 931       substr +(join "", map $self->{term}->ROW_t ($_), $self->{beg} .. $self->{end}),
 932              0, $self->{len}
 933 }
 934
 935 sub urxvt::line::r {
 936    my ($self) = @_;
 937
 938    if (@_ > 1)
 939      {
 940        $self->{term}->ROW_r ($_, $_[1], 0, ($_ - $self->{beg}) * $self->{ncol}, $self->{ncol})
 941           for $self->{beg} .. $self->{end};
 942      }
 943
 944    if (defined wantarray) {
 945       my $rend = [
 946          map @{ $self->{term}->ROW_r ($_) }, $self->{beg} .. $self->{end}
 947       ];
 948       $#$rend = $self->{len} - 1;
 949       return $rend;
 950    }
 951
 952    ()
 953 }
 954
 955 sub urxvt::line::beg { $_[0]{beg} }
 956 sub urxvt::line::end { $_[0]{end} }
 957 sub urxvt::line::l   { $_[0]{len} }
 958
 959 sub urxvt::line::offset_of {
 960    my ($self, $row, $col) = @_;
 961
 962    ($row - $self->{beg}) * $self->{ncol} + $col
 963 }
 964
 965 sub urxvt::line::coord_of {
 966    my ($self, $offset) = @_;
 967
 968    use integer;
 969
 970    (
 971       $offset / $self->{ncol} + $self->{beg},
 972       $offset % $self->{ncol}
 973    )
 974 }
 975
 976 =item ($row, $col) = $line->coord_of ($offset)
 977 =item $text = $term->special_encode $string
 978
 979 Converts a perl string into the special encoding used by rxvt-unicode,
 980 where one character corresponds to one screen cell. See
 981 C<< $term->ROW_t >> for details.
 982
 983 =item $string = $term->special_decode $text
 984
 985 Converts rxvt-unicodes text reprsentation into a perl string. See
 986 C<< $term->ROW_t >> for details.
 987
 988 =back
 989
 990 =head2 The C<urxvt::popup> Class
 991
 992 =over 4
 993
 994 =cut
 995
 996 package urxvt::popup;
 997
 998 sub add_item {
 999    my ($self, $item) = @_;
1000
1001    push @{ $self->{item} }, $item;
1002 }
1003
1004 sub add_button {
1005    my ($self, $text, $cb) = @_;
1006
1007    $self->add_item ({ type => "button", text => "[ $text ]", activate => $cb,
1008       render => sub { $_[0]{text} },
1009    });
1010 }
1011
1012 sub add_toggle {
1013    my ($self, $text, $cb, $value) = @_;
1014
1015    $self->add_item ({ type => "button", text => "  $text", value => $value,
1016       render => sub { ($_[0]{value} ? "✔" : " ") . substr $_[0]{text}, 1 },
1017       activate => sub { $cb->($_[0]{value} = !$_[0]{value}); },
1018    });
1019 }
1020
1021 sub show {
1022    my ($self) = @_;
1023
1024    local $urxvt::popup::self = $self;
1025
1026    urxvt->new ("--perl-lib" => "", "--perl-ext-common" => "", "-pty-fd" => -1, "-sl" => 0, "-b" => 0,
1027                "--transient-for" => $self->{term}->parent,
1028                "-pe" => "urxvt-popup")
1029       or die "unable to create popup window\n";
1030 }
1031
1032 sub DESTROY {
1033    my ($self) = @_;
1034
1035    $self->{term}->ungrab;
1036 }
1037
1038 =head2 The C<urxvt::timer> Class
1039
1040 This class implements timer watchers/events. Time is represented as a
1041 fractional number of seconds since the epoch. Example:
1042
1043    $term->{overlay} = $term->overlay (-1, 0, 8, 1, urxvt::OVERLAY_RSTYLE, 0);
1044    $term->{timer} = urxvt::timer
1045                     ->new
1046                     ->interval (1)
1047                     ->cb (sub {
1048                        $term->{overlay}->set (0, 0,
1049                           sprintf "%2d:%02d:%02d", (localtime urxvt::NOW)[2,1,0]);
1050                     });
1051
1052 =over 4
1053
1054 =item $timer = new urxvt::timer
1055
1056 Create a new timer object in started state. It is scheduled to fire
1057 immediately.
1058
1059 =item $timer = $timer->cb (sub { my ($timer) = @_; ... })
1060
1061 Set the callback to be called when the timer triggers.
1062
1063 =item $tstamp = $timer->at
1064
1065 Return the time this watcher will fire next.
1066
1067 =item $timer = $timer->set ($tstamp)
1068
1069 Set the time the event is generated to $tstamp.
1070
1071 =item $timer = $timer->interval ($interval)
1072
1073 Normally (and when C<$interval> is C<0>), the timer will automatically
1074 stop after it has fired once. If C<$interval> is non-zero, then the timer
1075 is automatically rescheduled at the given intervals.
1076
1077 =item $timer = $timer->start
1078
1079 Start the timer.
1080
1081 =item $timer = $timer->start ($tstamp)
1082
1083 Set the event trigger time to C<$tstamp> and start the timer.
1084
1085 =item $timer = $timer->stop
1086
1087 Stop the timer.
1088
1089 =back
1090
1091 =head2 The C<urxvt::iow> Class
1092
1093 This class implements io watchers/events. Example:
1094
1095   $term->{socket} = ...
1096   $term->{iow} = urxvt::iow
1097                  ->new
1098                  ->fd (fileno $term->{socket})
1099                  ->events (1) # wait for read data
1100                  ->start
1101                  ->cb (sub {
1102                    my ($iow, $revents) = @_;
1103                    # $revents must be 1 here, no need to check
1104                    sysread $term->{socket}, my $buf, 8192
1105                       or end-of-file;
1106                  });
1107
1108
1109 =over 4
1110
1111 =item $iow = new urxvt::iow
1112
1113 Create a new io watcher object in stopped state.
1114
1115 =item $iow = $iow->cb (sub { my ($iow, $reventmask) = @_; ... })
1116
1117 Set the callback to be called when io events are triggered. C<$reventmask>
1118 is a bitset as described in the C<events> method.
1119
1120 =item $iow = $iow->fd ($fd)
1121
1122 Set the filedescriptor (not handle) to watch.
1123
1124 =item $iow = $iow->events ($eventmask)
1125
1126 Set the event mask to watch. Bit #0 (value C<1>) enables watching for read
1127 data, Bit #1 (value C<2>) enables watching for write data.
1128
1129 =item $iow = $iow->start
1130
1131 Start watching for requested events on the given handle.
1132
1133 =item $iow = $iow->stop
1134
1135 Stop watching for events on the given filehandle.
1136
1137 =back
1138
1139 =head1 ENVIRONMENT
1140
1141 =head2 URXVT_PERL_VERBOSITY
1142
1143 This variable controls the verbosity level of the perl extension. Higher
1144 numbers indicate more verbose output.
1145
1146 =over 4
1147
1148 =item =0 - only fatal messages
1149
1150 =item =3 - script loading and management
1151
1152 =item =10 - all events received
1153
1154 =back
1155
1156 =head1 AUTHOR
1157
1158  Marc Lehmann <pcg@goof.com>
1159  http://software.schmorp.de/pkg/rxvt-unicode
1160
1161 =cut
1162
1163 1