configure.ac

   1 AC_PREREQ([2.54])
   2 AC_INIT([openbox], [3.5.0], [http://bugzilla.icculus.org])
   3 AM_INIT_AUTOMAKE
   4 AC_CONFIG_SRCDIR([openbox/openbox.c])
   5
   6 OB_VERSION=$PACKAGE_VERSION
   7 AC_SUBST(OB_VERSION)
   8
   9 dnl Making releases:
  10 dnl   RR_MICRO_VERSION += 1;
  11 dnl   RR_INTERFACE_AGE += 1;
  12 dnl   R_BINARY_AGE += 1;
  13 dnl if any functions have been added, set RR_INTERFACE_AGE to 0.
  14 dnl if backwards compatibility has been broken,
  15 dnl set RR_BINARY_AGE and RR_INTERFACE_AGE to 0.
  16 dnl
  17 dnl if MAJOR or MINOR version changes, be sure to change AC_INIT above to match
  18 dnl
  19 RR_MAJOR_VERSION=3
  20 RR_MINOR_VERSION=5
  21 RR_MICRO_VERSION=28
  22 RR_INTERFACE_AGE=1
  23 RR_BINARY_AGE=1
  24 RR_VERSION=$RR_MAJOR_VERSION.$RR_MINOR_VERSION
  25
  26 OBT_MAJOR_VERSION=3
  27 OBT_MINOR_VERSION=5
  28 OBT_MICRO_VERSION=1
  29 OBT_INTERFACE_AGE=1
  30 OBT_BINARY_AGE=1
  31 OBT_VERSION=$OBT_MAJOR_VERSION.$OBT_MINOR_VERSION
  32
  33 AC_SUBST(RR_MAJOR_VERSION)
  34 AC_SUBST(RR_MINOR_VERSION)
  35 AC_SUBST(RR_MICRO_VERSION)
  36 AC_SUBST(RR_INTERFACE_AGE)
  37 AC_SUBST(RR_BINARY_AGE)
  38 AC_SUBST(RR_VERSION)
  39 AC_SUBST(OBT_MAJOR_VERSION)
  40 AC_SUBST(OBT_MINOR_VERSION)
  41 AC_SUBST(OBT_MICRO_VERSION)
  42 AC_SUBST(OBT_INTERFACE_AGE)
  43 AC_SUBST(OBT_BINARY_AGE)
  44 AC_SUBST(OBT_VERSION)
  45
  46 dnl Libtool versioning
  47 RR_RELEASE=$RR_MAJOR_VERSION.$RR_MINOR_VERSION
  48 RR_CURRENT=`expr $RR_MICRO_VERSION - $RR_INTERFACE_AGE`
  49 RR_REVISION=$RR_INTERFACE_AGE
  50 RR_AGE=`expr $RR_BINARY_AGE - $RR_INTERFACE_AGE`
  51 RR_CURRENT_MINUS_AGE=`expr $RR_CURRENT - $RR_AGE`
  52
  53 OBT_RELEASE=$OBT_MAJOR_VERSION.$OBT_MINOR_VERSION
  54 OBT_CURRENT=`expr $OBT_MICRO_VERSION - $OBT_INTERFACE_AGE`
  55 OBT_REVISION=$OBT_INTERFACE_AGE
  56 OBT_AGE=`expr $OBT_BINARY_AGE - $OBT_INTERFACE_AGE`
  57 OBT_CURRENT_MINUS_AGE=`expr $OBT_CURRENT - $OBT_AGE`
  58
  59 AC_SUBST(RR_RELEASE)
  60 AC_SUBST(RR_CURRENT)
  61 AC_SUBST(RR_REVISION)
  62 AC_SUBST(RR_AGE)
  63 AC_SUBST(RR_CURRENT_MINUS_AGE)
  64 AC_SUBST(OBT_RELEASE)
  65 AC_SUBST(OBT_CURRENT)
  66 AC_SUBST(OBT_REVISION)
  67 AC_SUBST(OBT_AGE)
  68 AC_SUBST(OBT_CURRENT_MINUS_AGE)
  69
  70 AC_PREFIX_DEFAULT([/usr/local])
  71 test "$prefix" = "NONE" && prefix=$ac_default_prefix
  72
  73 dnl Determine build target
  74 OB_DEBUG
  75 dnl Pick compiler specific/build target flags, and set $CVS
  76 AM_PROG_CC_C_O
  77 OB_COMPILER_FLAGS
  78 AC_C_CONST
  79 AC_C_INLINE
  80
  81 AC_PROG_LIBTOOL
  82 AC_SUBST(LIBTOOL_DEPS)
  83 LIBTOOL="$LIBTOOL --silent"
  84
  85 AC_PROG_INSTALL
  86
  87 AM_GNU_GETTEXT_VERSION(0.15)
  88 AM_GNU_GETTEXT([external])
  89
  90 AC_CHECK_HEADERS(ctype.h dirent.h errno.h fcntl.h grp.h locale.h pwd.h)
  91 AC_CHECK_HEADERS(signal.h string.h stdio.h stdlib.h unistd.h sys/stat.h)
  92 AC_CHECK_HEADERS(sys/select.h sys/socket.h sys/time.h sys/types.h sys/wait.h)
  93
  94 AC_PATH_PROG([SED], [sed], [no])
  95 if test "$SED" = "no"; then
  96   AC_MSG_ERROR([The program "sed" is not available. This program is required to build Openbox.])
  97 fi
  98
  99 AC_PATH_PROG([DIRNAME], [dirname], [no])
 100 if test "$DIRNAME" = "no"; then
 101   AC_MSG_ERROR([The program "dirname" is not available. This program is required to build Openbox.])
 102 fi
 103
 104 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.14.0])
 105 AC_SUBST(GLIB_CFLAGS)
 106 AC_SUBST(GLIB_LIBS)
 107
 108 PKG_CHECK_MODULES(PANGO, [pango >= 1.8.0 pangoxft >= 1.8.0])
 109 AC_SUBST(PANGO_CFLAGS)
 110 AC_SUBST(PANGO_LIBS)
 111
 112 PKG_CHECK_MODULES(XML, [libxml-2.0 >= 2.6.0])
 113 AC_SUBST(XML_CFLAGS)
 114 AC_SUBST(XML_LIBS)
 115
 116 AC_ARG_ENABLE(startup-notification,
 117   AC_HELP_STRING(
 118     [--disable-startup-notification],
 119     [disable the startup notification library. [default=enabled]]
 120   ),
 121   [enable_sn=$enableval],
 122   [enable_sn=yes]
 123 )
 124
 125 if test "$enable_sn" = yes; then
 126 PKG_CHECK_MODULES(LIBSN, [libstartup-notification-1.0 >= 0.8],
 127   [
 128     AC_DEFINE(USE_LIBSN, [1], [Use startup-notification])
 129     AC_SUBST(LIBSN_CFLAGS)
 130     AC_SUBST(LIBSN_LIBS)
 131     sn_found=yes
 132   ],
 133   [
 134     sn_found=no
 135   ]
 136 )
 137 else
 138   sn_found=no
 139 fi
 140
 141 AC_ARG_ENABLE(xcursor,
 142   AC_HELP_STRING(
 143     [--disable-xcursor],
 144     [disable use of the X Cursor library. [default=enabled]]
 145   ),
 146   [enable_xcursor=$enableval],
 147   [enable_xcursor=yes]
 148 )
 149
 150 if test "$enable_xcursor" = yes; then
 151 PKG_CHECK_MODULES(XCURSOR, [xcursor],
 152   [
 153     AC_DEFINE(USE_XCURSOR, [1], [Use X Cursor library])
 154     AC_SUBST(XCURSOR_CFLAGS)
 155     AC_SUBST(XCURSOR_LIBS)
 156     xcursor_found=yes
 157   ],
 158   [
 159     xcursor_found=no
 160   ]
 161 )
 162 else
 163   xcursor_found=no
 164 fi
 165
 166 AC_ARG_ENABLE(imlib2,
 167   AC_HELP_STRING(
 168     [--disable-imlib2],
 169     [disable use of Imlib2 image library for loading icons. [default=enabled]]
 170   ),
 171   [enable_imlib2=$enableval],
 172   [enable_imlib2=yes]
 173 )
 174
 175 if test "$enable_imlib2" = yes; then
 176 PKG_CHECK_MODULES(IMLIB2, [imlib2],
 177   [
 178     AC_DEFINE(USE_IMLIB2, [1], [Use Imlib2 image library])
 179     AC_SUBST(IMLIB2_CFLAGS)
 180     AC_SUBST(IMLIB2_LIBS)
 181     # export it for the pkg-config file
 182     PKG_CONFIG_IMLIB=imlib2
 183     AC_SUBST(PKG_CONFIG_IMLIB)
 184     imlib2_found=yes
 185   ],
 186   [
 187     imlib2_found=no
 188   ]
 189 )
 190 else
 191   imlib2_found=no
 192 fi
 193
 194 AM_CONDITIONAL(USE_IMLIB2, [test $imlib2_found = yes])
 195
 196 dnl Check for session management
 197 X11_SM
 198
 199 #EFENCE_LIBS=-lefence
 200 EFENCE_LIBS=""
 201 AC_SUBST(EFENCE_LIBS)
 202
 203 dnl Check for X11 extensions
 204 X11_EXT_XKB
 205 X11_EXT_XRANDR
 206 X11_EXT_SHAPE
 207 X11_EXT_XINERAMA
 208 X11_EXT_SYNC
 209 X11_EXT_AUTH
 210
 211 AC_CONFIG_FILES([
 212   Makefile
 213   m4/Makefile
 214   po/Makefile.in
 215   obrender/obrender-3.5.pc
 216   obt/obt-3.5.pc
 217   obrender/version.h
 218   obt/version.h
 219   version.h
 220 ])
 221 AC_CONFIG_COMMANDS([doc],
 222                    [test -d doc || mkdir doc])
 223 AC_CONFIG_COMMANDS([data],
 224                    [test -d data || mkdir data])
 225 AC_CONFIG_COMMANDS([data/xsession],
 226                    [test -d data/xsession || mkdir data/xsession])
 227 AC_OUTPUT
 228
 229 AC_MSG_RESULT
 230 AC_MSG_RESULT([Compiling with these options:
 231                Startup Notification... $sn_found
 232                X Cursor Library... $xcursor_found
 233                Session Management... $SM
 234                Imlib2 library... $imlib2_found
 235                ])
 236 AC_MSG_RESULT([configure complete, now type "make"])